Aliens

Source Code

    5 REM written for the 2068        by Bob Redman May 12 '85
    7 CLS 
    8 REM "aliens.bas"
    9 BEEP .1,11
   10 GO SUB 1000
   20 GO SUB 1200
   30 REM screen set up
   34 CLS : PAPER 5: CLS : PAPER 5: BORDER 0
   40 CLS : PRINT AT 20,0; PAPER 4;"                                "
   45 PRINT AT 21,0; PAPER 4;"                                "
   50 FOR s=1 TO 20
   55 OVER 1
   60 PLOT RND*254,RND*120+40
   70 NEXT s
   75 OVER 0
   80 LET f1=0: LET l=15
   85 LET b=-22
   90 LET hits=0
  100 REM aliens
  110 POKE 23672,0
  120 LET t=PEEK 23672
  125 BRIGHT 1
  129 BRIGHT 1: IF t>=80-(a*6) THEN PRINT AT RND*17,RND*28+2; PAPER 8; INK 2;"\a": BEEP .05,b: LET f1=f1+1: BRIGHT 0: PRINT AT 21,28; INK 4;"\::\::"
  131 BRIGHT 0: LET b=b+.1
  135 PRINT AT 21,21;"aliens ": PRINT AT 21,28;f1
  140 IF f1>10 THEN GO TO 400
  160 IF t>=80-(a*6) THEN POKE 23672,0
  200 REM launcher base
  205 LET l=l+(|(1,1)=8)-(|(1,1)=4)
  210 LET l=l+(t=0)-(t=30)
  215 IF l<=0 THEN LET l=0
  220 IF l>31 THEN LET l=l-1
  222 BRIGHT 1: PRINT AT 19,l; INK 1;"\l": BEEP .001,69: BRIGHT 0
  225 PRINT AT 19,l;" "
  231 IF |(2,1)=1 THEN GO TO 250
  240 PRINT AT 19,l;" "
  241 IF |(2,1)=0 THEN GO TO 120
  250 FOR c=18 TO 0 STEP -1
  261 PRINT AT c,l; INK 0;"\d"
  265 SOUND 6,15;7,7;8,16;9,16;10,12;13,4
  271 PRINT AT c,l;" "
  276 IF ATTR (c-1,l)=106 THEN GO TO 300
  280 NEXT c
  285 SOUND 8,0;7,63
  290 GO TO 129
  300 REM missile hit
  310 BEEP .01,69
  330 PRINT AT c-1,l; FLASH 1;"\e"
  331 SOUND 6,6;7,7;8,16;9,16;10,16;12,56;13,8
  332 PAUSE 55
  333 SOUND 8,0;9,0;10,0
  335 PRINT AT 19,l;" "
  340 PRINT AT c-1,l;" "
  350 LET hits=hits+1: LET f1=f1-1: PRINT AT 21,29; INK 4;"\::"
  351 SOUND 8,0;7,63
  360 PRINT AT 21,3;"hits=";hits: PRINT AT 21,28;f1
  369 PAUSE 25
  370 GO TO 129
  400 REM PRINT AT 11,10; INK 0; FLASH 1;"You're Dead"
  401 PRINT AT 11,10; INK 0; FLASH 1;"They got you!"
  405 BEEP .1,1: BEEP .1,1: BEEP .1,1: BEEP .1,1
  406 BEEP .1,1: BEEP .1,1: BEEP .1,1: BEEP .1,1
  407 BEEP .1,1: BEEP .1,1: BEEP .1,1: BEEP .75,13
  408 CLS 
  410 PRINT AT 12,1;"  Do you want another game?                                                                            press  y or n "
  420 IF INKEY$="y" THEN GO TO 30
  430 IF INKEY$="n" THEN PAPER 6: INK 0: CLS : STOP 
  440 GO TO 420
 1000 FOR n=0 TO 7
 1010 READ a: POKE USR "a"+n,a
 1020 NEXT n
 1030 DATA 129,126,219,126,60,60,90,129
 1040 FOR n=0 TO 7
 1050 READ l: POKE USR "l"+n,l
 1060 NEXT n
 1070 DATA 24,24,24,24,60,126,255,90
 1080 FOR n=0 TO 7
 1090 READ d: POKE USR "d"+n,d
 1100 NEXT n
 1110 DATA 16,16,16,16,16,16,58,40
 1120 FOR n=0 TO 7
 1130 READ e: POKE USR "e"+n,e
 1140 NEXT n
 1150 DATA 137,74,52,204,51,44,82,145
 1160 RETURN 
 1200 REM instructions
 1203 PAPER 4: CLS : PAPER 4: BORDER 6
 1205 CLS : BRIGHT 1
 1207 PAPER 4: CLS : PAPER 4: BORDER 6
 1210 PRINT AT 3,3;"You have to defend yourself    against the attacking aliens    who will re-energise out of     hyperspace above the ground      It is your job to shoot the    aliens down using your rocket    base (\l)"
 1220 PRINT AT 16,3;"PRESS ANY KEY TO CONTINUE"
 1230 REM IF INKEY$=" " THEN GO TO 1250
 1240 PAUSE 0
 1242 BRIGHT 0
 1245 CLS 
 1247 PAPER 1: INK 7: BORDER 5: CLS 
 1250 PRINT AT 09,2;"Your launcher is controlled by the left joystick. If you      allow 10 aliens to be present at the same time you will be....   "                                     
 1252 PAUSE 300: BRIGHT 1: PRINT AT 15,09; INK 2; FLASH 1;"  ELIMINATED!!": BEEP .30,1: PAUSE 480                                     
 1253 PAPER 5: CLS : PAPER 5: BORDER 1
 1254 PAPER 5: INK 0
 1255 BRIGHT 0: CLS : BEEP .1,11
 1260 PRINT AT 13,1;" ENTER SKILL LEVEL FROM 1 TO 5"
 1270 PRINT AT 15,5;"1=EASIEST   5=HARDEST"
 1280 LET a$=INKEY$
 1290 INPUT "SKILL LEVEL = ";a$
 1300 IF a$<"1" OR a$>"5" THEN GO TO 1280
 1310 LET a=VAL a$-(.33)
 1314 PAPER 7: CLS : PAPER 7
 1320 RETURN 
 9999 SAVE "aliens" LINE 1