Stumper

Source Code

  10 LET D$="\,,\..\,,\..\,,\..\,,\.."
  15 RAND 
  20 GOSUB 9000
  25 POKE 16418,0
  30 DIM X$(32)
  32 DIM A$(10,8)
  34 DIM B$(10,8)
  35 LET AA=0
  36 LET BB=0
  40 FAST 
  50 DIM A(10)
  60 DIM B(10)
  70 FOR N=1 TO 10
  80 LET A(N)=INT (10000000*RND*RND*RND*RND)
  85 LET C$=STR$ A(N)
  87 LET A$(N)=X$( TO 8-LEN C$)+C$
  90 LET B(N)=INT (10000000*RND*RND*RND*RND)
  95 LET C$=STR$ B(N)
  97 LET B$(N)=X$( TO 8-LEN C$)+C$
 100 PRINT AT N*2,5;A$(N);AT N*2,16;" "
 110 PRINT AT N*2,23;B$(N);AT N*2,20;" "
 120 NEXT N
 200 SLOW 
 210 FOR N=1 TO 10
 215 PRINT AT 23,0;"YOUR MOVE, HUMAN ::"
 220 LET O$=INKEY$
 230 IF CODE O$<28 OR CODE O$>37 THEN GOTO 220
 235 PRINT AT 23,0;X$
 240 LET O=VAL O$+1
 250 IF A$(O)="        " THEN GOTO 220
 260 PRINT AT O*2,5;D$
 300 FOR I=1 TO 10
 310 IF B(I)=0 THEN GOTO 330
 320 IF B(I)>A(O) THEN GOTO 400
 330 NEXT I
 340 FOR I=1 TO 10
 350 IF B(I)>0 THEN GOTO 400
 360 NEXT I
 400 PRINT AT I*2,23;D$
 410 PRINT AT 22,3;A$(O)
 420 PRINT AT 22,23;B$(I)
 430 IF A(O)>B(I) THEN LET AA=AA+1
 440 IF B(I)>A(O) THEN LET BB=BB+1
 450 IF A(O)>B(I) THEN PRINT AT N*2,16;"%*";
 460 IF B(I)>A(O) THEN PRINT AT N*2,20;"%*";
 500 LET A$(O)="        "
 510 LET B$(I)="        "
 520 LET A(O)=0
 530 LET B(I)=0
 590 NEXT N
 600 PRINT AT 23,0;X$
 610 IF AA>BB THEN GOTO 700
 620 IF BB>AA THEN GOTO 800
 630 PRINT AT 23,0;"DRAW GAME, HUMAN - PRESS ENTER"
 640 PAUSE 40000
 650 PRINT AT 23,0;X$
 660 PRINT AT 22,0;X$
 670 LET AA=0
 680 LET BB=0
 690 GOTO 70
 700 LET D=20*(INT (3*RND)+1)
 710 GOTO 700+D
 720 PRINT AT 23,0;"YOU LUCKED OUT, PRESS ENTER"
 730 GOTO 640
 740 PRINT AT 23,0;"YOU WONT WIN AGAIN, PRESS ENTER"
 750 GOTO 640
 760 PRINT AT 23,0;"YOU CHEATED, PRESS ENTER"
 770 GOTO 640
 800 LET D=20*(INT (3*RND)+1)
 810 GOTO 800+D
 820 PRINT AT 23,0;"I WIN (AS USUAL), PRESS ENTER"
 830 GOTO 640
 840 PRINT AT 23,0;"GIVE UP, I\ 'LL WIN ANYWAY"
 850 GOTO 640
 860 PRINT AT 23,0;"HO HUM, THIS IS GETTING BORING"
 870 GOTO 640
 998 PAUSE 40000
 999 GOTO 999
9000 FAST 
9005 CLS 
9010 FOR Y=0 TO 43 STEP 4
9020 FOR X=9 TO 63
9030 PLOT X,Y
9040 NEXT X
9050 NEXT Y
9060 FOR X=9 TO 63 STEP 18
9070 FOR Y=0 TO 40
9080 PLOT X,Y
9090 NEXT Y
9100 NEXT X
9110 FOR N=1 TO 10
9120 PRINT AT N*2,0;N-1
9130 NEXT N
9140 PRINT AT 0,8; "YOU             STUMPER"
9160 RETURN 
9998 SAVE "STUMPE%R"
9999 RUN