Crasher

Gallery

Source Code

   0 REM "CRASHER"                        PROGRAM CORE BY TIM             HARTNELL                        REVISIONS, INSTRUCTION          AND MOVING GRAPHIC              SCREENS BY                      ANTHONY WILLING
   3 CLS 
   5 LET HS=0
  10 GOTO 9000
  20 PRINT "%I%N%S%T%R%U%C%T%I%O%N%S%? (Y/N)"
  30 INPUT U$
  40 IF U$="Y" THEN GOTO 51
  50 IF U$="N" THEN GOTO 155
  55 IF U$="" THEN GOTO 20
  60 CLS 
  70 PRINT AT 0,0;"%C%R%A%S%H%E%R";AT 1,0;"-------"
  80 PRINT 
  85 PRINT 
  90 PRINT "YOU ARE THE ""V"".  YOUR JOB--"
  95 PRINT "CRASH INTO LETTERS AND NUMBERS,"
 100 PRINT "WHICH SCORES POINTS."
 105 PRINT 
 110 PRINT "YOU STEER WITH THE ""5"" AND ""8"""
 115 PRINT "KEYS"
 120 PRINT 
 125 PRINT "AVOID THE %I%N%V%E%R%S%E CHARACTERS--"
 130 PRINT "THEY ARE A MUTATED LIFE FORM,"
 135 PRINT "AND HITTING ONE OF THEM HEAD ON"
 137 PRINT "WILL END THE GAME"
 140 PRINT 
 141 PRINT "THE SCREEN WILL SHIFT 100 TIMES,"
 142 PRINT "THEN THE GAME ENDS."
 145 GOSUB 9900
 147 PRINT 
 148 PRINT 
 150 GOSUB 9900
 155 GOSUB 9900
 156 PRINT AT 20,11;"%R%E%A%D%Y%?%?"
 157 GOSUB 9900
 160 CLS 
 170 LET X=10
 180 LET Y=10
 190 LET S=0
 200 LET F=S
 210 LET F=F+1
 220 PRINT AT 20,INT (RND*20);CHR$ (INT (RND*63+1)+(128 AND RND<.2));AT Y,X;" "
 230 SCROLL 
 240 LET X=X+(INKEY$="8" AND X<19)-(INKEY$="5" AND X>0)
 250 PRINT AT Y,X;"V";AT Y+1,X;
 260 LET A=PEEK (PEEK 16398+256*PEEK 16399)
 270 IF A<64 THEN LET S=S+A
 274 IF A>127 THEN GOSUB 2700
 279 IF A>127 THEN GOTO 290
 280 IF F<100 THEN GOTO 210
 290 CLS 
 310 IF S>HS THEN LET HS=S
 330 PRINT "%G%A%M%E% %O%V%E%R","%S%C%O%R%E" 
 340 PRINT " ",S
 350 PRINT 
 360 PRINT "%H%I%G%H% %S%C%O%R%E ";HS
 370 PRINT 
 380 PRINT AT 11,0;"%L%I%K%E% %A%N%O%T%H%E%R% %T%R%Y%?%? (Y/N)"
 385 PRINT AT 15,0;"(%E%N%T%E%R INS %F%O%R% %I%N%S%T%R%U%C%T%I%O%N%S)"
 390 INPUT U$
 400 IF U$="Y" THEN GOTO 155
 410 IF U$="N" THEN GOTO 2000
 420 IF U$="INS" THEN GOTO 60
2000 CLS 
2009 PRINT AT 11,0;"% ";AT 11,30;"% "
2010 FOR E=1 TO 15
2015 PRINT AT 11,E-1;" ";AT 11,31-E;" "
2020 PRINT AT 11,E;"% ";AT 11,30-E;"% "
2030 NEXT E
2050 FOR Q=1 TO 20
2060 FAST 
2070 PRINT AT 11,14;"%  % "
2080 SLOW 
2090 NEXT Q
2100 PRINT AT 11,13;"%    % "
2110 PRINT AT 10,13;"/   /"
2115 PRINT AT 9,14;"*   *"
2120 PRINT AT 12,14;"OWW"
2125 GOSUB 9900
2130 CLS 
2135 PRINT AT 11,11;"%C%R%A%S%H%E%R"
2140 GOSUB 9900
2145 PRINT AT 11,10;"%G%A%M%E% %O%V%E%R"
2150 POKE 16384,74
2699 STOP 
2700 FOR Q=1 TO 20
2710 FAST 
2720 SLOW 
2730 NEXT Q
2735 PRINT AT 11,10;"%C%R%A%S%H"
2736 GOSUB 9900
2740 RETURN 
8999 STOP 
9000 PRINT AT 0,11;"%C%R%A%S%H%E%R";AT 20,11;"%C%R%A%S%H%E%R"
9010 GOSUB 9900
9020 FOR G=0 TO 9
9025 PRINT AT G-1,11;"       ";AT 21-G,11;"       "
9030 PRINT AT G,11;"%C%R%A%S%H%E%R";AT 20-G,11;"%C%R%A%S%H%E%R"
9045 PRINT AT 9,11;"       ";AT 11,11;"       "
9050 NEXT G
9060 PRINT AT 10,11;"%C%R%A%S%H%E%R"
9070 FOR Q=1 TO 20
9080 FAST 
9090 SLOW 
9100 NEXT Q
9110 GOSUB 9900
9115 GOSUB 9900
9120 PRINT AT 10,11;"       "
9130 GOTO 11
9900 FOR P=1 TO 50
9910 NEXT P
9920 RETURN 
9990 STOP 
9991 CLEAR 
9992 SAVE "1019%5"
9993 RUN