Magnify

Source Code

   10 REM *** PROGRAM "MAGNIFY11"
   20 REM *** UPDATED 1/14/84 AM
   30 DIM L$(10,1)
   40 DIM C(2)
   50 DIM A$(2,255)
   60 DIM D(2)
   70 DATA "A"
   80 DATA 170,85,170,85,170,85,170,85
   90 DATA "B"
  100 DATA 255,129,129,129,129,129,129,255
  110 FOR J=1 TO 2
  120 READ L$(J,1)
  130 FOR H=0 TO 7
  140 READ K
  150 POKE USR L$(J,1)+H,K
  160 NEXT H
  170 NEXT j
  180 INK PI
  190 PRINT AT 9,0;"FOR RELIEF STYLE (LIGHT) PRESS 7"
  200 PRINT "FOR RELIEF STYLE (DARK)  PRESS 9"
  210 PRINT AT 13,6;"OTHERWISE, PRESS ENTER"
  220 PRINT AT 14,11;"TO CONTINUE"
  230 INPUT D$
  240 IF D$<" " THEN GO TO 290
  250 IF D$="7" THEN LET D(2)=8
  260 IF D$="9" THEN LET D(2)=10
  270 LET D(1)=VAL D$
  280 GO TO 520
  290 CLS 
  300 PRINT AT 5,12;"\a\a    \b\b    \::\::"
  310 PRINT AT 6,12;"\a\a    \b\b    \::\::"
  320 PRINT AT 8,6;"1     2     3     4 "
  330 BORDER 6
  340 PRINT AT 11,3;"SELECT BACKGROUND CHARACTER"
  350 PRINT AT 13,8;"ENTER 1, 2, 3 OR 4"
  360 PRINT AT 14,7;"OR ENTER 5 FOR OTHER"
  370 INPUT D(1)
  380 PRINT AT 11,0;"                               ": BORDER 5
  390 PRINT AT 11,6;"SELECT TEXT CHARACTER"
  400 INPUT D(2)
  410 IF D(1)=D(2) AND D(1)<>5 THEN GO TO 400
  420 CLS 
  430 IF D(1)<5 AND D(2)<5 THEN GO TO 520
  440 IF D(1)<5 THEN GO TO 490
  450 PRINT AT 11,3;"ENTER BACKGROUND CHARACTER"
  460 INPUT L$(5,1)
  470 CLS 
  480 IF D(2)<5 THEN GO TO 520
  490 PRINT AT 11,6;"ENTER TEXT CHARACTER"
  500 INPUT L$(6,1)
  510 LET D(2)=6
  520 CLS 
  530 LET LENGTH=0
  540 FOR G=1 TO 2
  550 PRINT AT 11,7;"ENTER TEXT - LINE ";G
  560 INPUT Y$
  570 IF LEN Y$>LENGTH THEN LET LENGTH=LEN Y$
  580 CLS 
  590 LET A$(G)=Y$
  600 NEXT G
  610 LET L$(1,1)=" "
  620 LET L$(2,1)="\a"
  630 LET L$(3,1)="\b"
  640 LET L$(4,1)="\::"
  650 LET L$(7,1)="\ '"
  660 LET L$(8,1)="\. "
  670 LET L$(9,1)="\':"
  680 LET L$(10,1)="\:."
  690 LET M=2
  700 LET C(1)=7
  710 LET C(2)=23
  720 LET ROW=11
  730 CLS 
  740 FOR X=1 TO LENGTH
  750 INK 7
  760 PRINT AT 20,0;A$(1,X)
  770 PRINT AT 21,0;A$(2,X)
  780 INK 9
  790 GO SUB 830
  800 CLS 
  810 NEXT X
  820 STOP 
  830 FOR C=0 TO 7
  840 FOR N=1 TO M
  850 FOR B=0 TO 1
  860 FOR R=0 TO 7
  870 LET SWITCH=2
  880 IF POINT (C,R+B*8)=0 THEN LET SWITCH=1
  890 LET RCOOR=ROW-(M/2*8)+(C*M)+N
  900 FOR L=1 TO M
  910 LET CCOOR=C(B+1)-(M/2*8)+(R*M)+L
  920 PRINT AT RCOOR,CCOOR;L$(D(SWITCH),1)
  930 LPRINT TAB CCOOR;L$(D(SWITCH),1);
  940 NEXT L
  950 NEXT R
  960 NEXT B
  970 NEXT N
  980 NEXT C
  990 RETURN