Analyze multiple investment types and financial products.
Appears on
Library tape of the Indiana Sinclair Timex User’s Group.
Library tape from the Sinclair Computer Users Society (SINCUS).
Gallery
Source Code
5 REM "B-9" from Carl Terry SINCUS, 1984
6 FOR F=26714 TO 26714+PEEK 26712: IF PEEK F=94 THEN POKE F,6
7 NEXT F: STOP
10 BORDER 0: PAPER 0: INK 7: CLS
15 POKE 23652,10
20 CLEAR
25 PRINT TAB 10;"____MENU___"''
30 PRINT " 1-COMPOUND INTEREST"''
35 PRINT " 2-LOAN DATA SUB MENU"''
40 PRINT " 3-MONTHLY PAYMENT TO AN ACCOUNT"''
45 PRINT " 4-PRESENT VALUE OF A BOND"''
50 PRINT " 5-ANNUITY DATA SUB MENU"''
55 PRINT " 6-DEPOSIT TO REACH GOAL"''
60 PRINT " 7-WEEK/MONTH/YEAR INC OR EXP"'
65 PRINT '" 8-LIFE INSURANCE ESTIMATER"'
70 PRINT '" 9-CALENDAR/ANALYZE UTILITY BILL"'
75 IF INKEY$>"9" OR INKEY$<"1" THEN GO TO 75
80 GO TO (225 AND INKEY$="1")+(130 AND INKEY$="2")+(680 AND INKEY$="3")+(1385 AND INKEY$="4")+(185 AND INKEY$="5")+(1920 AND INKEY$="6")+(2100 AND INKEY$="7")+(2425 AND INKEY$="8")+(2800 AND INKEY$="9")
125 IF INKEY$>"7" OR INKEY$<"1" THEN GO TO 75
130 CLS : REM LOAN DATA SUB MENU
135 PRINT ;" ___LOAN DATA SUB MENU___"
140 PRINT ''" 1-REDUCTION OF PRINCIPAL AND INTEREST AS PAYMENTS ARE MADE"''
145 PRINT " 2-EARLY PAYOFF"''
150 PRINT " 3-MAIN MENU"
155 PAUSE 0
160 GO TO (680 AND INKEY$="1")+(1190 AND INKEY$="2")+(20 AND INKEY$="4")
175 IF INKEY$<"1" OR INKEY$>"3" THEN GO TO 160
185 CLS : PRINT ;" ___ANNUITY DATA SUB MENU___": REM ANNUNITY SUB MENU
190 PRINT '''" 1-PRESENT VALUE OF AN ANNUITY"''
195 PRINT " 2-FUTURE VALUE OF AN ANNUITY"''
200 PRINT " 3-MAIN MENU"
205 IF INKEY$<"1" OR INKEY$>"3" THEN GO TO 205
210 GO TO (1590 AND INKEY$="1")+(1760 AND INKEY$="2")+(20 AND INKEY$="3")
225 BORDER 0
230 PAPER 0
235 INK 7
240 CLS : REM COMPOUND INTEREST
245 PRINT TAB 7;"COMPOUND INTEREST"''
250 LPRINT TAB 7;"COMPOUND INTEREST"''
255 PRINT "ENTER PRINCIPAL?"
260 LPRINT "ENTER PRINCIPAL?"
265 INPUT A
270 PRINT "$";A''
275 LPRINT "$";A''
280 PRINT "ENTER INTEREST(in decimal form)"
285 LPRINT "ENTER INTEREST(in decimal form)"
290 INPUT B
295 PRINT B*100;"%"''
300 LPRINT B*100;"%"''
305 PRINT "COMPOUND PERIOD-1-YEARLY -2-MONTHLEY -3-QUARTERLY -4-DAILY"
310 LPRINT "COMPOUND PERIOD-1-YEARLY -2-MONTHLEY -3-QUARTERLY -4-DAILY"
315 INPUT C
320 PRINT C'
325 LPRINT C'
330 IF C=1 THEN LET D=B
335 IF C=2 THEN LET D=B/12
340 IF C=3 THEN LET D=B/4
345 IF C=4 THEN LET D=B/360
350 PRINT "LENGTH OF TIME IN ABOVE UNITS ?"
355 LPRINT "LENGTH OF TIME IN ABOVE UNITS ?"
360 INPUT F
365 PRINT F''
370 LPRINT F''
375 LET G=A*(1+D)^F
380 LET H=G-A
385 PRINT "NEW BALANCE","INTEREST EARNED"'
390 LPRINT "NEW BALANCE","INTEREST EARNED"'
395 PRINT FLASH 1;"$";INT (100*G+.5)/100,"$";INT (100*H+.5)/100
400 LPRINT ;"$";INT (100*G+.5)/100,"$";INT (100*H+.5)/100
405 INPUT "PRESS ENTER FOR MENU";Z$
410 GO TO 20
525 CLS : REM LOAN PAYMENTS
530 PRINT TAB 3;"LOAN PAYMENTS"
535 LPRINT TAB 3;"LOAN PAYMENTS"
540 PRINT TAB 6;"TO ZERO"''
545 LPRINT TAB 6;"TO ZERO"''
550 PRINT "PRINCIPAL?"'
555 LPRINT "PRINCIPAL?"'
560 INPUT A
565 PRINT "$";A''
570 LPRINT "$";A''
575 PRINT "INTEREST RATE(decimal form)"'
580 LPRINT "INTEREST RATE(decimal form)"'
585 INPUT B
590 PRINT B*100;"%"''
595 LPRINT B*100;"%"''
600 PRINT "NUMBER OF YEARS?"'
605 LPRINT "NUMBER OF YEARS?"'
610 INPUT T
615 PRINT T''
620 LPRINT T''
625 LET E=B/12
630 LET R=T*12
635 LET P=A/((1-(1/1+E)^-R)/E)
640 LET P=INT (100*P+.5)/100
645 PRINT "MONTHLY PAYMENT"'
650 LPRINT "MONTHLY PAYMENT"'
655 PRINT FLASH 1;"$";P
660 LPRINT ;"$";P
665 FLASH 0
670 GO TO 405
680 CLS
685 PRINT TAB 10;"MONTHLY PAYMENT"'''
690 LPRINT TAB 10;"MONTHLY PAYMENT"'''
695 PRINT "ENTER PRINCIPAL?"
700 LPRINT "ENTER PRINCIPAL?"
705 INPUT A
710 PRINT "$";A''
715 LPRINT "$";A''
720 PRINT "INTEREST RATE(decimal form)"'
725 LPRINT "INTEREST RATE(decimal form)"'
730 INPUT B
735 PRINT B*100;"%"''
740 LPRINT B*100;"%"''
745 PRINT "MONTHLY PAYMENT?"'
750 LPRINT "MONTHLY PAYMENT?"'
755 INPUT C
760 PRINT "$";C'''
765 LPRINT "$";C'''
770 PRINT "Do you want to print the resultswith no stopping? If so ENTER ""GO"", otherwise just press ENTER"
775 LET go=NOT PI
780 POKE 23658,8
785 INPUT """GO"" or just ENTER ";z$
790 IF z$="GO" OR z$="go" THEN LET go=1
795 PAUSE go
800 CLS
805 LET X=A
810 FOR N=NOT PI TO 1
815 LET K=NOT PI
820 LET K=K+20
825 LET D=B/12
830 LET E=D*A
835 LET L=E+A
840 LET F=L-C
845 IF N=NOT PI THEN LET E=NOT PI
850 IF N=NOT PI THEN LET F=A
855 PRINT N;TAB 5;"$";INT (100*F+.5)/100;TAB 17;N;TAB 22;"$";INT (100*E+.5)/100
860 LPRINT N;TAB 5;"$";INT (100*F+.5)/100;TAB 17;N;TAB 22;"$";INT (100*E+.5)/100
865 IF F<=1 THEN GO TO 905
870 IF K=N THEN GO TO 890
875 LET N=N+1
880 LET A=F
885 GO TO 830
890 PAUSE go
895 CLS
900 GO TO 820
905 LET M=C*N
910 LET P=M-X
915 PAUSE go
920 CLS
925 PRINT N;" PAYMENTS WERE MADE"''''''
930 LPRINT N;" PAYMENTS WERE MADE"''''''
935 PRINT "TOTAL AMOUNT PAID WAS--"; FLASH 1;"$";INT (100*M+.5)/100; FLASH 0;
940 LPRINT "TOTAL AMOUNT PAID WAS--";"$";INT (100*M+.5)/100;
945 PRINT " OF THIS---"; FLASH 1;" $";INT (100*P+.5)/100; FLASH 0;" WAS INTEREST"
950 LPRINT " OF THIS--- $";INT (100*P+.5)/100;" WAS INTEREST"
955 INPUT "PRESS ENTER FOR MENU";Z$
960 GO TO 130
965 CLS : REM MONTHLY DEPOSIT
970 PRINT TAB 7;"MONTHLY DEPOSIT"''
975 LPRINT TAB 7;"MONTHLY DEPOSIT"''
980 PRINT "MONTHLY DEPOSIT"'
985 LPRINT "MONTHLY DEPOSIT"'
990 INPUT A
995 PRINT "$";A'
1000 LPRINT "$";A'
1005 PRINT "INTEREST RATE?(decimal form)"'
1010 LPRINT "INTEREST RATE?(decimal form)"'
1015 INPUT B
1020 PRINT B'
1025 LPRINT B'
1030 PRINT "PRESENT BALANCE"'
1035 LPRINT "PRESENT BALANCE"'
1040 INPUT C'
1045 PRINT "$";C'
1050 LPRINT "$";C'
1055 PRINT "NUMBER OF YEARS"'
1060 LPRINT "NUMBER OF YEARS"'
1065 INPUT T
1070 PRINT T
1075 LPRINT T
1080 CLS
1085 FOR N=NOT PI TO 1
1090 LET K=NOT PI
1095 LET K=K+20
1100 LET D=A+C
1105 LET E=B/12
1110 IF N=NOT PI THEN LET E=NOT PI
1115 LET F=D*E
1120 LET G=F+D-(E*A)
1125 PRINT N;TAB 5;"$";INT (100*G+.5)/100
1130 LPRINT N;TAB 5;"$";INT (100*G+.5)/100
1135 LET L=K
1140 LET R=T*12
1145 IF N=R-1 THEN GO TO 405
1150 IF L=N THEN GO TO 1175
1155 LET N=N+1
1160 LET C=G
1165 GO TO 1100
1170 CLS
1175 GO TO 1095
1190 REM EARLY PAYOFF
1195 CLS
1200 PRINT ''
1205 LPRINT ''
1210 PRINT TAB 10;"EARLY PAYOFF"''
1215 LPRINT TAB 10;"EARLY PAYOFF"''
1220 PRINT "MONTHLY PAYMENT"
1225 INPUT A
1230 PRINT "$";: PRINT A''
1235 LPRINT "$";: PRINT A''
1240 PRINT "INTEREST RATE(decimal form)"
1245 LPRINT "INTEREST RATE(decimal form)"
1250 INPUT B
1255 PRINT B''
1260 LPRINT B''
1265 PRINT "NUMBER OF PAYMENTS MADE"
1270 LPRINT "NUMBER OF PAYMENTS MADE"
1275 INPUT C
1280 PRINT C''
1285 LPRINT C''
1290 PRINT "TOTAL NUMBER OF PAYMENTS"'
1295 LPRINT "TOTAL NUMBER OF PAYMENTS"''
1300 INPUT D
1305 PRINT D''
1310 LPRINT D''
1315 LET I=B/12
1320 LET K=C-D
1325 LET X=A*((1-(1+I)^K)/I)
1330 LET F=(D-C)*A
1335 LET G=F-X
1340 PRINT "EARLY PAYOFF",
1345 LPRINT "EARLY PAYOFF",
1350 PRINT "$";INT (100*X+.5)/100''
1355 LPRINT "$";INT (100*X+.5)/100''
1360 FLASH 1: PRINT "MONEY SAVED",: PRINT "$";INT (100*G+.5)/100
1365 LPRINT "MONEY SAVED",: PRINT "$";INT (100*G+.5)/100
1370 FLASH 0
1375 INPUT "PRESS ENTER FOR MENU";Z$
1380 GO TO 130
1385 CLS : REM PRESENT BOND VAL
1390 PRINT '
1395 LPRINT '
1400 PRINT TAB 8;"PRESENT VALUE OF"
1405 LPRINT TAB 8;"PRESENT VALUE OF"
1410 PRINT TAB 13;"A BOND"''
1415 LPRINT TAB 13;"A BOND"''
1420 PRINT " BOND FACE VALUE"
1425 LPRINT " BOND FACE VALUE"
1430 INPUT D
1435 PRINT "$";D''
1440 LPRINT "$";D''
1445 PRINT "SEMI-ANNUAL RECIEPT"
1450 LPRINT "SEMI-ANNUAL RECIEPT"
1455 INPUT A
1460 PRINT TAB 16;"$";A''
1465 LPRINT TAB 16;"$";A''
1470 PRINT "INTEREST RATE?(decimal form)"',
1475 LPRINT "INTEREST RATE?(decimal form)"',
1480 INPUT B
1485 PRINT B*100;"%"''
1490 LPRINT B*100;"%"''
1495 PRINT "NUNBER OF YEARS TO MATURITY"
1500 LPRINT "NUNBER OF YEARS TO MATURITY"
1505 INPUT T
1510 PRINT TAB 16;T''
1515 LPRINT TAB 16;T''
1520 LET N=T*2
1525 LET C=B/2
1530 LET R=A*(1-(1/(1+C))^N)/C
1535 LET Q=D/(1+C)^N
1540 LET P=R+Q
1545 PRINT TAB 7;"PRESENT VALUE OF "
1550 LPRINT TAB 7;"PRESENT VALUE OF "
1555 PRINT TAB 10;"THE BOND IS"'
1560 LPRINT TAB 10;"THE BOND IS"'
1565 PRINT TAB 11; FLASH 1;"$";INT (100*P+.5)/100
1570 LPRINT TAB 11; FLASH 1;"$";INT (100*P+.5)/100
1575 FLASH 0
1580 GO TO 405
1590 CLS : REM PRESENT ANNUITY
1595 PRINT ''
1600 LPRINT ''
1605 PRINT TAB 8;"PRESENT VALUE OF"
1610 LPRINT TAB 8;"PRESENT VALUE OF"
1615 PRINT TAB 10;"AN ANNUITY"''
1620 LPRINT TAB 10;"AN ANNUITY"''
1625 PRINT " MONTHLY RECEIPT?"
1630 LPRINT " MONTHLY RECEIPT?"
1635 INPUT A
1640 PRINT " $";A''
1645 LPRINT " $";A''
1650 PRINT "INTEREST RATE?(decimal form)"
1655 LPRINT "INTEREST RATE?(decimal form)"
1660 INPUT B
1665 PRINT TAB 1;B*100;"%"''
1670 LPRINT TAB 1;B*100;"%"''
1675 PRINT " NUMBER OF YEARS?"
1680 LPRINT " NUMBER OF YEARS?"
1685 INPUT T
1690 PRINT TAB 1;T''
1695 LPRINT TAB 1;T''
1700 LET N=T*12
1705 LET C=B/12
1710 LET P=A*(1-(1/(1+C))^N)/C
1715 PRINT TAB 8;"PRESENT VALUE OF"
1720 LPRINT TAB 8;"PRESENT VALUE OF"
1725 PRINT TAB 9;"THE ANNUITY IS:"
1730 LPRINT TAB 9;"THE ANNUITY IS:"
1735 PRINT TAB 10; FLASH 1;"$";INT (100*P+.5)/100
1740 LPRINT TAB 10;"$";INT (100*P+.5)/100
1745 FLASH 0
1750 INPUT "PRESS ENTER FOR MENU";Z$
1755 GO TO 185
1760 CLS : REM FUTURE ANNUITY VA
1765 PRINT ''
1770 LPRINT ''
1775 PRINT TAB 8;"FUTURE VALUE OF"
1780 LPRINT TAB 8;"FUTURE VALUE OF"
1785 PRINT TAB 10;"AN ANNUITY"''
1790 LPRINT TAB 10;"AN ANNUITY"''
1795 PRINT " MONTHLY DEPOSIT?"
1800 LPRINT " MONTHLY DEPOSIT?"
1805 INPUT A
1810 PRINT " $";A''
1815 LPRINT " $";A''
1820 PRINT "INTEREST RATE?(decimal form)"
1825 LPRINT "INTEREST RATE?(decimal form)"
1830 INPUT B
1835 PRINT " ";B*100;"%"''
1840 LPRINT " ";B*100;"%"''
1845 PRINT " NUMBER OF YEARS?"
1850 LPRINT " NUMBER OF YEARS?"
1855 INPUT T
1860 PRINT " ";T''
1865 LPRINT " ";T''
1870 LET N=T*12
1875 LET C=B/12
1880 LET V=A*((1+C)^N-1)/C
1885 PRINT TAB 8;"FUTURE VALUE IS"''
1890 LPRINT TAB 8;"FUTURE VALUE IS"''
1895 PRINT TAB 9; FLASH 1;"$";INT (100*V+.5)/100
1900 LPRINT TAB 9;"$";INT (100*V+.5)/100
1905 FLASH 0
1910 GO TO 1750
1920 CLS : REM REACH A GOAL PAY
1925 PRINT ''
1930 LPRINT ''
1935 PRINT TAB 7;"PAYMENT TO REACH"
1940 LPRINT TAB 7;"PAYMENT TO REACH"
1945 PRINT TAB 14;"GOAL"''
1950 LPRINT TAB 14;"GOAL"''
1955 PRINT " AMOUNT WANTED?"
1960 LPRINT " AMOUNT WANTED?"
1965 PRINT
1970 LPRINT
1975 INPUT A
1980 PRINT " ";"$";A''
1985 LPRINT " ";"$";A''
1990 PRINT "INTEREST RATE?(decimal form)"
1995 LPRINT "INTEREST RATE?(decimal form)"
2000 PRINT
2005 LPRINT
2010 INPUT B
2015 PRINT " ";B*100;"%"''
2020 LPRINT " ";B*100;"%"''
2025 PRINT " NUMBER OF YEARS?"
2030 LPRINT " NUMBER OF YEARS?"
2035 INPUT T
2040 PRINT " ";T''
2045 LPRINT " ";T''
2050 LET R=T*12
2055 LET D=B/12
2060 LET P=A/(((1+D)^R-1)/D)
2065 PRINT TAB 9;"MONTHLY DEPOSIT"
2070 LPRINT TAB 9;"MONTHLY DEPOSIT"
2075 PRINT TAB 12; FLASH 1;"$";INT (100*P+.8)/100
2080 LPRINT TAB 12;"$";INT (100*P+.8)/100
2085 FLASH 0
2090 GO TO 1580
2100 REM "figures"06.22.86 P Hill, SINCUS
2105 CLS : POKE 23658,0
2110 DEF FN f(n)=n*12
2115 DEF FN g(n)=n/12
2120 DEF FN h(n)=INT ((n*12/52)*100+.05)/100
2125 DEF FN i(n)=INT ((n*52/12)*100+.5)/100
2130 DEF FN j(n)=n*52
2135 DEF FN k(n)=n*12
2140 GO TO 2175
2145 INPUT "enter name";n$: PRINT n$
2150 INPUT "PRINTOUT? y/n ";q$: IF q$<>"y" THEN RETURN
2155 LPRINT n$'"weekly amt","$";w$
2160 LPRINT "monthly amt","$";m$
2165 LPRINT "annual amt","$";a$
2170 LPRINT : CLEAR
2175 CLS : PRINT "Expenses/income periodic tally"''" ___BUDGET BILLS/INCOME___"''"1-Week"''"2-Month"''"3-Year"''"4-6 Months"''"5-Bi-Monthly"''"6-RETURN TO MAIN MENU"
2180 LET a$=INKEY$: IF INKEY$<"1" OR INKEY$>"6" THEN GO TO 2180
2185 GO TO (2215 AND a$="1")+(2245 AND a$="2")+(2275 AND a$="3")+(2315 AND a$="4")+(2365 AND a$="5")+(20 AND a$="6")
2215 CLS : INPUT "weekly bill amount $";n
2220 PRINT "Weekly Amt<","$";n: LET w$=STR$ n
2225 PRINT "Monthly Amt","$";: PRINT (FN i(n)): LET m$=STR$ (FN i(n))
2230 PRINT "Annual Amt","$";: PRINT FN j(n): LET a$=STR$ FN j(n)
2235 PAUSE 0: INPUT "name? JUST y >ENTER< TO SKIP";n$: IF n$="y" THEN GO SUB 2145
2240 GO TO 2175
2245 CLS : INPUT "Monthly bill AMOUNT $";n
2250 PRINT "Weekly Amt","$";: PRINT FN h(n): LET w$=STR$ FN h(n)
2255 PRINT "Monthly Amt<","$";n: LET m$=STR$ n
2260 PRINT "Annual Amt","$";: PRINT FN k(n): LET a$=STR$ FN k(n)
2265 PAUSE 0: INPUT "name? JUST y >ENTER< TO SKIP";n$: IF n$="y" THEN GO SUB 2145
2270 GO TO 2175
2275 CLS : INPUT "Annual bill AMOUNT $";n
2280 PRINT "Weekly Amt","$";INT (n/52*100+.05)/100
2285 LET w$=STR$ (INT (n/52*100+.05)/100)
2290 PRINT "Monthly Amt","$";INT (n/12*100+.05)/100
2295 LET m$=STR$ (INT (n/12*100+.05)/100)
2300 PRINT "Annual Amt<","$";n: LET a$=STR$ n
2305 PAUSE 0: INPUT "name? JUST y >ENTER< TO SKIP";n$: IF n$="y" THEN GO SUB 2145
2310 GO TO 2175
2315 CLS : INPUT "Semi-annual bill AMOUNT $";n
2320 PRINT "Weekly Amt","$";INT ((n*2)/52*100+.05)/100
2325 LET w$=STR$ (INT ((n*2)/52*100+.05)/100)
2330 PRINT "Monthly Amt","$";INT ((n/6)*100+.05)/100
2335 LET m$=STR$ (INT ((n/6)*100+.05)/100)
2340 PRINT "Annual Amt","$";INT ((n*2)*100+.05)/100
2345 LET a$=STR$ (INT ((n*2)*100+.05)/100)
2350 PRINT "6 Mos. Amt<","$";n
2355 PAUSE 0: INPUT "name? JUST y >ENTER< TO SKIP";n$: IF n$="y" THEN GO SUB 2145
2360 GO TO 2175
2365 CLS : INPUT "Bi-monthly bill AMOUNT $";n
2370 PRINT "Weekly Amt","$";INT ((n*6)/52*100+.05)/100
2375 LET w$=STR$ (INT ((n*6)/52*100+.05)/100)
2380 PRINT "Monthly Amt","$";INT ((n*6/12)*100+.05)/100
2385 LET m$=STR$ (INT ((n*6/12)*100+.05)/100)
2390 PRINT "Annual Amt","$";INT ((n*6)*100+.05)/100
2395 LET a$=STR$ (INT ((n*6)*100+.05)/100)
2400 PRINT "Bi-monthly Amt<","$";n
2405 PAUSE 0: INPUT "name? JUST y >ENTER< TO SKIP";n$: IF n$="y" THEN GO SUB 2145
2410 GO TO 2175
2425 REM Life Insurance Estimat-er from PARADE MAGAZINE, April 24, 1983, by Andrew Tobias
2430 REM Adapted for computer use by John Colonna, SINCUS
2435 CLS : PRINT AT 10,3; INVERSE 1;"RETURN to MAIN MENU key R.";'TAB 5;"ANY key for INSURANCE"'TAB 9;"Estimater";''" by John Colonna, SINCUS\*"; INVERSE 0: PAUSE 0: LET z$=INKEY$: IF z$="r" OR z$="R" THEN CLS : GO TO 20
2440 GO SUB 2710
2445 PRINT '''" LIFE INSURANCE ESTIMATER"
2455 PRINT '''" Simply stated the amount oflife insurance you need is equalto the amount needed to replace you financially. By using this program you can estimate what your family would need. The first step is to determine 75% of your take-home pay."
2460 INPUT "Enter 75% of your annual take- home pay. ";p
2470 PRINT ''" 75% of annual"
2475 PRINT " take-home pay = $";p
2480 GO SUB 2785
2490 PRINT '''''" The next important questionis to find out the Social Secur-ity benefits your family could expect to receive. The current range is between $5000 to $16000(tax-free) a year. Contact your local Security Security office."
2495 INPUT "Enter Social Security yearly benefits. ";b
2500 PRINT ''''" S. S. benefits = $";b
2505 GO SUB 2785
2515 PRINT ''" The difference between yourannual income needed (";p;") andyour Social Security benefits (";b;") is $";p-b;"."
2520 PRINT " This annual insurance gap you'll want life insurance to make up, but you must decide forhow many years. This depends on the ages of your spouse and children. Choose a time period from the table."
2525 PRINT '" NUMBER OF YEARS"
2535 PRINT '"5 10 15 20 25 30 50"
2540 INPUT "Enter time period from above. ";t
2545 IF t<5 OR t>50 THEN GO TO 2540
2550 IF t=5 THEN LET a=4.7
2555 IF t=10 THEN LET a=8.7
2560 IF t=15 THEN LET a=12
2565 IF t=20 THEN LET a=15
2570 IF t=25 THEN LET a=18
2575 IF t=30 THEN LET a=20
2580 IF t=50 THEN LET a=26
2585 PRINT '" The amount of money needed for the next ";t;" years is $";a*(p-b);"."
2590 GO SUB 2785
2600 PRINT '''''" Now you must add a lump sumas a cushion for funeral ex-penses, debts, etc., at least half a year's salary."
2605 INPUT "Enter lump sum. ";l
2610 PRINT '''''" Lump sum = $";l
2615 GO SUB 2785
2620 PRINT '''
2625 PRINT " Now you must subtract what-ever group life insurance you may have at work and also your assets such as savings accounts,stocks, retirement accounts, etc."
2630 INPUT "Enter your assets. ";gl
2635 PRINT ''''" Total assets = $";gl
2640 GO SUB 2785
2645 PRINT ''"SUMMARY OF LIFE INSURANCE NEEDS"
2650 PRINT '' INVERSE 1;"Annual Income Needed";TAB 23;: PRINT p
2655 PRINT ' INVERSE 1;"Annual S. S. Benefits";TAB 24;: PRINT b
2660 PRINT ' INVERSE 1;"No. of Years Needed";TAB 26;: PRINT t
2665 PRINT ' INVERSE 1;"Amt. of Money Needed";TAB 23;: PRINT a*(p-b)
2670 PRINT ' INVERSE 1;"Lump Sum Expenses";TAB 23;: PRINT l
2675 PRINT ' INVERSE 1;"Assets";TAB 23;: PRINT gl
2680 PRINT ''" Your life insurance needs are- "'TAB 13;"$"; INVERSE 1;(((a*(p-b))+l)-gl)
2685 INPUT "COPY or AGAIN (C/A)? ";n$
2690 IF n$="C" OR n$="c" THEN COPY
2695 IF n$="A" OR n$="a" THEN RUN 2425
2700 GO TO 2685
2705 STOP
2710 BORDER 6: CLS
2715 PRINT '''
2720 PRINT TAB 12;"\::\::\::\::\::\::\::\::\::"
2725 PRINT TAB 12; INVERSE 1;" L I F E "
2730 PRINT TAB 12;"\::\::\::\::\::\::\::\::\::"
2735 PRINT : PRINT
2740 PRINT TAB 7;"\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::"
2745 PRINT TAB 7; INVERSE 1;" I N S U R A N C E "
2750 PRINT TAB 7;"\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::"
2755 PRINT : PRINT
2760 PRINT TAB 7;"\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::"
2765 PRINT TAB 7; INVERSE 1;" E S T I M A T E R "
2770 PRINT TAB 7;"\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::"
2775 GO SUB 2790
2780 RETURN
2785 PRINT AT 21,PI; FLASH 1;"Press any key to continue."
2790 PAUSE 0: CLS
2795 RETURN
2800 POKE 23658,8: CLS : PRINT AT 8,0; INVERSE 1;"RETURN to MAIN MENU key R.";TAB 1; INVERSE 1;''"C key for CALENDAR"';"by LESLIE H. WEBER,TSS NEWSNOTES";'' INVERSE 1;"U KEY FOR UTILITY BILL ANALYZER"'"FROM 1/85 TSS NEWSNOTES"; INVERSE 0: PAUSE 0: LET z$=INKEY$: GO TO (20 AND Z$="R")+(2805 AND Z$="C")+(3200 AND Z$="U")
2805 CLEAR : PRINT TAB 6;"Any Calendar Month"
2810 PRINT TAB 6;"From 1700 to 1999"
2815 PRINT : PRINT : REM FROM LESLIE H. WEBER,CANYON COUNTRY,CA 91351 FROM PG#6 TSS NEWSNOTES 1/85 COPIED BY JOHN COLONNA
2820 LET col=4: LET M$=""
2825 DIM m(12)
2830 LET m(1)=31: LET m(3)=31: LET m(5)=31: LET m(7)=31: LET m(8)=31: LET m(10)=31: LET m(12)=31
2835 LET m(2)=28
2840 LET m(4)=30: LET m(6)=30: LET m(9)=30: LET m(11)=30
2845 PRINT "Number of month?"
2850 INPUT n
2855 PRINT AT 4,24;n
2860 PRINT "Year ?"
2865 INPUT y: LET year=y
2870 PRINT AT 5,22;y
2875 LET l=NOT PI
2880 IF y/4=INT (y/4) AND NOT y/100=INT (y/100) OR y/400=INT (y/400) THEN LET l=1
2885 LET dm=m(n)
2890 IF n=2 AND l THEN LET dm=29
2895 IF y<1900 AND y>1800 THEN GO SUB 3050
2900 IF y<1800 THEN GO SUB 3065
2905 LET y=y-1800
2910 LET d=365*y+INT (y/4)+2
2915 FOR i=1 TO n-1
2920 LET d=d+m(i)
2925 NEXT i
2930 IF n<3 AND l THEN LET d=d-1
2935 LET DATE=NOT PI
2940 LET w=d-7*INT (d/7)
2945 LET cur=1
2950 PRINT : PRINT
2955 GO SUB 3080
2960 PRINT TAB 2;"SUN MON TUE WED THU FRI SAT"
2965 FOR i=NOT PI TO 5
2970 FOR j=3 TO 9
2975 IF cur>14 AND cur<22 AND j=6 THEN LET DATE=CUR: PRINT INVERSE 1;TAB col*w+1;"S";cur;: GO TO 2985
2980 PRINT ;TAB col*w+2;cur;
2985 IF cur=dm THEN GO TO 3025
2990 LET cur=cur+1
2995 IF w=6 THEN GO TO 3010
3000 LET w=w+1
3005 NEXT j
3010 LET w=NOT PI
3015 PRINT
3020 NEXT i
3025 REM PRINT ''"DONT FORGET SINCUS MEETING at"'"7pm, WEDNESDAY, ";M$;", ";DATE: COPY
3030 POKE 23658,8: PAUSE 0: CLS : PRINT "###-- LIST APPOINTMENTS FOR"'M$;"? --###": INPUT Z$: IF Z$="Y" THEN GO SUB 3145
3035 CLS : INPUT "PRESS ENTER TO SEE ANOTHER MONTH";A$
3045 GO TO 2800
3050 LET y=y-1800
3055 LET d=VAL "365*y+INT (y/4)+3"
3060 RETURN
3065 LET y=y-1800
3070 LET d=VAL "365*y+INT (y/4)+4"
3075 RETURN
3080 RESTORE 3080: DATA "January","February","March","April","May","June","July","August","September","October","November","December"
3085 IF n>0 AND n<13 THEN FOR i=1 TO n: READ m$: NEXT i: PRINT AT 9,4;m$,year
3140 RETURN
3145 CLS : PRINT '"ENTER DATE OF APPOINTMENT'S"'"FOR ";m$: INPUT N$
3150 CLS : PRINT '"ENTER DATA FOR ";N$;" ";m$: INPUT P$
3155 LPRINT 'N$;" - ";P$
3160 PRINT '"MORE DATA?": INPUT Z$: IF Z$="Y" THEN GO TO 3145
3165 RETURN
3170 STOP
3200 REM Utlity Bill Analyzer
3210 CLS : PRINT "Do You KNOW the WATTAGE OR"'"AMPERAGE? (INPUT W OR A) ";: INPUT B$: PRINT B$
3215 IF B$<>"A" AND B$<>"W" THEN GO TO VAL "3210"
3220 IF B$="W" THEN GO TO VAL "3270"
3225 PRINT "ENTER name of EQUIPMENT";: INPUT N$: PRINT "-";N$
3230 PRINT "How many hours OPERATION per dayfor the ";N$;" ?";: INPUT H: PRINT " -";H;" HOURS"
3235 PRINT "How many AMPS REQUIRED for the"'N$;: INPUT I: PRINT " -";I;"AMPS"
3240 PRINT "VOLTAGE Rating? 115,120,220,240 ";: INPUT E: PRINT " -";E;" VOLTS"
3245 LET P=I*E: PRINT "WATTS Required ",P'"Now ENTER rate per KW hour from Electric bill (.O5 FOR 5 CENTS)";
3250 INPUT r: PRINT " ";r: LET C=(R*(P/1000))*(H*30): PRINT "COST TO RUN ";N$;" PER"'"MONTH $";C
3255 PRINT AT 19,5; FLASH 1;"COPY ?";: PRINT " Y/N": INPUT z$: IF z$="Y" THEN COPY
3260 PRINT AT 19,5;"ANY MORE ? Y/N": INPUT Z$: IF Z$="Y" THEN GO TO VAL "3200"
3265 GO TO VAL "2800"
3270 PRINT "ENTER name of EQUIPMENT";: INPUT N$: PRINT "-";N$
3275 PRINT "How many hours OPERATION per dayfor the ";N$;" ?";: INPUT H: PRINT " -";H;" HOURS"
3280 PRINT "What is the WATTAGE?";: INPUT p: PRINT " - ";p;" WATTS"
3285 PRINT "VOLTAGE Rating? 115,120,220,240 ";: INPUT E: PRINT " -";E;" VOLTS"
3290 LET i=p/e: PRINT "AMPS Required = ";i'"enter rate per KW hour from Electric bill(.05 for 5 cents)"
3295 GO TO VAL "3250"
9000 STOP
9999 CLEAR : SAVE "INVESTMENT" LINE 1: BEEP .01,.77: REM PRINT AT 10,0;" SAVING AND INVESTMENT PRESENTED BY ""SINCUS"""