1987 Federal Income Tax Calculator

NOTE: The following program can be typed in, without any modification, on your ZX81/TS1000/TS1500 and TS2068/Spectrum.

IT’S THAT TIME AGAIN FOLKS! And with the following program, you will be ready for it. Yup! It’s that festive season of the year lovingly referred to as the good old “TAX SEASON”.

As you may have guessed, the phrase “TAX SIMPLIFICATION” is an oxymoron. It is about the same as Jumbo Shrimp and the U.S. Postal Service. In fact, just figuring the proper standard deduction is a job in itself, and I am sure that many individual taxpayers will end up cheating THEMSELVES in this respect.

For instance, there is no longer any additional exemptions for age 65 or over, or for people who are blind. Instead Uncle has built an additional STANDARD deduction into the law. Notice that I emphasized the word STANDARD. If you itemize your return, there is NO additional allowance or deduction.

Let’s take a couple, both age 66, who are using filing status 2, MARRIED FILING A JOINT RETURN. First of all, they will get 2 exemptions, (not 4 as in the past), for a total of $3,800. The standard deduction, $3,760, is increased by $2,440 which gives them a total STANDARD deduction of $6,200. However, they have a lot of medical expenses, Real Estate Taxes, some Interest Expenses and deductible contributions, which came to a total of $7.000. This is $800 greater than the STANDARD deductions, so they intend to ITEMIIZE. Lets give them $20,000 taxable retirement income.

OK. We take the $20,000 income and deduct from it the $3,800 exemption and the $7,000 worth of itemized deductions which leaves them with taxable income of $9,200. Notice that there is nothing extra allowed for their ages. The $2,440 has totally disappeared. Had the couple each been 21 and the $20,000 been earned income, the taxable income still would have been $9,200. The older couple was penalized by losing the additional $2,440 deduction they would have been allowed had they used the STANDARD deduction. For the younger couple there was not any penalty. This means that the old folks $7,000 was worth only $4,560. You did it to us again Ronny.

I swore I wasn’t going to get on a soap box again this year, but there I go again. Lets get down to business.

I have written this program using no multi-statement lines or DATA statements. Originally I had written two programs. One of the programs had multi-statement lines and DATA statements, and the other did not. In an effort to save space in TDM and to avoid confusion, I decided to eliminate everything that would not be compatible with you computer regardless of the model. Only CAPS mode was used. I also found that by putting the DATA in D$, I saved a lot o bytes.

I think that you can type this program in and use it without any further documentation or further explanation.

If your computer has caps and lower case modes, use the CAPS mode when running it. On the TS2068 and the Spectrum you can add a line at 105 POKE 23658,8 to accomplish this. If your computer has a FAST mode, add line 475 FAST and line 485 SLOW..but that is optional. If you have lower case capability, use it “ad lib” when entering text.

Pay particular attention to line 440 and be certain you are using the correct operarators. You cna eliminate the REMs if you feel so inclined and eliminate all the extraneous spaces. The PRINT position notation was not used because this is not standard notation on some of your computers. Just use the appropriate number of commas to obtain the correct PRINT positions.

The program will calculate the proper standard deduction for you. In the event you are taking itemized deductions, the program will select the higher of standard or itemized deduction and deduct that figure only. This feature alone is worth the effort of typing in this program.

Another unique feature of the program is the calculation of the tax on NET CAPITAL GAINS, which during this transition year (1987) is limited to 28% maximum on these gains. In 1988 the maximum tax rate will be 28% and no adjustment will be required. I must note here that I am writing this the week of October 19th…the week the New York Stock Exchange went bananas, so for 1987 the expression CAPITAL GAIN may also become an oxymoron.

The program has not been written with any ERROR TRAPPING, so be careful when you RUN it. I have some really nifty error trapping routines and if Tim will allow me, I will publish a few of ’em right here in the pages of TDM sometime soon.

You have my blessing to incorporate this program, as written, into any of your own tax programming endevors. As far as a I am concerned, it is public domain as of this minute. (It would be nice if you gave the old man here, or my company ABBA SOFT a little credit.)

You will not be able to use this program if you can be taken as a dependent on another persons return. Special rules apply. Also for childeren under age 14 who have investment income greater than $1000, Form 8615 must be used.

Final Note: I have released a complete 1040 tax program which is called QWIK-1040, that will quickly prepare your entire 1987 Federal Tax Return including schedules.

If you have any questions, you can drop me a line. If you don’t have any questions, you can drop me a line also. It’s lonely out here in the sticks! Herb Bowers, Sr., 2588 Woodshire Circle, Chesapeake, VA 23323.

   0>REM        1987
     **FEDERAL TAX CALCULATOR**
        BY: HERB BOWERS, SR.
           NOVEMBER 1987
 FOR: ZX-81, T/S 1000, T/S 1500,
     T/S 2068, SINCLAIR SPECTRUM
       PC8300, TK90X AND TK 95
 *******************************

 100 REM ▒INFORMATION INPUT▒

 110 PRINT AT 8,0;"ENTER FILING
STATUS:";TAB 4;"1. SINGLE";TAB 4
;"2. MARRIED FILING JOINT";TAB 4
;"3. MARRIED FILING SEPERATE";TA
B 4;"4. HEAD OF HOUSEHOLD";TAB 4
;"5. QUALIFYING WIDOW/ER"
 120 INPUT FS
 130 CLS
 140 PRINT AT 9,0;"HOW MANY DEPE
NDENTS BESIDES YOU";" AND YOUR S
POUSE" AND FS=2;"?";TAB 4;"IF NO
NE THEN ENTER 0"
 150 INPUT EX
 160 LET EX=EX+1+(FS=2)
 165 LET AA=0
 170 FOR F=0 TO FS=2
 180 CLS
 190 PRINT AT 9,0;"ARE YOU" AND
NOT F;"IS SPOUSE" AND F;" 65 OR
OLDER";TAB 12;"Y OR N"
 200 INPUT I$
 210 LET AA=AA+(I$(1)="Y")
 220 CLS
 230 PRINT AT 9,0;"ARE YOU" AND
NOT F;"IS SPOUSE" AND F;" BLIND?
";TAB 12;"Y OR N"
 240 INPUT I$
 250 LET AA=AA+(I$(1)="Y")
 260 NEXT f
 270 CLS
 280 PRINT AT 9,0;"ENTER ADJUSTE
D GROSS INCOME","FORM 1040,LINE
31; 1040A,LINE 13","1040EZ, LINE
3"
 290 INPUT AG
 300 CLS
 310 PRINT AT 9,0;"ENTER NET LON
G TERM CAPITAL GAIN(SMALLER OF L
INE 17 OR 18,SCH.D) (IF 0 OR LES
S THEN ENTER 0)"
 320 INPUT CG
 400 CLS
 410 PRINT AT 9,0;"ENTER TOTAL I
TEMIZED DEDUCTIONS","LINE 26, SC
HEDULE A","(IF NONE THEN ENTER 0
)"
 420 INPUT ID
 430 CLS

 435 REM ▒STANDARD DEDUCTION▒
             CALCULATION

 440 IF AA THEN LET AA=((FS=1)*(
     ((AA=1)*1210)+(AA=2)*1960))
     +((FS=2 OR FS=5)*(((AA=1)*
     1840)+((AA>=2)*2440)))+
     ((FS=3)*(((AA=1)*1220)+(AA=
     2)*1820))+((FS=4)*(((AA=1)*
     2610)+(AA=2)*3360))+((AA>2)
     *600)+((AA>3)*600)
 450 LET SD=(2540*(FS=1 OR
     FS=4))+(3760*(FS=2 OR
     FS=5))+(1880*(FS=3))+AA
 460 LET TA=AG-((SD>=ID)*SD)-
     ((ID>SD)*ID)-EX*1900

 465 REM ▒PRINT INFO TO SCREEN▒

 470 PRINT ,,"*FEDERAL INCOME TA
X CALCULATION*",,"FILING STATUS=
 ";FS,"EXEMPTIONS= ";EX,,,,"ADJU
STED GROSS INCOME= ";AG,,," LESS
: ";EX;" EXEMPTION";"S" AND EX>1
;"*1900= ";EX*1900," LESS: ITEMI
ZED DED.= ";ID AND ID>SD," LESS:
 STANDARD DED.= ";SD AND SD>=ID,
,,"TAXABLE INCOME= ";TA*(TA>0),,
,"NET CAPITAL GAIN= ";CG,,,"TAX
LIABILITY= ";
 480 GO SUB 1000
 490 PRINT TAX,"BEFORE CREDITS O
R ADD'L TAXES"
 500 PRINT ,,"ENTER TOTAL FEDERA
L WITHHOLDING"
 510 INPUT WH
 520 LET L=WH-TAX
 530 PRINT AT 19,0;"TOTAL FEDERA
L WITHHELD= ";WH,,,"YOUR REFUND
IS: " AND L>=0;"YOU OWE: " AND L
<0;"$";ABS L
 540 STOP

1000 REM ▒TAX CALCULATION▒
              CONTROL

     INPUT: TA=TAXABLE AMOUNT
            CG=NET CAPITAL GAIN
            FS=FILING STATUS
               (1 TO 5)

    OUTPUT: TAX=TAX LIABILITY

1010 IF TA>=25 THEN GO TO 1040
1020 LET TAX=(TA>=5)+(TA>=15)
1030 RETURN

1035 REM ▒SEPARATE CAPITAL GAIN▒

1040 LET MX=(27000*(FS=1))+
     (45000*(FS=2 OR FS=5))+
     (22500*(FS=3))+(38000*
     (FS=4))
1050 LET CGT=(CG*.28)*(TA>MX)
1060 LET CGA=CG*(CGT>0)
1070 LET L=(TA-CGA)/100
1080 IF NOT CGA AND TA<50000
     THEN GO TO 1140

1090 REM ▒X, Y, Z, SCHEDULES▒

1100 GO SUB 1300
1110 LET TAX=INT ((L+CGT)+.5)
1120 RETURN

1130 REM ▒TAX TABLES AMOUNTS▒
           SET UP BRACKETS

1140 LET BR=25+((L>30)*25)
1150 LET B1=INT (TA/BR)
1160 LET B2=B1+BR
1170 LET B3=B2+BR
1180 LET L=B2/100

1185 REM ▒BEGIN CALCULATION▒

1190 GO SUB 1300
1200 LET L1=L
1210 LET L=B3/100
1220 GO SUB 1300
1230 LET L2=L
1240 LET TAX=INT ((L1+L2)/2+.5)
1245 REM ▒END CALCULATION▒

1250 RETURN

1300 REM ▒DATA CONVERTER▒

1310 LET LO=0
1320 GO SUB 1500
1330 FOR F=1 TO 60 STEP 12
1340 LET HI=VAL D$(F TO F+2)
1350 LET PLUS=VAL D$(F+3 TO F+7)
1360 LET PCT=VAL D$(F+8 TO F+11)
1370 IF L>LO AND L<=HI THEN
     GO TO 1400
1380 LET LO=HI
1390 NEXT F

1395 REM ▒UPPER/LOWER PARAMETER▒
               BRACKET TAX

1400 LET L=(L-LO)*PCT+PLUS
1410 RETURN

1500 REM ▒PSEUDO-DATA▒

1510      REM ▒SINGLE▒

1515 IF FS=1 THEN LET D$="018000
00001116800198001527002448002854
00530400359E91475438.5"

1520     REM ▒JOINT;Q/W▒

1525 IF FS=2 OR FS=5 THEN LET D$
="030000000011280003300015450040
8000289000884000359E92459038.5"

1530 REM ▒MARRIED FILING SEP.▒

1535 IF FS=3 THEN LET D$="015000
00001114000165001522502040002845
00442000359E91229538.5"

1540  REM ▒HEAD OF HOUSEHOLD▒

1545 IF FS=4 THEN LET D$="025000
00001123000275001538003350002880
00755000359E92225038.5"

1550 RETURN