typist

Source Code

    5 REM typist                          working 2068-Lawrence    
   10 REM  Input data beginning  with line 1400                   
 1000 REM print keyboard
 1030 INK 0: PAPER 6: CLS : DIM o$(32): GO SUB 1270
 1040 CLS : PRINT "\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c  \d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e  \f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h"
 1050 PRINT " \a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c  \d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e  \f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h"
 1060 PRINT "  \a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c  \d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e  \f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h"
 1070 PRINT "\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\c\a\b\d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \e\d \f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g\h\f\g "
 1080 PRINT OVER 1;AT 1,0;" 1  2  3  4  5  6  7  8  9  0"
 1090 PRINT OVER 1;AT 4,0;"  Q  W  E  R  T  Y  U  I  O  P"
 1100 PRINT OVER 1;AT 7,0;"   A  S  D  F  G  H  J  K  L  E"
 1110 PRINT OVER 1;AT 10,0;" C  Z  X  C  V  B  N  M  S  B  C"
 1115 PRINT AT 12,6;"\a\b\b\b\b\b\b\b\b\b\b\b\b\b\b\b\b\b\b\b\c           \d    SPACE  BAR     \e           \f\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\h"
 1120 REM accept input
 1150 LET total=0: LET right=0
 1160 READ a$: IF a$="STOP" THEN RESTORE 1430: READ a$
 1170 PRINT INK 1;AT 16,0;o$;AT 16,0;a$'o$;o$: PRINT AT 17,0;
 1180 FOR i=1 TO LEN a$
 1190 LET t$=INKEY$: IF t$<>"" THEN GO TO 1210
 1200 GO TO 1190
 1210 LET total=total+1: BEEP .1,30: IF t$<>a$(i) THEN PRINT PAPER 5;t$;CHR$ 8;: GO TO 1190
 1220 LET right=right+1
 1230 PRINT BRIGHT 1;t$;
 1240 NEXT i: PRINT AT 21,25;INT (right/total*100);"%  "
 1250 INPUT "More? (y/n) ";q$: IF q$<>"n" THEN PAUSE 25: GO TO 1160
 1260 STOP 
 1270 REM USR CHARACTERS
 1300 RESTORE : FOR i=0 TO 63: READ byte: POKE USR "a"+i,byte: NEXT i: RETURN 
 1310 DATA 0,0,0,0,0,7,4,4,0,0,0,0,0,255,0,0,0,0,0,0,0,224,32,32,4,4,4,4,4,4,4,4,32,32,32,32,32,32,32,32,4,4,7,0,0,0,0,0,0,0,255,0,0,0,0,9,32,32,224,0,0,0,0,0
 1390 RETURN 
 1400 REM data for tests - Put in no more than 32 characters per DATA statement.
 1430 DATA "Just type what you see."
 1440 DATA "This is a T/S2068 typing test."
 1450 DATA "Don't look at the keyboard."
 1470 DATA "asdfghjkl qwertyuiop"
 1480 DATA "zxcvbnm 1234567890"
 1490 DATA "Old MacDonald had a farm."
 1500 DATA "McDonald's has McNuggets."
 1510 DATA "Give me liberty or give me death"
 1520 DATA "The bear went over the mountain."
 1530 DATA "Never had it and never will."
 1540 DATA "The doctor is in his office."
 1550 DATA "May the force be with you."
 1560 DATA "The priest is on the altar."
 1570 DATA "A penny saved is a penny earned."
 1580 DATA "I've heard that before."
 2000 DATA "STOP"
 9999 SAVE "typist" LINE 1: BEEP 1,32: PRINT INVERSE 1;"Program Saved": PRINT : PRINT "Rewind tape to verify": VERIFY "": PRINT ' FLASH 1;"Program Verified.": BEEP .5,32