Hammer-Dialer

Source Code

    1 GO TO 5
    2 REM  To save the MTERM MACROKEYS and XLATE TABLES and all other settings you must first POKE 54066 to 54101 to zero to eliminate the terminal program initialization of these variables, then when you RAND USR to there all your current settings will be intact and ready (as if just loaded from within the terminal program). 
    3 REM  Also to save settings  as a part of MTERM you must SAVE "Mterm" CODE 54016,9984 
    5 CLS : OUT 119,0: PRINT "HAMMER-DIALER"
    6 PRINT : RESTORE 2000: ON ERR GO TO 10: FOR x=1 TO 20: READ a$: PRINT CHR$ (96+x);" ";a$: READ a$: NEXT x
   10 ON ERR RESET : INPUT "NUMBER to harrass: ";a$: PRINT : PRINT a$: PRINT : IF a$="" THEN GO TO 5
   11 IF CODE a$<65 THEN OUT 119,0: STOP 
   12 IF CODE a$=65 OR CODE a$=97 THEN RANDOMIZE USR 54016
   13 IF CODE a$>64 THEN GO SUB 3000
   15 OUT 119,31
   16 PRINT b$
   20 FOR i=1 TO LEN a$
   30 LET a=VAL a$(i): PRINT a$(i);
   32 IF a=0 THEN LET a=10
   35 PAUSE 25
   40 GO SUB 60
   50 NEXT i
   55 GO TO 150
   60 FOR d=1 TO a
   70 FOR e=3 TO 4
   80 OUT 119,e
   90 PAUSE 3.5
  100 NEXT e
  110 OUT 119,1
  120 OUT 119,2
  130 NEXT d
  140 RETURN 
  150 FOR x=1 TO 10
  155 IF INKEY$<>"" THEN GO TO 200
  160 PAUSE 90: BEEP .05,-30
  170 IF IN 119>=128 THEN POKE 61699,21: FOR x=1 TO 10: BEEP .05,30: NEXT x: RANDOMIZE USR 54016
  180 NEXT x
  190 OUT 119,0: PAUSE 360: BEEP .1,1: BEEP .1,1: POKE 23692,255: PRINT : PRINT : GO TO 15
  200 OUT 119,0: PAUSE 30: RUN 
 1144 LOAD "e-z term"CODE 
 1145 INK 7: BORDER 0: PAPER 0: CLS : PRINT AT 3,9;"HAMMER-DIALER";AT 14,8;"FLASHWARE \* 1986": CIRCLE 123,110,20: PLOT 127,133: DRAW 20,0: DRAW -5,-20: DRAW -15,0: DRAW -5,-10: DRAW -8,0: DRAW -6,-17: DRAW 0,23: DRAW 6,0: DRAW 4,9: DRAW 6,0: DRAW 2,15: BEEP .2,10: BEEP .2,5: BEEP .2,2: PAUSE 4: BEEP .2,10: BEEP .2,5: BEEP .2,2: PAUSE 8: BEEP .2,10: BEEP .2,5: BEEP .2,2: BEEP .2,5: BEEP .2,10: BEEP .2,10
 1146 RUN 
 2000 REM  DATA LIST (limit 19 numbers)+ RUN MTERM 
 2001 DATA " RUN MTERM ","x"
 2002 DATA "Cin-Comm","2317013"
 2003 DATA "Coconut","9848705"
 2004 DATA "Cinsoft Online","3967467"
 2005 DATA "CINTUG","4742985"
 2006 DATA "Commodore Connection","7520837"
 2007 DATA "Annie's BBS","5211151"
 2008 DATA "Dragon's Nest","8315468"
 2009 DATA "MYSTERY BBS","7731952"
 2010 DATA "REACTOR","2831178"
 2011 DATA "SAMS VIDEO ARCADE","4517513"
 2012 DATA "MYTH FOUNDATION","7770744"
 2013 DATA "THE SALAMANDER","5753395"
 2014 DATA "Komputer Klassified","4898433"
 2015 DATA "M*A*S*H 4077th","7538364"
 2016 DATA "END OF UNIVERSE","7777020"
 2017 DATA "HILL TOP LITE","4711938"
 2018 DATA "ORACLE","9214238"
 2019 DATA "TIGER's DEN","4743676"
 3000 LET a=CODE a$-96
 3010 RESTORE 2000
 3020 FOR x=1 TO a: READ a$: LET b$=a$ AND x=a: READ a$: NEXT x: RETURN 
 9997 SAVE "HAMMERDIAL" LINE 1144: SAVE "e-z term"CODE 54016,9984: REM rev. date 02/22/86 \* FLASHWARE Randy/Lucy Gordon (CompuServe ID 71106,262)