Related Articles: 2-K Bingo
Developer(s): Imre Auersbacher
Date: 1985
Type: Program
Platform(s): TS 2068
1 BORDER 5: PAPER 3: CLS
2 PRINT PAPER 6;AT 2,4;" Welcome to BING0-2068 "; PAPER 7;AT 6,11;"Options";AT 8,8;"1- Play BINGO ";AT 9,8;"2- LPRINT Cards": GO SUB 40: BEEP 0.05,15
4 INPUT "Enter option no.--> ";z: IF (z<1)+(z>2) THEN GO TO 4
6 BEEP 0.1,22: PRINT PAPER 5;AT 7+INT z,5;">>": PAUSE 90
7 GO TO 10*(z=1)+50*(z=2)
10 RANDOMIZE : DIM y$(75): LET l$="BINGO": PAPER 0: CLS
12 PRINT PAPER 7;AT 2,8;" BINGO Caller ";AT 8,9;" Call: "
15 GO SUB 40: FOR z=1 TO 75
20 LET r=INT (RND*75)+1: IF y$(r)="*" THEN GO TO 20
25 BEEP 0.05,25: PRINT PAPER 6;AT 8,15;" ";l$(INT (r/15+0.95));"-";r;" ": LET y$(r)="*"
30 IF INKEY$<>"" THEN GO TO 30
31 IF INKEY$="" THEN GO TO 31
32 IF INKEY$="q" THEN GO TO 99
35 NEXT z: STOP : STOP
40 INK 7: PLOT 3,72: DRAW 250,0: DRAW 0,100: DRAW -250,0: DRAW 0,-100: INK 0: RETURN
50 RANDOMIZE : PAPER 7: CLS
52 INPUT "How many cards? ";c
55 FOR x=1 TO c: DIM y$(75)
56 CLS : PRINT TAB 5;"B";TAB 10;"I";TAB 15;"N";TAB 20;"G";TAB 25;"O": DIM a(5): PRINT
58 FOR y=1 TO 5: PRINT
60 FOR z=1 TO 5
62 LET a(z)=INT (RND*15)+(z-1)*15+1
64 IF y$(a(z))="*" THEN GO TO 62
66 LET y$(a(z))="*": NEXT z
70 PRINT TAB 5;a(1);TAB 10;a(2);
72 IF y=3 THEN PRINT TAB 14;"FREE";
74 IF y<>3 THEN PRINT TAB 15;a(3);
76 PRINT TAB 20;a(4);TAB 25;a(5): PRINT : PRINT : NEXT y
77 FOR z=1 TO 6: PLOT 28+(z-1)*40,4: DRAW 0,171: PLOT 28,4+(z-1)*32: DRAW 199,0: NEXT z: PLOT 28,165: DRAW 199,0
78 COPY : FOR z=1 TO 5: LPRINT : NEXT z: NEXT x: GO TO 1
90 SAVE "bingo" LINE 1