Cassette Label Maker

Author(s): Lee Gayman
Publication: Syntax
Pub Details: Syntax/Syntax ZX80 v4 n12 (Volume 4, Issue 12)
Date: December 1983
Pages: 7-8

This program lets you design a three-line label on the screen with all characters available, then just hit “C” to copy as many labels as needed on the printer.

Once printed, you need only a pair of scissors and a little glue for really professionally labeled cassettes.

E. Arthur Brown now offers thermal mailing labels for the 2040, $24.95 for 1000 (New Products this issue).

In testing this program, we found you can edit, rather than re-enter, when the messages of lines 620 or 640 appear. Do this:

  • Move the cursor right
  • Key: ‘+”1st”+xx$(aTOb)+”2nd”‘
  • Press ENTER (or NEWLINE)

where 1st and 2nd stand for any string you want to add in those positions. Replace xx with X for the first line, Y for the second, or Z for the third. Use your choice of positions for a and b to slice the string you want to edit.

Hit BREAK to exit.–KO

  10 REM  CASSETTE LABEL PROGRAM
20 REM
30 REM BY L. GAYMAN 9/12/83
40 REM MECHANICSBURG, PA.
50 REM
60 LET X$=" "
70 LET Y$=" "
80 LET Z$=" "
90 PRINT " CASSETTE LABEL PROGRAM "
100 PRINT ,,"USE WITH PRINTER TO MAKE LABELS."
110 PRINT ,,"YOU MAY MAKE 3 LINES, EACH","LIMITED TO 30 CHARACTERS. ENTER","ONE LINE AT A TIME, FOLLOWED BY","N/L."
120 PRINT AT 20,0;"NOW ENTER LINE 1:"
130 PRINT AT 10,0;"▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄"
140 FOR I=1 TO 3
150 PRINT "▌";TAB 31;"▐"
160 NEXT I
170 PRINT "▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀"
180 INPUT A$
190 IF A$>"" THEN LET X$=A$
200 IF A$="" THEN GOTO 270
210 IF LEN A$>30 THEN GOSUB 620
220 IF LEN A$>30 THEN GOTO 180
230 PRINT AT 11,1;" "
240 PRINT AT 11,1;A$
250 GOSUB 640
260 GOTO 180
270 PRINT AT 20,0;"NEXT, PLEASE ENTER LINE 2: "
280 INPUT B$
290 IF B$>"" THEN LET Y$=B$
300 IF B$="" THEN GOTO 370
310 IF LEN B$>30 THEN GOSUB 620
320 IF LEN B$>30 THEN GOTO 280
330 PRINT AT 12,1;" "
340 PRINT AT 12,1;B$
350 GOSUB 640
360 GOTO 280
370 PRINT AT 20,0;"NOW ENTER YOUR LAST LINE: "
380 INPUT C$
390 IF C$>"" THEN LET Z$=C$
400 IF C$="" THEN GOTO 470
410 IF LEN C$>30 THEN GOSUB 620
420 IF LEN C$>30 THEN GOTO 380
430 PRINT AT 13,1;" "
440 PRINT AT 13,1;C$
450 GOSUB 640
460 GOTO 380
470 PRINT AT 20,0;" "C" FOR COPY,"N" FOR NEW LABEL "
480 PAUSE 4E4
490 LET D$=INKEY$
500 IF D$="N" THEN CLS
510 IF D$="N" THEN RUN
520 IF D$="" THEN GOTO 480
530 LPRINT "▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄"
540 LPRINT "▌";X$;TAB 31;"▐"
550 LPRINT "▌";Y$;TAB 31;"▐"
560 LPRINT "▌";Z$;TAB 31;"▐"
570 LPRINT "▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀"
580 FOR I=1 TO 3
590 LPRINT
600 NEXT I
610 GOTO 470
620 PRINT AT 20,0;"TOO MANY LETTERS,PLEASE RE-ENTER"
630 RETURN
640 PRINT AT 20,0;" PRESS N/L IF O.K. (OR RE-ENTER)"
650 RETURN
9998 SAVE "L"
9999 RUN
SYNTACTIC SUM: 48019, 8K ROM
Listing lines 130-170 with the box graphics
Listing lines 130-170 with the box graphics
Listing lines 530-570 with the label border graphics
Listing lines 530-570 with the label border graphics

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.