3 Games

Gallery

Source Code

  50 REM "A"
 100 LET A$="*"
 105 LET N=0
 110 LET A=0
 115 LET B=0
 120 LET C=0
 125 LET D=0
 130 LET T=1
 135 LET X=12
 160 LET R=INT (RND*27)
 170 PRINT AT 21,R;A$
 180 SCROLL 
 190 SCROLL 
 200 LET N=N+T
 205 IF N=100 THEN LET A$="\.'\. "
 210 IF N=104 THEN LET T=2
 215 LET E=D
 220 LET D=C
 230 LET C=B
 240 LET B=A
 250 LET A=R
 255 PRINT AT 9,X-2;"      "
 260 PRINT AT 11,X;"\'.\.'"
 270 IF X>=E-2 AND X<=E+T THEN GOTO 500
 280 IF INKEY$="5" THEN LET X=X-T
 290 IF INKEY$="8" THEN LET X=X+T
 300 GOTO 160
 500 PRINT AT 11,X-1;"CRASH"
 510 PRINT AT 0,0;"SCORE=";N
 520 CLEAR 
 530 PAUSE 100
 540 FAST 
 550 CLS 
 560 SLOW 
 570 RUN 

   1 REM "LB"
   5 FAST 
  10 RAND 0
  20 DIM A(66)
  30 PRINT AT 2,9;"LONDON BRIDGE"
  40 LET WR=1700
  50 PRINT AT 16,25;"WR=";WR;TAB 11;"\@@       \@@";TAB 0;"INPUT";TAB 1;"123";TAB 1;"4%56";TAB 1;"789"
  55 PRINT AT 6,11;"\@@\@@  %   \@@\@@"
  60 FOR I=1 TO 11
  70 PRINT TAB 12;"\@@     \@@"
  80 NEXT I
  90 FOR N=11 TO 60
 100 LET A(N)=INT (RND*5+1)
 110 LET A$=CHR$ (28+A(N))
 120 LET M=(N-1)/5
 130 GOSUB 500
 135 NEXT N
 140 LET N=8
 145 SLOW 
 150 LET A(N)=-28
 155 PRINT AT 20,20;"TO COLLAPSE"
 160 LET DROP=INT (RND*(67-N)+N-6)
 170 IF A(DROP)<=0 THEN GOTO 160
 180 PRINT TAB 25;A(DROP)
 190 INPUT DIR
 200 LET I=(INT DIR-1)/3
 205 LET M=(N-1)/5
 210 LET J=M-INT M+I-INT I
 220 LET N1=N+5*(INT I-1)+3*(I-INT I)-1
 230 IF DIR<1 OR DIR>9 OR J<0.1 OR J>1.4 OR N1<6 THEN GOTO 190
 235 IF A(N1)<=0 AND N1<=60 THEN GOTO 190
 240 IF N1>60 THEN LET A(N1)=-28
 250 LET A$=CHR$ (28+A(N))
 260 GOSUB 500
 270 LET M=(N1-1)/5
 280 LET A$=CHR$ (156+A(N1))
 290 GOSUB 500
 300 PRINT AT 20,20;"           ";TAB 25;" "
 310 FOR J=1 TO 70
 320 NEXT J
 330 LET M=(DROP-1)/5
 350 LET A$=" "
 360 GOSUB 500
 370 IF N1=DROP THEN GOTO 600
 380 IF N1>60 THEN GOTO 800
 390 LET SCORE=10*(3-INT I)+10*(2-INT I)*(1-INT I)
 400 IF A(N1)=A(DROP) THEN LET SCORE=SCORE*3
 410 GOSUB 900
 420 LET A(DROP)=0
 430 LET N=N1
 440 GOTO 155
 500 PRINT AT 5+INT M,13+5*(M-INT M);A$
 510 RETURN 
 600 PRINT AT 20,16;"YOU HAVE FALLEN";TAB 18;"IN THE WATER"
 700 STOP 
 800 LET SCORE=1000
 810 GOSUB 900
 820 STOP 
 900 LET A(1)=A(1)+SCORE
 910 PRINT AT 11,22;"SCORE ";SCORE;" "
 920 PRINT AT 13,22;"TOTAL ";A(1)
 930 RETURN 

  10 REM "SP"
  20 LET X=32
  30 LET Y=22
  40 GOSUB 500
  50 UNPLOT X,Y
  60 PLOT X,Y
  70 GOTO 40
  80 GOSUB 500
  90 GOTO 80
 100 GOSUB 500
 110 PLOT X,Y
 120 UNPLOT X,Y
 130 GOTO 100
 500 IF INKEY$="1" THEN GOTO 40
 510 IF INKEY$="2" THEN GOTO 80
 520 IF INKEY$="3" THEN GOTO 600
 530 IF INKEY$="0" THEN GOTO 100
 540 IF INKEY$="5" THEN LET X=X-1
 550 IF INKEY$="6" THEN LET Y=Y-1
 555 IF Y=43 THEN GOTO 565
 560 IF INKEY$="7" THEN LET Y=Y+1
 565 IF X=63 THEN GOTO 590
 570 IF INKEY$="8" THEN LET X=X+1
 590 RETURN 
 600 COPY