Checkbook Balancer

Gallery

Source Code

    5 REM John Colonna, SINCUS
   10 REM checkbal  VER. 1.4
   20 BORDER 5: CLS 
   30 LET x=3: LET t=0: LET d=0
   40 GO SUB 450
   50 PRINT "      CHECKBOOK  BALANCER"
   60 GO SUB 450
   70 PRINT TAB 7;"BEFORE YOU BEGIN-"
   80 PRINT 
   90 PRINT AT 9,2;"1. Adjust checkbook for fees, checks, or deposits not recorded"
  100 PRINT AT 12,2;"2. Arrange cancelled checks innumerical order."
  110 PRINT AT 15,2;"3. Compare checks with your   records."
  120 PRINT AT 18,2;"4. Obtain last bank statement."
  130 PRINT AT 20,3; FLASH 1;"Press any key to continue"
  140 PAUSE 0
  150 CLS 
  160 FOR j=1 TO 22
  170 PRINT TAB 0; PAPER 1;"              "
  180 NEXT j
  190 PRINT AT 0,1;"OUTSTANDING"
  200 PRINT AT 1,3;"CHECKS"
  210 PRINT AT 2,2;"#";AT 2,7;"Amt."
  220 FOR i=1 TO i
  230 INPUT "Enter check number (Enter '0'   when completed) #";c: PRINT AT x,1;c: IF c=0 THEN GO TO 270
  240 INPUT "Indicate amount $";a: PRINT AT x,7;a
  250 LET x=x+1: LET t=t+a
  260 NEXT i
  270 PRINT AT x+1,0;"TOTAL";" $";t
  280 INPUT "Enter balance from statement    $";b: PRINT AT 1,15;"STATEMENT": PRINT AT 2,16;"BALANCE  ";b
  290 FOR i=1 TO i
  300 INPUT "Enter recent deposits not shown on statement (Enter '0' when    completed) $";r: IF r=0 THEN GO TO 330
  310 LET d=d+r
  320 NEXT i
  330 PRINT AT 4,16;"RECENT"
  340 PRINT AT 5,15;"DEPOSITS +";d
  350 PRINT AT 5,25; OVER 1;"______"
  360 LET s=b+d
  370 PRINT AT 7,17; INVERSE 1;"TOTAL"; INVERSE 0;"   ";s
  380 LET p=s-t: LET p=INT (p*100+.5)/100
  390 PRINT AT 9,17;"OUT."
  400 PRINT AT 10,16;"CHECKS  -";t
  410 PRINT AT 10,25; OVER 1;"______"
  420 PRINT AT 12,16; INVERSE 1;"BALANCE"; INVERSE 0;AT 12,25;p
  430 PRINT AT 14,17; PAPER 5;"YOUR PRESENT";AT 16,15;"CHECKBOOK BALANCE";AT 18,19;"SHOULD BE";AT 20,20;"$";p
  435 INPUT "COPY or AGAIN? (C/A) ";a$ 
  440 IF a$="c" OR a$="C" THEN COPY 
  443 IF a$="a" OR a$="A" THEN GO TO 20
  445 GO TO 435
  450 PRINT 
  470 FOR i=1 TO 16: PRINT "$$";: NEXT i
  490 PRINT : PRINT 
  500 RETURN 
 9999 CLEAR : CLS : SAVE "checkbal" LINE 1: BEEP 1,32: PRINT : PRINT INVERSE 1;"Rewind to VERIFY": VERIFY "checkbal": PRINT FLASH 1;" V E R I F I E D ": BEEP .5,32: BEEP .5,32