Graphic Screen$ Dump for the Tandy DMP105

See all articles from Sinc-Link v10 n2
Author(s): Abed Kahale
Publication: Sinc-Link
Pub Details: Sinc-Link v10 n2 (Volume 10, Issue 2)
Date: March/April 1992
Pages: 9

This printer is not supported by any software that I know of, having a non Centronics protocol but a fairly good 7 pin head dot matrix with graphics capability. The 176 vertical pixcels divided by 7 do not result in an integer number. So, after a two hours session with Bob Swoger, the following program was developed and it worked, but SLOW, 15 minutes for the screen dump. Later on, I was able to convert the working part of the program to M.C. using the Timachine compiler. Now it only takes 20 seconds for Brooke$ minus a piece of chin. B Integer out of range.

Brooke$ screen dump on the Tandy DMP105
Brooke$ screen dump on the Tandy DMP105
  1 REM   TANDY DMP105   PRINTER DRIVER   by Abed Kahale 1/92
4 REM CLEAR 64769: REM Start address-1.
5 REM RANDOMIZE USR 100: LOAD "PDRVR.CC"CODE 64770
20 RANDOMIZE USR 100: OPEN #3,"LP"
30 RANDOMIZE USR 100: POKE 16092,0: REM no line feed, otherwise double spacing results.
50 RANDOMIZE USR 100: POKE 16093,32: REM LPRINTs & CHR$s sent to printer.
60 LPRINT CHR$ 10: REM single line feed.
65 REM LPRINT CHR$ 27;CHR$ 19: REM PICA gives expanded picture BELOW.
80 LPRINT CHR$ 27;CHR$ 23: REM ELITE gives correct picture.
90 REM LPRINT CHR$ 27;CHR$ 20: REM CONDENSED gives hi-res narrow picture.
95 RANDOMIZE USR 100: LOAD "BROOKE.C$"SCREEN$
100 LPRINT CHR$ 18: REM Puts printer in graphics mode.
110 REM RANDOMIZE USR 64770
120 REM !INT R,C,B: REM TIMACHINE Instructions.
130 REM ! LPRINT
150 REM ! OPEN #: REM TIMACHINE starts.
155 FOR Y=0 TO 175 STEP 7: LET R=175-Y: REM vertical pixels from the top. (STEP 8) for 8-pin head.
160 FOR C=0 TO 255: REM Horizontal pixels.
170 LET B=0
180 LET B=B+POINT (C,R-1)
190 LET B=B+2*POINT (C,R-2)
200 LET B=B+4*POINT (C,R-3)
210 LET B=B+8*POINT (C,R-4)
220 LET B=B+16*POINT (C,R-5)
230 LET B=B+32*POINT (C,R-6)
240 LET B=B+64*POINT (C,R-7)
250 LET B=B+128
255 IF IN 127<>236 THEN GO TO 255: REM checks printer READY.
260 LPRINT CHR$ B;
270 NEXT C
280 LPRINT CHR$ 27;CHR$ 90;CHR$ 0: REM carriage return.
290 NEXT Y
300 LPRINT CHR$ 30: REM Back to character mode.
310 REM ! CLOSE #: REM TIMACHINE ends.
Fairlight - a prelude title screen dump
Fairlight – a prelude title screen dump

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.