Bowling

Source Code

   0  % % % %B%O%W%L%I%N%G% % %                    % %W%R%I%T%T%E%N% % %B%Y%                    % % %G%E%N%E% %B%U%Z%A% % 
  10 LET R1=0
 100 FAST 
 110 CLS 
 120 PRINT AT 1,7;"% %B%O%W%L%I%N%G% %A%V%E%R%A%G%E% "
 130 PRINT AT 4,0;"% %T%O% %I%N%I%T%I%A%L%I%Z%E% ";TAB 31;"%1"
 140 PRINT AT 6,0;"% %T%O% %E%N%T%E%R% %S%C%O%R%E%S% ";TAB 31;"%2"
 150 PRINT AT 8,0;"% %T%O% %D%I%S%P%L%A%Y% %P%L%A%Y%E%R% %D%A%T%A% ";TAB 31;"%3"
 160 PRINT AT 10,0;"% %T%O% %E%D%I%T% %D%A%T%A% ";TAB 31;"%4"
 170 PRINT AT 12,0;"% %T%O% %S%A%V%E% %O%N% %T%A%P%E% ";TAB 31;"%5"
 190 SLOW 
 200 LET Y$=INKEY$
 210 PRINT AT 21,4;"ENTER ONE OF ABOVE ::";AT 21,4;"%E%N%T%E%R% %O%N%E% %O%F% %A%B%O%V%E% %:%:"
 220 IF CODE Y$<29 OR CODE Y$>32 THEN GOTO 200
 230 FAST 
 240 CLS 
 250 GOTO VAL Y$*1000
1000 PRINT "HOW MANY WEEKS IS THE SEASON? ";
1010 SLOW 
1020 INPUT WEEKS
1030 PRINT WEEKS
1040 PRINT ,,"HOW MANY PLAYERS ON THE TEAM? ";
1050 INPUT PLAYERS
1060 PRINT PLAYERS
1100 DIM S(PLAYERS,WEEKS,3)
1110 DIM P$(PLAYERS,32)
1120 DIM T(WEEKS)
1190 CLS 
1200 FOR N=1 TO PLAYERS
1210 PRINT "NAME OF PLAYER NO.";N
1220 INPUT P$(N)
1230 PRINT P$(N)
1240 PRINT 
1250 NEXT N
1260 GOTO 100
2000 SLOW 
2010 LET R1=R1+1
2020 IF R1=WEEKS THEN GOTO 2500
2100 FOR N=1 TO PLAYERS
2110 CLS 
2120 PRINT "SCORE FOR WEEK NO.";R1;" FOR"
2130 PRINT P$(N)
2140 FOR I=1 TO 3
2150 PRINT "GAME NO.";I;
2160 INPUT S(N,R1,I)
2170 PRINT TAB 29;S(N,R1,I)
2180 PRINT 
2190 NEXT I
2200 LET T(R1)=S(N,R1,1)+S(N,R1,2)+S(N,R1,3)
2210 PRINT "SERIES =";TAB 29;T(R1)
2220 PAUSE 40000
2230 CLS 
2240 NEXT N
2250 GOTO 100
3000 IF R1=0 THEN GOTO 100
3010 PRINT AT 1,2;"% %W%H%A%T% %I%S% %T%H%E% %P%L%A%Y%E%R\:.%S% %N%A%M%E% "
3015 SLOW 
3020 INPUT N$
3025 FAST 
3030 FOR A=1 TO PLAYERS
3040 IF N$=P$(A, TO LEN N$) THEN GOTO 3100
3050 NEXT A
3060 PRINT ,,N$;" NOT IN FILE."
3070 PAUSE 40000
3080 GOTO 100
3100 CLS 
3110 PRINT "BOWLING DATA FOR :::",P$(A)
3120 FAST 
3130 LET HIGAME=0
3135 LET TPINS=0
3136 LET TGAMES=0
3140 LET HISERIES=0
3150 FOR B=1 TO R1
3160 LET SERIES=0
3170 FOR C=1 TO 3
3175 LET TGAMES=TGAMES+1
3180 LET GAME=S(A,B,C)
3185 LET TPINS=TPINS+GAME
3190 IF GAME>HIGAME THEN LET HIGAME=GAME
3200 LET SERIES=SERIES+GAME
3210 NEXT C
3220 IF SERIES>HISERIES THEN LET HISERIES=SERIES
3230 NEXT B
3300 PRINT ,,"% %H%I%G%H% %G%A%M%E% %=% ",HIGAME
3310 PRINT ,,"% %H%I%G%H% %S%E%R%I%E%S% %=",HISERIES
3320 LET AVERAGE=TPINS/TGAMES
3330 LET AVERAGE=INT (100*AVERAGE+.05)/100
3340 PRINT ,,"% %A%V%E%R%A%G%E% %=% ",AVERAGE
3400 PAUSE 40000
3410 IF INKEY$="Z" THEN COPY 
3420 GOTO 100
4000 PRINT ,,"% %W%H%A%T% %I%S% %T%H%E% %P%L%A%Y%E%R%S% %N%A%M%E%?% "
4010 SLOW 
4020 INPUT N$
4030 FAST 
4040 FOR A=1 TO PLAYERS
4050 IF N$=P$(A, TO LEN N$) THEN GOTO 4100
4060 NEXT A
4070 GOTO 3060
4100 CLS 
4110 PRINT ,,P$(A)
4120 PRINT ,,"% %C%H%A%N%G%E% %N%A%M%E%?% "
4130 PAUSE 40000
4140 IF INKEY$="Y" THEN GOTO 4900
4150 CLS 
4160 PRINT ,,"WHAT WEEK?"
4170 SLOW 
4180 INPUT WW
4190 FAST 
4220 PRINT 
4230 FOR N=1 TO 3
4240 PRINT N,S(A,WW,N)
4250 NEXT N
4260 PRINT ,,"WHICH GAME (1, 2,3 OR 0 TO EXIT)DO YOU WANT TO CHANGE?"
4265 SLOW 
4270 LET W$=INKEY$
4271 IF CODE W$<28 OR CODE W$>31 THEN GOTO 4270
4272 IF W$="0" THEN GOTO 100
4275 FAST 
4276 LET WG=VAL W$
4280 IF WG>3 OR WG<1 THEN GOTO 4270
4290 PRINT ,,"NEW GAME TOTAL?"
4295 SLOW 
4300 INPUT NG
4305 FAST 
4310 IF NG<0 OR NG>300 THEN GOTO 4295
4320 LET S(A,WW,WG)=NG
4330 GOTO 100
4900 PRINT ,,"WHAT IS THE NEW NAME?"
4905 SLOW 
4910 INPUT P$(A)
4920 GOTO 100
5000 PRINT ,,"ENTER THE FILE NAME, PEPARE THE RECORDER AND PRESS ENTER :::"
5010 SLOW 
5020 INPUT F$
5030 FAST 
5040 SAVE F$
5050 GOTO 100
9997 STOP 
9998 SAVE "BOWLIN%G"
9999 GOTO 1