Banner

    1 REM        BANNER 
    2 REM   FLASHWARE  \* 1984  
    3 REM RANDY/LUCY GORDON               TIMEX/SINCLAIR USERS            GROUP      CINTI.,OH.
    4 GO TO 2000
 1000 REM BYTE TO BIT CONVERSION
 1005 DATA 128,64,32,16,8,4,2,1
 1010 LET X=-J+1
 1015 RESTORE 1005
 1020 FOR P=7 TO 0 STEP -1
 1030 LET X=X+J
 1040 READ R
 1050 IF NOT A>=R THEN GO TO 1080
 1060 LET A=A-R
 1070 LET C$(X,Y TO Y+J-1)=B$ AND J>=1: LET C$(X+1,Y TO Y+J-1)=B$ AND J>=2: LET C$(X+2,Y TO Y+J-1)=B$ AND J>=3: LET C$(X+3,Y TO Y+J-1)=B$ AND J=4
 1080 NEXT P
 1400 RETURN 
 2000 REM INPUT CHARACTER
 2001 PRINT AT 3,13;"BANNER";AT 13,8;"FLASHWARE \* 1984": CIRCLE 123,110,20: PLOT 127,133: DRAW 20,0: DRAW -5,-20: DRAW -15,0: DRAW -5,-10: DRAW -8,0: DRAW -6,-17: DRAW 0,23: DRAW 6,0: DRAW 4,9: DRAW 6,0: DRAW 2,15
 2002 DIM C$(32,32)
 2003 INPUT "INPUT WIDTH; 1,2,3 OR 4 ";J
 2005 INPUT "INPUT GRAPHICS TOKEN ";B$
 2006 LET B$=(B$ AND J>=1)+(B$ AND J>=2)+(B$ AND J>=3)+(B$ AND J=4)
 2009 INPUT "INPUT MESSAGE ";A$
 2012 PRINT A$
 2016 FOR Q=1 TO LEN A$
 2017 LET Y=(13 AND J=1)+(9 AND J=2)+(5 AND J=3)+(1 AND J=4)
 2020 FOR K=7 TO 0 STEP -1
 2030 LET N=((PEEK 23606+PEEK 23607*256))+CODE A$(Q)*8+K
 2040 LET A=PEEK N
 2050 GO SUB 1000
 2055 LET Y=Y+J
 2070 NEXT K
 2076 GO SUB 3000
 2077 DIM C$(32,32)
 2079 NEXT Q
 2080 GO TO 2000
 3000 REM COPY
 3015 LET S=J*8
 3100 FOR H=1 TO S
 3105 LPRINT C$(H, TO 32)
 3110 NEXT H
 3200 RETURN 
 9990 REM     TAIL LEADER  
 9991 REM   FLASHWARE  \* 1984  
 9992 LET TIME=INT ((PEEK 23672+256*PEEK 23673+256*256*PEEK 23674)/60): LET HR=INT (TIME/60/60): LET MIN=INT ((TIME-(HR*60*60))/60): LET SEC=TIME-((MIN*60)+(HR*60*60)): PRINT AT 21,0;"ON LINE__";TAB 10;HR;":";MIN;":";SEC;"  "
 9993 IF INKEY$="" THEN GO TO 9992
 9994 STOP 
 9995 ON ERR RESET : INK 7: BORDER 1: PAPER 1: FLASH 0: INVERSE 0: OVER 0: BRIGHT 0: CLS : PRINT AT 10,8;" STOP THE TAPE ": FOR A=0 TO 5: BEEP .3,19: BEEP .3,-8: NEXT A: CLS 
 9996 GO TO 1
 9997 SAVE "BANNER" LINE 9995: REM 10/06/84