Manager

Source Code

   10 GO SUB 1300
   20 REM Manager
   30 GO SUB 1160: REM  variables
   40 LET week=week+1
   50 GO SUB 720: REM print-out
   60 GO SUB 980: REM  people
   70 GO SUB 720
   80 GO SUB 860: REM  make
   90 GO SUB 720
  100 GO SUB 600: REM  sales
  110 GO SUB 150
  120 LET capital=capital-wage*workforce
  130 GO TO 40
  140 BEEP .5,RND*50: BEEP .4,RND*50: RETURN 
  150 REM unpredictables ***
  160 CLS 
  170 IF RND<.45 THEN GO TO 270
  180 LET a=INT (RND*7)+1
  190 GO SUB 140
  200 PRINT ''"Unions demand ";a;"% pay rise.   "
  210 LET wage=INT (100*(wage+(a*wage/100)))/100
  220 PAUSE VAL "100"
  230 PRINT '''"Pay per employee is now $";wage
  240 PAUSE VAL "100"
  250 GO SUB 140
  260 CLS 
  270 IF RND<.85 THEN GO TO 360
  280 PRINT ''' INK 2;"Storm flood ruins some of your  stock.",,,,,,"Stand by for damage report:",
  290 PAUSE VAL "100"
  300 LET a=INT (RND*stock/2)+1
  310 LET stock=stock-a
  320 PRINT '' INK 4;"Total stock destroyed was ";a'"radios, worth $";a*sellprice;" retail."
  330 PAUSE VAL "100"
  340 PRINT ''"Stock on hand is now ";stock
  350 PAUSE VAL "100"
  360 IF  RND>.3 THEN GO TO 480
  370 CLS 
  380 PRINT ''"Supplier announces dramatic","price rise!"
  390 PAUSE VAL "100"
  400 LET a=INT ((RND*100*cost/7))/100
  410 IF a<.01 THEN GO TO 400
  420 PRINT ''"Cost of making radios","goes up by "; INK 2;"$";a; INK 0;" each.  " 
  430 PAUSE VAL "100"
  440 LET cost=cost+a
  450 PRINT '' INK 7; PAPER 1;" It now costs "; INK 7; PAPER 0;"$";cost;" "
  460 PRINT "to make each one."
  470 PAUSE VAL "100"
  480 IF RND<.65 AND make<sellprice THEN RETURN 
  490 CLS 
  500 GO SUB 140
  510 PRINT ''"You have a chance to raise      your price." 
  520 PRINT '"Radios now sell for $";sellprice
  530 PAUSE VAL "100"
  540 INPUT "What percentage increase?  ";a
  550 IF a>0 THEN LET z=z+a
  560 LET sellprice=INT (100*(sellprice+a*sellprice/100))/100
  570 PAUSE VAL "100"
  580 PRINT ' INK PI;"Radios now sell for $";sellprice;"     "
  590 PAUSE VAL "100": RETURN 
  600 REM **  sales  **
  610 GO SUB 140
  620 PRINT PAPER 5;'"Total stock is ";stock;" radios     "
  630 PAUSE VAL "100"
  640 PRINT PAPER PI;'"Stand by for sales report.....  "
  650 PAUSE VAL "300"
  660 BORDER 7: PAPER 7: CLS 
  670 PRINT '' INK 1;"Total radios sold: ";a
  680 LET stock=stock-a
  690 PRINT '"Income from sale: $";a*sellprice
  700 LET capital=capital+a*sellprice
  710 PAUSE VAL "100": RETURN 
  720 REM PRINT -out
  730 FOR g=40 TO 50: BEEP .008,g: BEEP .008,60-2*g: NEXT g
  740 CLS 
  750 IF capital+stock<1 THEN GO TO 1110: REM bankrupt
  760 IF capital+stock>999999 THEN PRINT INK 2;"!! You have made a million !!": PAUSE VAL "500": GO TO 1160
  770 PRINT AT 0,5;"FACTORY REPORT: WEEK ";week
  780 PRINT '"Capital = $";capital
  790 PRINT "Stock = ";stock;" radios, worth $";stock*sellprice
  800 PRINT "Selling price = $";sellprice;" each"
  810 PRINT "Cost = $";cost;" each"
  820 PRINT "Employees = ";workforce;" people"
  830 PRINT "Wages = $";wage;" per week"'"Payroll this week = $";wage*workforce
  840 PRINT "Production = ";produce;" radios/person"'"Max production = ";produce*workforce;" radios"
  850 RETURN 
  860 INPUT " How many radios do you want to  make?   ";make
  870 IF NOT make THEN RETURN 
  880 IF make*cost>capital THEN PRINT AT 11,0; INK 2;"Not enough money": GO TO 860
  890 IF make>produce*workforce THEN PRINT AT 11,0; INK 4;"Not enough people": GO TO 860
  900 PRINT AT 11,0;"Target production = ";make;"    "
  910 LET make=make-INT (RND*make/5*(z/100))
  920 PAUSE VAL "100"
  930 PRINT AT 12,0;"Total made in week ";week;" was ";make;"  "
  940 LET stock=stock+make
  950 LET capital=capital-cost*make
  960 PAUSE VAL "50"
  970 RETURN 
  980 REM people
  990 INPUT "How many people do you want","to hire?  ";a
 1000 LET workforce=workforce+a
 1010 PAUSE VAL "100": GO SUB 720
 1020 IF a>0 THEN RETURN 
 1030 INPUT "How many people do you want","to "; INK 4;"fire?  ";a
 1040 IF a=0 THEN GO TO 1100
 1050 IF a>workforce THEN GO TO 1030
 1060 LET a=INT (RND*a+1)
 1070 PAUSE VAL "100"
 1080 PRINT INK PI;"Unions allow you to fire ";a
 1090 LET workforce=workforce-a
 1100 PAUSE VAL "100": RETURN 
 1110 REM bankruptcy
 1120 PRINT ''TAB 8; INK 2;"!! BANKRUPT !!!!"
 1130 PRINT ''"Oh, the shame of it!"
 1140 PRINT ''"Still, you kept the business"
 1150 PRINT ''"going for "; INK 1;week; INK 0;" weeks.";#0;"Press any key for another run": PAUSE NOT PI: RUN 
 1160 REM variables
 1170 LET capital=500+INT (RND*500)
 1180 LET stock=100+INT (RND*50)
 1190 LET sellprice=10+INT (RND*5)
 1200 LET cost=2+INT (RND*5)
 1210 IF cost>sellprice THEN GO TO 1190
 1220 LET workforce=7+INT (RND*10)
 1230 LET wage=12+INT (RND*sellprice*5)
 1240 LET produce=5+INT (RND*6)
 1250 LET week=0
 1260 REM z= sales resistance *  factor *
 1270 LET z=1
 1280 PAPER 7: CLS : BORDER 7: INK 0: RETURN 
 1300 CLS : PRINT AT PI,12;"MANAGER"''''" Modified from page 138"'"THE TIMEX SINCLAIR 2068 EXPLORED by    Tim Hartnell"
 1310 PRINT ''''" A radio manufacturers game.... Good Luck!"''''" To begin     press any key"
 1320 PAUSE NOT PI: RETURN 
 1330 SAVE "manager" LINE 10