Use Math to introduce your children to the ZX/TS and give them experience with basic skills of addition, subtraction, multiplication and division. Math provides 4 skill levels with 10 problems in a set. Students get 3 tries on each problem before getting an answer.
Use the mix-up choice to choose randomly among the 4 operations. Division is protected from remainders, and subtraction never yields a negative answer.
Enter the listing in FAST mode, then switch your ZX/TS to SLOW and SAVE by typing RUN 100. Math self-starts and contains input prompts.
Inverse graphics are:
650 six graphic shift D
1120 graphic shift space
1130 graphic shift H
1140 graphic shift space
1150 graphic shift H
1240 graphic shift H, A, H, A between words graphic shift H then repeat beginning sequence.
10 REM ***********************
20 REM * MATH PRACTICE *
30 REM * BY B.L. BOYER *
40 REM ***********************
50 REM
60 LET I=INT (D/E)
70 LET D=I*E
80 LET D$=STR$ D
90 RETURN
100 SAVE "MATH"
110 PRINT AT 10,0;"PLEASE TELL ME YOUR NAME"
120 DIM G$(10)
130 INPUT G$
140 DIM B$(5,14)
150 LET B$(1)="ADDITION"
160 LET B$(2)="SUBTRACTION"
170 LET B$(3)="MULTIPLICATION"
180 LET B$(4)="DIVISION"
190 LET B$(5)="MIX-UP"
200 LET GUESS=0
210 LET R=0
220 LET W=0
230 RAND
240 CLS
250 PRINT "THANK YOU, ";G$;AT 1,1;"NOW, PLEASE SELECT";AT 2,1;"1. (+) ";B$(1);AT 3,1;"2. (-) ";B$(2);AT 4,1;"3. (X) ";B$(3);AT 5,1;"4. (/) ";B$(4);AT 6,1;"5. (?) ";B$(5)
260 IF INKEY$<>"" THEN GOTO 260
270 IF INKEY$="" THEN GOTO 270
280 LET A$=INKEY$
290 REM *CHECK FOR VALID ENTRY
300 IF CODE A$<29 OR CODE A$>33THEN GOTO 260
310 LET SL=VAL A$
320 LET A=SL
330 PRINT AT 8,0;"YOU PICKED ";A;" ";B$(A)
340 PRINT AT 10,0;"NOW PICK DIFFICULTY";AT 11,0;"LEVEL 1 TO 4"
350 IF INKEY$<>"" THEN GOTO 350
360 IF INKEY$="" THEN GOTO 360
370 LET C$=INKEY$
380 IF CODE C$<29 OR CODE C$>32THEN GOTO 380
390 LET C=VAL C$
400 FOR K=1 TO 10
410 FAST
420 IF SL=5 THEN LET A=INT (RND*4)+1
430 CLS
440 PRINT AT 1,1;B$(A);TAB 17;"LEVEL ";C;AT 6,10;"PROBLEM ";K
450 DIM D$(C)
460 DIM E$(C)
470 IF C>1 AND A>=3 THEN DIM E$(C-1)
480 IF C>2 AND A=4 THEN DIM E$(C-2)
490 LET D$=STR$ (INT (RND*9999)+0)
500 LET E$=STR$ (INT (RND*9999)+0)
510 LET D=VAL D$
520 LET E=VAL E$
530 IF D>E THEN GOTO 600
540 LET T$=E$
550 LET TEMP=E
560 LET E=D
570 LET E$=D$
580 LET D=TEMP
590 LET D$=T$
600 IF (INT (D/E)<>D/E) AND A=4THEN GOSUB 60
610 LET T=LEN STR$ D
620 LET S=LEN STR$ E
630 SLOW
640 IF A<4 THEN PRINT AT 10,10-T;D$;TAB 10-S;E$;AT 12,5;"-----";AT 13,0;" "
650 IF A=4 THEN PRINT AT 14,5;"▒▒▒▒▒▒";AT 15,5-S;E$;AT 15,5;")";AT 15,6;D$
660 IF A=1 THEN PRINT AT 11,4;"+"
670 IF A=2 THEN PRINT AT 11,4;"-"
680 IF A=3 THEN PRINT AT 11,4;"X"
690 PRINT AT 21,0;"ENTER YOUR ANSWER, PLEASE"
700 INPUT ANS
710 IF A=1 THEN LET CORANS=D+E
720 IF A=2 THEN LET CORANS=D-E
730 IF A=3 THEN LET CORANS=D*E
740 IF A=4 THEN LET CORANS=D/E
750 PRINT AT 20,0;" ";AT 21,0;" "
760 IF CORANS=ANS THEN GOSUB 900
770 IF CORANS<>ANS THEN GOTO 1040
780 NEXT K
790 CLS
800 PRINT AT 1,1;B$(SL);TAB 17;"LEVEL ";C
810 PRINT AT 9,1;G$;AT 10,1;"YOU HAD";AT 12,1;R;" RIGHT AND ";W;" WRONG"
820 FOR I=1 TO 30
830 NEXT I
840 PRINT AT 10,1;"WOULD YOU";AT 12,1;"LIKE TO TRY ANOTHER GAME?";AT 21,1;"ENTER (Y)ES OR (N)O"
850 IF INKEY$<>"" THEN GOTO 850
860 IF INKEY$="" THEN GOTO 860
870 LET A$=INKEY$
880 IF CODE A$=62 THEN GOTO 200
890 STOP
900 REM **RECOG. CORRECT ANSWER
910 LET R=R+1
920 LET F$=STR$ CORANS
930 LET U=LEN F$
940 LET GUESS=0
950 FOR J=1 TO U
960 PRINT AT 10,20;"YOU ARE";AT 11,20;"CORRECT"
970 IF A<>4 THEN PRINT AT 13,10-J;F$(U-J+1)
980 IF A=4 THEN PRINT AT 13,6+T-J;F$(U-J+1)
990 PRINT AT 10,20;"YOU ARE";AT 11,20;"CORRECT"
1000 NEXT J
1010 FOR I=1 TO 15
1020 NEXT I
1030 RETURN
1040 REM *INFORM OF WRONG ANSWER
1050 LET F$=STR$ CORANS
1060 LET U=LEN F$
1070 IF GUESS=2 THEN GOTO 1260
1080 FOR J=1 TO U
1090 PRINT AT 10,20;"YOU ARE";AT 11,20;" WRONG "
1100 FOR I=1 TO 4
1110 NEXT I
1120 IF GUESS=0 AND A<>4 THEN PRINT AT 13,10-J;"█"
1130 IF GUESS<>0 AND A<>4 THEN PRINT AT 13,10-J;"▒"
1140 IF GUESS=0 AND A=4 THEN PRINT AT 13,6+T-J;"█"
1150 IF GUESS<>0 AND A=4 THEN PRINT AT 13,6+T-J;"▒"
1160 PRINT AT 10,20;"YOU ARE";AT 11,20;" WRONG "
1170 NEXT J
1180 FOR I=1 TO 5
1190 NEXT I
1200 LET GUESS=GUESS+1
1210 PRINT AT 10,20;" ";AT 11,20;" "
1220 PRINT AT 13,20;"YOU HAVE";AT 14,20;3-GUESS;" CHANCES"
1230 IF GUESS=2 THEN PRINT AT 14,28;" ";AT 17,20;G$;AT 18,20;"THINK HARDER"
1240 PRINT AT 21,0;"▒▒▒▒PLEASE▒TRY▒AGAIN▒▒▒▒▒"
1250 GOTO 700
1260 LET W=W+1
1270 PRINT AT 13,20;" ";AT 14,20;" "
1280 FOR J=1 TO U
1290 PRINT AT 10,20;"THE CORRECT";AT 11,20;"ANSWER"
1300 IF A<>4 THEN PRINT AT 13,10-J;F$(U-J+1)
1310 IF A=4 THEN PRINT AT 13,6+T-J;F$(U-J+1)
1320 PRINT AT 10,20;"THE CORRECT";AT 11,20;"ANSWER"
1330 NEXT J
1340 FOR I=1 TO 10
1350 NEXT I
1360 LET GUESS=0
1370 GOTO 780
SYNTACTIC SUM: 53897, 8K ROM
Media
Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.