Income Tax 1

Source Code

   10 POKE 23658,0: PAPER 7: CLS : PRINT ''"INCOME TAX PROGRAM to be used with OS-64 (64 col.) and 80 column printer": PRINT ''"PRESS ANY KEY for instructions": PAUSE 0: GO SUB 3400
   20 CLS : BEEP .05,20: BEEP .05,20: BEEP .06,15: PRINT AT 10,10;"TURN ON YOUR PRINTER!!!"
   30 PRINT '"Answer all questions with the amount asked for, Enter ""0"" if    question does not apply to you. do not use commas in numbers.   (For example, enter 5000, not 5,000) Press ENTER after answeringeach question."
   40 PRINT : PRINT "Press any key when ready."
   50 PAUSE 0: CLS 
   60 INPUT "What is your filing status?     s = single                      mj= married filing jointly      ms= married filing separately   hh= head of household.          q = qualifying widow'widower";c$
   70 IF c$<>"s" AND c$<>"mj" AND c$<>"ms" AND c$<>"hh" AND c$<>"q" THEN PRINT "Wrong filing status.  Start over": PAUSE 100: CLS 
   80 IF c$="mj" OR c$="q" THEN LET b3=3670
   90 IF c$="s" OR c$="hh" THEN LET b3=2480
  100 IF c$="ms" THEN LET b3=1835
  110 IF c$<>"s" AND c$<>"mj" AND c$<>"ms" AND c$<>"hh" AND c$<>"q" THEN GO TO 30
  120 INPUT "Count your number of exemptions.(One each for self and spouse.)";a
  130 INPUT "Count the number 65 and over,and the number blind";a1
  140 INPUT "count the number of dependents, Other than yourself and spouse";b
  150 LET b2=a+a1+b
  160 INPUT "Wages, salaries, tips, rents,   capital gains, IRA disbursements(Enter""0""if none)?";c: PRINT c
  170 INPUT "Interest income?";d: PRINT d
  180 INPUT "Dividend income?";e;" Less exclusion";e1: PRINT e: PRINT e1
  190 LET e2=e-e1: IF e1>e THEN LET e2=0
  200 INPUT "Refunds State & Local Taxes";r: PRINT r
  210 INPUT "Alimony received";l: PRINT l: GO SUB 910
  220 GO SUB 2600: INPUT "Busines Income/Loss (use-)";m: PRINT m
  230 CLS : GO SUB 2640: INPUT "Capital Gains/Loss (use-for loss)";n: PRINT n
  240 GO SUB 2680: INPUT "40% of Capital gains";n1: PRINT n1
  250 GO SUB 2660: INPUT "Other gains/losses (use-)";o: PRINT o
  260 GO SUB 2540: INPUT "Taxable pension, IRA distributions & Annuities";p: PRINT p
  270 CLS : INPUT "Taxable amount other pension & annuities ";q: PRINT q
  280 CLS 
  290 GO SUB 2580: INPUT "Rents,royalties,partnershps,estates,etc.)";s: PRINT s
  300 CLS 
  310 GO SUB 2620: INPUT "Farm income/loss (use-)";t: PRINT t
  320 GO SUB 2700: INPUT "Total Unemployment Comp.";u1: PRINT u1: LET u=0
  330 GO SUB 2710: INPUT "Social Security";v1: PRINT v1: LET v=0
  340 INPUT "Other Income";w
  350 LET agi=c+d+e2+r+l+m+n+n1+o+p+q+s+t+u1+u+v+w
  360 PRINT "Your total income is:$";agi
  370 GO SUB 1110
  380 INPUT "Moving expense ";f: PRINT f
  390 INPUT "Employee business expenses ";h: PRINT h
  400 INPUT "IRA deduction ";g: PRINT g
  410 INPUT "Payments to a Keogh (HR-10) retirement plan ";j: PRINT j
  420 INPUT "Penalty on early withdrawal of savings ";k
  430 INPUT "Alimony paid ";x: PRINT x
  440 INPUT "Deduction for married couple when both work. ";y: PRINT y
  450 LET z1=f+h+g+j+k+x+y
  460 LET agi=agi-z1
  470 GO SUB 1250
  480 CLS : PRINT "UNEMPLOYMENT COMPENSATION WORKSHEET"''"1. Married filing joint return."'"2. Married filing separate."'"3. Married not filing joint return and DID NOT live with spouse at anytime during the year."'"4.All others."
  490 PRINT '"Input a Number"
  500 INPUT aa: IF aa=1 THEN LET aa=18000
  510 IF aa=2 THEN LET aa=0
  520 IF aa=3 OR aa=4 THEN LET aa=12000
  530 CLS : PRINT "Total unemployment comp.";u1
  540 INPUT "Overpayment of unemployment comp.""REPAID""";cc
  550 LET dd=u1-cc
  560 LET bb=c+d+e2+r+l+m+n+n1+o+p+q+s+t+w: PRINT "All amounts shown on form 1040 lines 7 thru 19 plus line 22. NOT INCLUDING UNEMPLOYMENT COMP.=";bb
  570 LET ff=bb+dd
  580 LET ee=f+h+g+j+k+x: PRINT "Total of amounts shown on Form 1040, line 24 thru 29";ee
  590 LET hh=ff-ee
  600 LET ii=hh-aa
  610 IF ii<=0 THEN LET ii=0: GO TO 630
  620 IF ii>0 THEN GO TO 640
  630 PRINT "If this number ";ii;" is 0 or less then no tax is due!": GO TO 670
  640 LET jj=ii/2
  650 PRINT "TAXABLE UNEMPLOYMENT COMP.=$";jj
  660 PRINT "Use the smaller of these figures on FORM 1040, line 20b.": PRINT dd;" or ";jj
  670 INPUT "Enter the Smaller figure";u: PRINT u
  680 LET agi=agi+u
  690 PRINT "PRESS A KEY FOR SOCIAL SECURITY WORKSHEET": PAUSE 0
  700 CLS : PRINT " WORK SHEET FOR SOCIAL SECURITY": PRINT ''"1. Single"'"2. Married filing jointly"'"3. Married filing separate"'"4. Married not filing jointly and DID NOT live with spouse         during 1986."
  710 INPUT zz
  720 IF zz=1 THEN LET zz=25000
  730 IF zz=2 THEN LET zz=32000
  740 IF zz=3 THEN LET zz=0
  750 IF zz=4 THEN LET zz=25000
  760 PRINT "All amounts from Forms SSA-1099=$";v1: IF v1<=0 THEN PRINT "none of your benefits are taxable.": GO TO 860
  770 LET yy=v1/2
  780 LET ww=c+d+e2+r+l+m+n+n1+o+p+q+s+t+u+w: PRINT "Total of lines 7 thru 20b plus line 22 from form 1040=$";ww
  790 INPUT "Enter any tax exempt interest received in 1986";tt
  800 LET uu=yy+ww+tt
  810 LET vv=f+h+g+j+k+x: PRINT "Total of amounts from lines 24 thru 29=$";vv
  820 LET ss=uu-vv-zz
  830 IF ss<=0 THEN LET ss=0: PRINT "None of your benefits are taxable the figure is:";ss: LET v=0: LET ss=v: GO TO 880
  840 LET rr=ss/2
  850 PRINT ;yy': PRINT ;rr': PRINT "Use the smaller of these figures on Form 1040 line 21b"
  860 INPUT "ENTER THE FIGURE";v: PRINT v
  870 LET b1=b1+v
  880 PRINT "PRESS A KEY FOR TAX COMPUTATION": PAUSE 0
  890 CLS : PRINT "TAX COMPUTATION"
  900 GO SUB 2720
  910 CLS 
  920 GO SUB 3360
  930 IF c$="s" THEN LET c$="Single": LET b3=2480
  940 IF c$="mj" THEN LET c$="Married filing jointly": LET b3=3670
  950 IF c$="ms" THEN LET c$="Married filing separate": LET b3=1835
  960 IF c$="hh" THEN LET c$="Head of Household": LET b3=2480
  970 IF c$="q" THEN LET c$="qualifying widow (widower)": LET b3=3670
  980 LPRINT '"FILING STATUS ---";TAB 18;c$;TAB 42;"lines 1 to 5"
  990 LPRINT "NUMBER EXEMPTIONS -----";TAB 24;a;TAB 45;"lines 6a & 6b"
 1000 LPRINT "NUMBER over 65/BLIND --";TAB 24;a1;TAB 45;"lines 6a & 6b"
 1010 LPRINT "NUMBER DEPENDENTS -----";TAB 24;b;TAB 45;"line 6c & 6e"
 1020 LPRINT "TOTAL EXEMPTIONS -------------";TAB 31;b2;TAB 45;"line 6f"
 1030 LPRINT "WAGES, SALARIES, TIPS, etc -----";TAB 34;c;TAB 45;"line 7"
 1040 LPRINT "INTEREST INCOME ----------------";TAB 34;d;TAB 45;"line 8"
 1050 LPRINT "DIVIDENDS ----------------------";TAB 34;e;TAB 45;"line 9a"
 1060 LPRINT "LESS EXCLUSION -----------------";TAB 34;"-";e1;TAB 45;"line 9b"
 1070 LPRINT "DIVIDEND less EXCLUSION. -------";TAB 34;e2;TAB 45;"line 9c"
 1080 LPRINT "REFUNDS ST. & LOCAL TAXES-------";TAB 34;r;TAB 45;"line 10"
 1090 LPRINT "ALIMONY RECEIVED ---------------";TAB 34;l;TAB 45;"line 11"
 1100 RETURN 
 1110 LPRINT "BUSINESS INCOME/LOSS -----------";TAB 34;m;TAB 45;"line 12"
 1120 LPRINT "CAPITAL GAINS/LOSS -------------";TAB 34;n;TAB 45;"line 13"
 1130 LPRINT "40% of CAPITAL GAINS -----------";TAB 34;n1;TAB 45;"line 14"
 1140 LPRINT "OTHER GAINS/LOSSES -------------";TAB 34;o;TAB 45;"line 15"
 1150 LPRINT "TAXABLE PENSIONS,IRA,ANNUIT.----";TAB 34;p;TAB 45;"line 16"
 1160 LPRINT "OTHER PENSIONS,ANNUIT. etc. ----";TAB 34;q;TAB 45;"line 17a"
 1170 LPRINT "RENTS ROYALTIES ETC. -----------";TAB 34;s;TAB 45;"line 18"
 1180 LPRINT "FARM INCOME or LOSS ------------";TAB 34;t;TAB 45;"line 19"
 1190 LPRINT "UNEMPLOY.COMP.received ---------";TAB 34;u1;TAB 45;"line 20a"
 1200 LPRINT "UNEMPLOY. COMP. TAXABLE --------";TAB 34;u;TAB 45;"line 21b"
 1210 LPRINT "TOTAL SOC.SEC.RECEIVED ---------";TAB 34;v1;TAB 45;"line 21a"
 1220 LPRINT "TAXABLE AMT. S.S.---------------";TAB 34;v;TAB 45;"line 21b"
 1230 LPRINT "OTHER INCOME -------------------";TAB 34;w;TAB 45;"line 22"
 1240 LPRINT "TOTAL INCOME ------------------";TAB 34;agi;TAB 45;"line 23": RETURN 
 1250 LPRINT '"      ADJUSTMENTS TO INCOME"
 1260 LPRINT "MOVING EXPENSES -----------------";TAB 34;f;TAB 45;"line 24"
 1270 LPRINT "EMPLOYEE BUSINESS EXPENSE -------";TAB 34;h;TAB 45;"line 25"
 1280 LPRINT "IRA DEDUCTION -------------------";TAB 34;g;TAB 45;"line 26a"
 1290 LPRINT "PAYMENTS TO A KEOGH -------------";TAB 34;j;TAB 45;"line 27"
 1300 LPRINT "PENALTY ON EARLY WITHDRAWAL SAV.-";TAB 34;k;TAB 45;"line 28"
 1310 LPRINT "ALIMONY PAID --------------------";TAB 34;x;TAB 45;"line 29"
 1320 LPRINT "DEDUCTION MARRIED COUPLE --------";TAB 34;y;TAB 45;"line 30"
 1330 LPRINT "TOTAL ADJUSTMENTS ---------------";TAB 34;z1;TAB 45;"line 31"
 1340 LPRINT "ADJUSTED GROSS INCOME -----------";TAB 34;agi;TAB 45;"line 32"
 1350 LPRINT '"       ITEMIZED DEDUCTIONS Schedule A"
 1360 GO SUB 2820
 1370 LPRINT "Prescriptions & Drugs ----------";TAB 34;dru;TAB 45;"line 1"
 1380 LPRINT "Doctors, Dentists, Nurses etc. --";TAB 34;pre;TAB 45;"line 2a"
 1390 LPRINT "Transportation & Lodging --------";TAB 34;tra;TAB 45;"line 2b"
 1400 LPRINT "Other (hearing aids etc. --------";TAB 34;oth;TAB 45;"line 2c"
 1410 LPRINT "Subtotal ------------------------";TAB 34;d5;TAB 45;"line 3"
 1420 LPRINT agi;" * 5% ----------------";TAB 34;b5;TAB 45;"line 4"
 1430 LPRINT d5;" less ";b5;" --------";TAB 34;b6;TAB 45;"line 5"
 1440 GO SUB 2280
 1450 LPRINT "State & Local income taxes --";TAB 34;sli;TAB 45;"line 6"
 1460 LPRINT "Real Estate Taxes ------------";TAB 34;ret;TAB 45;"line 7"
 1470 LPRINT "General Sales Tax ------------";TAB 34;gst;TAB 45;"line 8a"
 1480 LPRINT "Sales Tax Motor Vehicle-------";TAB 34;vst;TAB 45;"line 8b"
 1490 LPRINT "Other Taxes ------------------";TAB 34;tto;TAB 45;"line 9"
 1500 LPRINT "TOTAL TAXES ------------------";TAB 34;b7;TAB 45;"line 10"
 1510 GO SUB 2280
 1520 LPRINT "Home Mortgage Interest -------";TAB 34;hmb;TAB 45;"line 11a"
 1530 LPRINT "Home Mort. to Individual -----";TAB 34;hmi;TAB 45;"line 11b"
 1540 LPRINT "Credit Card Interest ---------";TAB 34;cci;TAB 45;"line 12"
 1550 LPRINT : LPRINT : LPRINT : LPRINT : LPRINT : LPRINT 
 1560 LPRINT "Other Interest paid ----------";TAB 34;oip;TAB 45;"line 13"
 1570 LPRINT "TOTAL INTEREST ---------------";TAB 34;b8;TAB 45;"line 14"
 1580 GO SUB 2280
 1590 GO SUB 2720
 1600 LPRINT "Cash Contributions -----------";TAB 34;ccd;TAB 45;"line 15a"
 1610 LPRINT "Cash Cont. over 3000 ---------";TAB 34;xxx;TAB 45;"line 15b"
 1620 LPRINT "Other than cash --------------";TAB 34;xxy;TAB 45;"line 16"
 1630 LPRINT "Carryover from prior year ----";TAB 34;xxz;TAB 45;"line 17"
 1640 LPRINT "TOTAL CONTRIBUTIONS ----------";TAB 34;b9;TAB 45;"line 18"
 1650 GO SUB 2280
 1660 LPRINT "Casualty and Theft losses -----";TAB 34;ctl;TAB 45;"line 19"
 1670 GO SUB 2280
 1680 LPRINT "Union and Professional Dues ---";TAB 34;upd;TAB 45;"line 20"
 1690 LPRINT "Tax Return Preparation fees ---";TAB 34;tpf;TAB 45;"line 21"
 1700 LPRINT "Other (list) ------------------";TAB 34;odd;TAB 45;"line 22"
 1710 LPRINT "TOTAL MISCELLANEOUS -----------";TAB 34;b10;TAB 45;"line 23"
 1720 GO SUB 2280
 1730 LPRINT "TOTAL ITEMIZED DEDUCTIONS -----";TAB 34;b11;TAB 45;"line 24"
 1740 LPRINT "Dependents = ";b2
 1750 LPRINT "STANDARD DEDUCTION = ";b3;TAB 45;"line 25"
 1760 LPRINT "Line 25 less Line 24 ";TAB 34;b12;TAB 45;"line 26"
 1770 LPRINT "If line 25 is more than line 24, see instructions for line 26   on page 22 of Instructions."
 1780 LPRINT "       TAX COMPUTATION if you DO NOT ITEMIZE "
 1790 GO SUB 2280
 1800 LPRINT "Amount from line 32(adj.gr.inc.)";TAB 42;agi;TAB 55;"line 33"
 1810 LPRINT "If you do NOT Itemize, Cash Contribution";TAB 42;b9;TAB 55;"line 34b"
 1820 LET agi=agi-b9
 1830 LPRINT "Line 33 less 34b";TAB 42;agi;TAB 55;"line 35"
 1840 LET b15=b2*1080
 1850 LPRINT "Multiply 1080 by no.exemptions";TAB 42;b15;TAB 55;"line 36"
 1860 LET agi=agi-b15: LPRINT "TAXABLE INCOME";TAB 42;agi;TAB 55;"line 37"
 1870 GO SUB 2260: LPRINT "TAX";TAB 42;t9;TAB 55;"line 38"
 1880 GO SUB 2300
 1890 LPRINT "Additional Taxes";TAB 42;t10;TAB 55;"line 39"
 1900 LET b21=t9+t10: LPRINT "TOTAL TAXES";TAB 42;b21;TAB 55;"line 40"
 1910 GO SUB 2310
 1920 LPRINT "Credit for Child Care & Depents.";TAB 42;c1;TAB 55;"line 41"
 1930 LPRINT "Credit for Elderly & Disabled";TAB 42;c2;TAB 55;"line 42"
 1940 REM LPRINT "Residential Energy Credit";TAB 42;c3;TAB 55;"line 43"
 1950 LPRINT "Partial Credit for Political Contr.";TAB 42;c4;TAB 55;"line 43"
 1960 LET c5=c1+c2+c4
 1970 LPRINT "TOTAL PERSONAL CREDITS";TAB 42;c5;TAB 55;"line 44"
 1980 LET c6=b21-c5: IF c6<0 THEN LET c6=0: LPRINT "TAX less CREDITS";TAB 42;c6;TAB 55;"line 45"
 1990 GO SUB 2360
 2000 LPRINT "Foreign Tax Credit";TAB 42;c7;TAB 55;"line 46"
 2010 LPRINT "General Business Credit";TAB 42;c8;TAB 55;"line 47"
 2020 LET c9=c7+c8: LPRINT "Total Business Credits";TAB 42;c9;TAB 55;"line 48"
 2030 LET c10=c6-c9: IF c10<=0 THEN LET c10=0: LPRINT "Line 45 less line 48";TAB 42;c10;TAB 55;"line 49"
 2040 GO SUB 2390
 2050 LPRINT "Self Employment Tax";TAB 42;c11;TAB 55;"line 50"
 2060 LPRINT "Alternative minimum tax";TAB 42;c12;TAB 55;"line 51"
 2070 LPRINT "Tax from recapture of investment credit";TAB 42;c13;TAB 55;"line 52"
 2080 LPRINT "Social Security Tax on Tips";TAB 42;c14;TAB 55;"line 53"
 2090 LPRINT "Tax on IRA";TAB 42;c15;TAB 55;"line 54"
 2100 LET c16=c10+c11+c12+c13+c14+c15: LPRINT "THIS IS YOUR TOTAL TAX";TAB 42;c16;TAB 55;"line 55"
 2110 GO SUB 2450
 2120 LPRINT "FEDERAL INCOME TAX WITHHELD";TAB 42;c20;TAB 55;"line 56"
 2130 LPRINT "1986 estimated tax payments";TAB 42;c21;TAB 55;"line 57"
 2140 LPRINT "Earned Income credit";TAB 42;c22;TAB 55;"line 58"
 2150 LPRINT "Amount paid with form 4868";TAB 42;c23;TAB 55;"line 59"
 2160 LPRINT "Excess Social Security Tax paid";TAB 42;c24;TAB 55;"line 60"
 2170 LPRINT "Credit for Federal Tax on special fuels";TAB 42;c25;TAB 55;"line 61"
 2180 LPRINT "Regulated Investment Co.credit";TAB 42;c26;TAB 55;"line 62"
 2190 LET c27=c20+c21+c22+c23+c24+c25+c26: LPRINT "These are your TOTAL PAYMENTS";TAB 42;c27;TAB 55;"line 63"
 2200 LET c28=c27-c16
 2210 LPRINT "AMOUNT OVERPAID";TAB 42;c28;TAB 55;"line 64"
 2220 LET c29=c16-c27
 2230 LPRINT "Amount of line 65 to be REFUNDED";TAB 42;c28;TAB 55;"line 65"
 2240 LPRINT "Amount YOU OWE";TAB 42;c29;TAB 55;"line 67"
 2250 LPRINT '"ENTER THE FIGURES ON THE LINES INDICATED, IF THEY DO NOT APPLY  TO YOUR SITUATION DO NOT USE THEM!!": STOP 
 2260 BEEP .05,20: BEEP .05,15: CLS : PRINT AT 8,2;"YOUR TAXABLE INCOME IS $";agi;'"Now you must refer to the TAX TABLES in the instructions and    INPUT The amount listed!!!!": INPUT "TAX FROM TAX TABLES ";t9
 2270 RETURN 
 2280 LPRINT "----------------------------------------------------------------": RETURN 
 2290 STOP 
 2300 INPUT "Any Additional Taxes?";t10: RETURN 
 2310 INPUT "Credit for Child & Depend.";c1
 2320 INPUT "Credit for Elderly & Disabled";c2
 2330 INPUT "Residential Energy Credit";c3
 2340 INPUT "Partial credit for Political Contr.";c4
 2350 RETURN 
 2360 INPUT "Foreign Tax Credit";c7
 2370 INPUT "General Business Credit";c8
 2380 RETURN 
 2390 INPUT "Self Employment Tax";c11
 2400 INPUT "Alternative minimum tax";c12
 2410 INPUT "Tax from recapture of investment credit";c13
 2420 INPUT "Social Security Tax on tips";c14
 2430 INPUT "Tax on IRA";c15
 2440 RETURN 
 2450 INPUT "FEDERAL INCOME TAX Withheld";c20
 2460 INPUT "1985 estimated tax payments";c21
 2470 INPUT "Earned Income Credit";c22
 2480 INPUT "Amount paid w/form 4868";c23
 2490 INPUT "Excess Social Security Tax withheld";c24
 2500 INPUT "Credit for Federal Gasoline & special fuels";c25
 2510 INPUT "Regulated Investment Co. credit.";c26
 2520 RETURN 
 2530 STOP 
 2540 CLS : PRINT "Use line 16 to report fully taxable pension and annuity income  and any IRA distributions you received."
 2550 PRINT "You should receive a Form W-2P showing the amount of your       pension or annuity."
 2560 PRINT '"   Your pension or annuity payments are fully taxable if:"'"1. You did not contribute to the cost of your pension or        annuity."'"2. You got back tax-free your entire cost before 1986"
 2570 RETURN 
 2580 CLS : PRINT "For rents royalties etc. you must attach Schedule E"
 2590 RETURN 
 2600 CLS : PRINT "You must attach Schedule ""C""."
 2610 RETURN 
 2620 CLS : PRINT "Use Schedule ""F"""
 2630 RETURN 
 2640 CLS : PRINT "Use Schedule ""D"""
 2650 RETURN 
 2660 CLS : PRINT "Supplemental gain/loss attach ""Form 4797"""
 2670 RETURN 
 2680 CLS : PRINT "40% of Capital Gains not reported on line 13"
 2690 RETURN 
 2700 CLS : PRINT "NOTE:"'"ENTER TOTAL AMOUNT of Unemployment Compensation!!"'"from Form 1099-G": RETURN 
 2710 CLS : PRINT "NOTE:"'"    ENTER TOTAL AMOUNT of Social Security!!!": RETURN 
 2720 CLS : PRINT "Charitable Contributions (Worksheet page 14)"
 2730 INPUT "Cash contributions";ccd: PRINT ccd
 2740 IF c$="ms" THEN LET c$="Married filing separate": LET b3=1770
 2750 INPUT "Non-Cash contributions";ccn: PRINT ccn: GO TO 2770
 2760 LPRINT "       FORM 1040 page 1"
 2770 LET cct=ccd+ccn: PRINT "Total = ";cct
 2780 LET z=cct/2: IF z<=25 THEN LET z=25
 2790 REM LET agi=agi-z
 2800 PRINT "Allowable Charitable Contributions=";z
 2810 RETURN 
 2820 INPUT "Prescriptions, Drugs & Insulin";dru: PRINT dru
 2830 INPUT "Doctors, Dentists, Nurses, Hospitals, Insurance premiums";pre: PRINT pre
 2840 INPUT "Transportation & Lodging";tra: PRINT tra
 2850 INPUT "Other (hearing aids, dentures, eyeglasses etc.";oth: PRINT oth
 2860 LET d5=dru+pre+tra+oth: PRINT ;d5;" Total"
 2870 LET b5=agi*.05: LET b6=d5-b5: IF d5=0 THEN LET b5=0
 2880 IF b5<agi*.05 THEN LET b6=0
 2890 IF b6<=0 THEN LET b6=0: PRINT "Not enough Medical for deduction to qualify is less than 5% of  Adjusted Gross Income! Total to enter on line 5 is: ";b6
 2900 IF b6>0 THEN PRINT "Your Medical Deduction to enter on line 5 is ";b6;
 2910 PRINT '"PRESS A KEY": PAUSE 0
 2920 CLS : PRINT "TAXES YOU PAID"
 2930 INPUT "State and Local Income Taxes";sli: PRINT 'sli
 2940 INPUT "Real Estate Taxes";ret: PRINT ret
 2950 INPUT "General Sales Tax (see tax tables)";gst: PRINT gst
 2960 INPUT "General Sales Tax on Motor Vehicles";vst: PRINT vst
 2970 INPUT "Other Taxes";tto: PRINT tto
 2980 LET b7=sli+ret+gst+vst+tto: PRINT ;b7;" Total"
 2990 PRINT '"Your total taxes to enter on line 10 is: ";b7
 3000 PRINT '"PRESS A KEY": PAUSE 0
 3010 CLS : PRINT "INTEREST YOU PAID"
 3020 INPUT "Mome Mortgage interest paid to banks";hmb: PRINT 'hmb
 3030 INPUT "Home Mortgage interest paid to individuals";hmi: PRINT hmi
 3040 INPUT "Credit Card Interest";cci: PRINT cci
 3050 INPUT "Other Interest paid";oip: PRINT oip
 3060 LET b8=hmb+hmi+cci+oip: PRINT b8;" Total"
 3070 PRINT '"Your total interest to enter on line 14 is: ";b8
 3080 PRINT '"PRESS A KEY": PAUSE 0
 3090 CLS : PRINT "CONTRIBUTIONS YOU MADE"
 3100 INPUT "Cash contributions. (line 15a) ";cco: PRINT 'cco
 3110 INPUT "Cash contributions totaling 3000 or more to any one organizationshow how much! (line 15b)";xxx: PRINT xxx
 3120 INPUT "Contributions other than cash (line 16) ";xxy: PRINT xxy
 3130 INPUT "Carryover from previous year (line 17) ";xxz: PRINT xxz
 3140 LET b9=cco+xxx+xxy+xxz: PRINT ;b9;" Total"
 3150 PRINT '"Your total contributions to enter on line 18 are: ";b9
 3160 PRINT '"PRESS A KEY": PAUSE 0
 3170 CLS : PRINT "CASUALTY AND THEFT LOSSES"'"You must attach Form 4684"
 3180 INPUT "Total casualty and theft losses ";ctl: PRINT ctl
 3190 PRINT "Your total casualty to enter on line 19 are ";ctl
 3200 PRINT '"PRESS A KEY": PAUSE 0
 3210 CLS : PRINT "MISCELLANEOUS DEDUCTIONS"
 3220 INPUT "Union and Professional Dues (line 20) ";upd: PRINT 'upd
 3230 INPUT "Tax Preparation Fee ";tpf: PRINT tpf
 3240 INPUT "Other Deductions (line 22) ";odd;: PRINT odd
 3250 LET b10=upd+tpf+odd: PRINT ;b10;" Total"
 3260 LET b11=b6+b7+b8+b9+ctl+b10: PRINT b11
 3270 PRINT '"Grand Total of ITEMIZED DEDUCTIONS enter on Line 24 ";b11
 3280 IF c$="mj" OR c$="q" THEN LET b3=3670
 3290 IF c$="s" OR c$="hh" THEN LET b3=2480
 3300 IF c$="ms" THEN LET b3=1835
 3310 LET b12=b11-b3: IF b12<=0 THEN LET b12=0
 3320 PRINT "YOUR STANDARD DEDUCTION IS: $";b3
 3330 PRINT "Enter on line 25 ";b3
 3340 PRINT "Enter on line 26 ";b12
 3350 RETURN 
 3360 POKE 65518,1
 3370 LPRINT CHR$ 27;CHR$ 80
 3380 POKE 65518,0
 3390 RETURN 
 3400 CLS : PRINT TAB 25;"INSTRUCTIONS"
 3410 PRINT '" INPUT ALL INFORMATION FROM YOUR W2's and ANY SPECIAL FORMS YOU MAY HAVE TO FILL OUT, THE INFORMATION WILL PRINT AS YOU GO ALONG"
 3420 PRINT " THE PROGRAM WILL CALCULATE YOUR TAX AND WILL SHOW YOU THE      AMOUNT OF YOUR REFUND OR THE AMOUNT YOU WILL HAVE TO PAY."
 3430 PRINT " SOME INPUTS YOU WILL BE ASKED TO ENTER TWICE AT DIFFERENT TIMES(SUCH AS SOCIAL SECURITY AND CHARITABLE CONTRIBUTIONS) THIS WILLNOT AFFECT THE FINAL COMPUTATION!"
 3440 PRINT '"NOTE: LINE 3370 IS THE CODES FOR PICA PRINT ON THE LEGEND 808   PRINTER YOU DO NOT NEED THIS WITH THE OS-64 CARTRIDGE UNLESS    YOU WANT TO CHANGE YOUR PRINT STYLE."
 3450 PRINT '" HAVE FUN BUT CHECK THE FIGURES WITH YOUR CALCULATOR ANY WAY.   AND IF YOU FIND SOME BUGS I WOULD LIKE TO HEAR ABOUT THEM."'"WALLY HAYES"'"5530 ABRAHAM DR."'"PARMA,OHIO 44130"
 3460 PRINT "PRESS A KEY": PAUSE 0: RETURN 
 3470 STOP 
 3480 GO TO 10: REM LOAD "BOLD"CODE : GO TO 10: REM char set
 3490 SAVE "incometax1" LINE 3480: BEEP .05,20: GO TO 10