Monsters

In this game you (represented by a 0) try to avoid four monsters (represented by Xs). You must go through a randomly generated maze, get to the other side and land on a black bar without being caught by a monster.

To move, hit a key from 1 to 8. Hitting 1 allows you to move to the upper left and hitting 4 allows you to move to the upper right. Keys 5 through 8 allow you to move in the direction of the arrow on that key.

To play again, just hit ENTER. To end the game, hit the N key and ENTER. If you can’t get through the maze you may exit the program by hitting BREAK. You can rerun the program by hitting RUN and ENTER.

   1 GOTO 9900
   2 LET J=P
   3 LET P=P+(INKEY$="8")-(INKEY$="5")+((INKEY$="6")-(INKEY$="7"))*33+((INKEY$="3")-(INKEY$="1"))*34+((INKEY$="2")-(INKEY$="4"))*32
   4 LET P=P+(PEEK P=118)
   6 IF NOT P=J THEN POKE J,0
   7 IF PEEK P=8 OR PEEK P=61 THEN LET P=J
   8 IF PEEK P=5 THEN GOTO 8000
   9 POKE P,52
  10 RETURN
  11 FOR I=1 TO 4
  12 GOSUB 2
  14 LET J=A(I)-D
  16 LET K=P-D
  17 LET L=INT (K/33)
  19 LET K=K-L*33
  20 LET J=J-SGN ((INT (J/33)-L))*33-SGN (((J-INT (J/33)*33))-K)
  22 POKE A(I),0
  24 IF (PEEK (D+J)<>118 AND (((PEEK (D+J)=8) AND INT (RND*9)+1>4))) OR PEEK (D+J)=0 OR PEEK (D+J)=52 THEN LET A(I)=D+J
  25 IF PEEK A(I)=52 THEN GOTO 9000
  26 POKE A(I),61
  28 NEXT I
  30 GOTO 11
8000 POKE P,151
8001 PRINT "YOU HAVE PROVED YOURSELF TO BE SUPERIOR TO THE SKELETONS YOU WERE PITTED AGAINST."
8002 GOTO 9002
9000 POKE A(I),180
9001 PRINT "YOU HAVED PROVED TO BE INFERIOR TO THE SKELETONS YOU WERE PITTED AGAINST. YOUR RACE WILL BE ELIMINATED FROM SOCIETY."
9002 PRINT "PLAY AGAIN?(Y/N)"
9004 INPUT A$
9006 IF A$="N" THEN STOP
9008 CLS
9900 LET P=VAL "133+PEEK 16396+256*PEEK 16397"
9901 FAST
9902 DIM A(VAL "4")
9906 FOR I=SGN PI TO VAL "4"
9912 LET A(I)=VAL "49+PEEK 16396+256*PEEK 16397"+INT (RND*6)+INT (RND*5+1)*33
9914 NEXT I
9916 FOR I=SGN PI TO VAL "6"
9918 FOR J=SGN PI TO VAL "20"
9919 LET A$=" ▒"
9920 IF VAL "I=1 OR I=8" THEN LET A$="▒▒"
9921 PRINT A$(VAL "INT (RND*8)+1>5"+SGN PI);
9922 NEXT J
9924 PRINT "▌"
9926 NEXT I
9928 SLOW
9937 LET D=VAL "PEEK 16396+256*PEEK 16397+1"
9938 POKE P,CODE "O"
9940 GOTO VAL "11"
SYNTACTIC SUM: 5731, 8K/16K

---

Chief Editor, Ann Zevnik, will be taking a 2 week leave of absence from SYNTAX to get married. Ann is returning to her home town Peoria, IL, for the big day on Oct. 9.