2068 Gazer’s Guide

Author(s): Paul Bingham
Pub Details: Time Designs Magazine v2 n1 (Volume 2, Issue 1)
Date: November/December 1985
Pages: 7-8
Star chart: Taurus, Aries, Orion, Pegasi and the Vernal Equinox
Star chart: Taurus, Aries, Orion, Pegasi and the Vernal Equinox

Everyone enjoys looking at the stars on a starry night even when they do not consider themselves amateur astronomers. A standard pair of binoculars can reveal some breathtaking sights in the night sky. They can show Jupiter and between two and four of its moons…including the forbidden Europa 2010 fans! Jupiter is quite a sight all summer long. Halley’s comet is coming and will be easy to spot in those same binoculars by November, if one knows where to look.

But if everyone feels as I do, the heavens can be a little confusing when it comes down to finding things. If one does not know the constellations, or has no idea where to look to find anything less obvious than the full moon, then I may have just the remedy. The 2068 can direct us, using the accompanying program listing.

Up until now, looking things up in an astronomical reference only provided some coordinates given as “Right Ascension” and “Declination” or “RA” and “Dec”. These strange figures are for aiming telescopes accurately, but are generally meaningless to the casual observer. The 2068 can make sense out of most anything, and such is the case with RA and Dec. The computer can convert these values into an easier to follow set of horizontal and vertical coordinates called altitude and azimuth.

Altitude indicates the relative height in the sky being zero at the horizon and progressing to 90, directly over-head. Simple enough. Azimuth is just as easy. Remember a compass with north, east, south, and west? Azimuth follows the compass clockwise with zero as north, 90 as east, 180 as south, and so on to 360 (north again). Even if numbers zero to 360 are confusing, the program prints out the compass directions too.

The program spits out values by time of day for which compass direction (azimuth) to look and how high off the horizon (altitude) to look, to find just what we are searching for. By using any set of RA and Dec values in an astronomy book or from magazines like ASTRONOMY or SKY AND TELESCOPE, we can easily find any object in the sky any time for any date. Our program and the 2068 handle all the calculating…all we do is look where it indicates and enjoy!

PROGRAM NOTES: The program is designed to be simple and straight forward. One can naturally alter it to suit one’s taste, but lines 30 thru 115 are the program’s core, and should be entered as is.

As the program listing stands now, “o” and “L” for longitude and latitude in line 5 are set for my location. Someone in the local liabrary map room can help with these values if available nowhere else. The factor “k” in line 5 is set for 1985. Values for [the years] ’86 thru ’89 are: 6.6241, 6.6081, 6.5921, 6.6419 respectively. The value “v” is the time zone displacement. The west coast is 8, the east coast is 5, my zone in Arizona is 7.

RA and Dec are always listed in hours-minutes-seconds fashion. Rounding to the nearest hour value is generally accurate enough. The program will accept hour values with decimal input, if real accuracy is required. One must remember to enter a minus sign if one is listed with the RA or Dec value.

The 24 time system is required by the program. This is familiar to most everyone, but in case one is rusty…midnight is zero. The value increases by one, each hour thru noon (12). Then 1:00pm becomes 13 and so on to 11:00pm (23). Figure A for Jupiter will show that even fractions of the hour are accepted.

The program will indicate a minus altitude value for any object below the horizon. Objects near due south, or directly over-head sometimes give less accurate results until the object moves. The remainder of the program needs no explanation to run.

Of interest will be the table of RA and Dec values in Figure B for Halley’s comet. These are given weekly thru June 1986. In case a test of the listing is desired, use the table in Figure C as a check.

Good-bye and Good Gazing! P.B.

Program Listing

   1 REM  RA/Dec to Alt/Azimuth
5 LET n=180: LET c=.99999: LET o=111.7: LET L=33.4: LET k=6.6383: LET v=7: DIM C$(1,16): LET C$(1)="NEE SES SWW NWN ": DIM M$(1,72): LET M$(1)="Jan 0Feb 31Mar 59Apr 90May120Jun151Jul181Aug212Sep243Oct273Nov304Dec334"
10 INPUT "Object:";N$: INPUT "RA:";R: INPUT "Dec:";D
15 CLS : FOR t=1 TO 12: PRINT t;: LET m=t: GO SUB 170: PRINT TAB 5;M$(1,m TO m+2): NEXT t: INPUT "Month:";m: CLS : INPUT "Day:";w: GO SUB 170: LET y=VAL M$(1,m+3 TO m+5)+w: PRINT N$: PRINT "RA=";R;TAB 9;"Dec=";D;TAB 20;"Date:";M$(1,m TO m+2);" ";w
20 INPUT "(0-24hr):";u: LET u=INT (u*100+.01)/100
30 LET T=k+.0657*y+1.0027*(u+v)-(o/15)
40 IF (T)>24 THEN LET T=T-24
50 LET H=(T-R)*15
60 LET q=D/n*PI: LET f=L/n*PI
70 LET g=COS (D*PI/n): LET i=COS (L*PI/n): LET j=COS (H*PI/n)
80 LET A=(q*f)+(g*i*j): IF A>=1 THEN LET A=c
85 IF A<=-1 THEN LET A=-c
90 LET A=(ASN A)*n/PI
100 LET Z=(q-f*(INT A/n*PI))/(i*COS (INT A*PI/n)): IF Z>=1 THEN LET Z=c
105 IF Z<=-1 THEN LET Z=-c
110 LET Z=(ACS Z)*n/PI
115 IF H>360 OR H>0 AND H<n OR H<-n AND H>-360 THEN GO SUB 180
130 PRINT "Time:";u;TAB 11;"ALT=";INT (A+.5);TAB 19;"AZM=";INT (Z+.5);: IF Z<23 THEN LET Z=340
135 LET p=(INT ((Z-23)/45))*2+1: PRINT TAB 29;C$(1,p);C$(1,1+p)
140 INPUT "1)COPY 2)RA 3)Day 4)Hr 5)Quit ";p: IF p=5 THEN STOP
150 IF p=1 THEN COPY : GO TO 140
160 GO TO p*5
170 LET m=(m-1)*6+1: RETURN
180 LET Z=360-Z: RETURN

Figure A

JUPITER
RA=21.2  Dec=-17.2  Date:Oct 7

Time:18    ALT=27  AZM=139  SE
Time:18.25 ALT=29  AZM=143  SE
Time:18.5  ALT=31  AZM=147  SE
Time:18.75 ALT=32  AZM=152  SE
Time:19    ALT=34  AZM=155  SE
Time:19.25 ALT=35  AZM=164  S

Figure B

       HALLEY'S COMET

  date        RA         Dec
           h  m  s    o  '  "

14- 9-85   6 12 41 +19 31 43
21- 9-85   6 13 16 +19 40 35
28- 9-85   6 12 27 +19 51 37
 5-10-85   6  9 44 +20  5 45
12-10-85   6  4 23 +20 23 57
19-10-85   5 55 15 +20 47  8
26-10-85   5 40 35 +21 15 20
 2-11-85   5 17 30 +21 45 19
 9-11-85   4 41 42 +22  3 54
16-11-85   3 48  2 +21 33 38
23-11-85   2 35 55 +19  7 48
30-11-85   1 17 51 +14 21 30
 7-12-85   0 12  4 + 8 51 31
14-12-85  23 24 41 + 4 18 52
21-12-85  22 52  1 + 1  2 20
28-12-85  22 28 53 - 1 17 13
 4- 1-86  22 11 31 - 3  0 54
11- 1-86  21 57 22 - 4 24 33
18- 1-86  21 44 46 - 5 39 36
25- 1-86  21 32 35 - 6 54 52
 1- 2-86  21 20  9 - 8 17 18
 8- 2-86  21  7 20 - 9 51 24
15- 2-86  20 54 31 -11 38 48
22- 2-86  20 42 10 -13 39 31
 1- 3-86  20 30 11 -15 56 43
 8- 3-86  20 17 31 -18 40 40
15- 3-86  20  1 56 -22 12  4
22- 3-86  19 38 53 -27  8 29
29- 3-86  18 57  0 -34 30 28
 5- 4-86  17 24 56 -44 15 29
12- 4-86  14 29 42 -46 33 30
19- 4-86  12 13 37 -34 31 18
26- 4-86  11 14 30 -23 20 34
 3- 5-86  10 47 43 -16 26  1
10- 5-86  10 34 24 -12 13  1
17- 5-86  10 27 42 - 9 32 15
24- 5-86  10 24 42 - 7 46 50
31- 5-86  10 23 58 - 6 36 49
 7- 6-86  10 24 44 - 5 50 49
14- 6-86  10 26 32 - 5 21 55

NOTE: A copy of the listing and of a longer version of the program is available from the author for $3.00 or send your own tape and $1.00. Paul’s address is POB 2034, Mesa, AZ 85204.

Figure C

Object                       RA    Dec    Date   Time  ALT  AZM
w Galaxy Cluster 1656       13.5  -47.3   6/1     3    -26  222
Hercules Cluster M13        16.7   36.5   8/15   22     65  268
Whirlpool Galaxy M51        13.5   47.3   10/14  18     33  315
Dumbell Nebula M27          20.0   22.7   10/13  19     90  180
Eskimo Nebula 2392           7.2   21.0   12/7    1     68  165

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.