Banners

Gallery

Source Code

   1 REM ***     BANNERS     ***
   2 REM ***********************
  10 DIM D$(64)
  20 INPUT M$
  30 FAST 
  40 FOR C=1 TO LEN M$
  50 LET A$=M$(C)
  60 IF CODE A$>63 THEN LET A$=CHR$ (CODE M$(C)-128)
  65 FOR N=0 TO 7
  70 LET Z=PEEK (7680+N+8*CODE A$)
  80 FOR X=1 TO 8
  90 LET Z=Z/2
 100 IF Z<>INT Z THEN GOTO 500
 110 LET D$(N*8+X)="0"
 115 IF CODE M$(C)>63 THEN LET D$(N*8+X)="1"
 120 IF N*8+X=64 THEN GOSUB 900
 130 LET Z=INT Z
 140 NEXT X
 150 NEXT N
 160 NEXT C
 170 SLOW 
 180 GOTO 1010
 500 LET D$(N*8+X)="1"
 505 IF CODE M$(C)>63 THEN LET D$(N*8+X)="0"
 510 GOTO 120
 900 FOR P=8 TO 1 STEP -1
 910 FOR F=1 TO 2
 920 FOR E=7 TO 0 STEP -1
 930 IF D$(E*8+P)="1" THEN LPRINT "% % % % ";
 940 IF D$(E*8+P)="0" THEN LPRINT "    ";
 950 NEXT E
 960 NEXT F
 970 NEXT P
 980 RETURN 
1000 SAVE "1007%3"
1010 CLS 
1020 PRINT TAB 8;"%Z%X% %B%A%N%N%E%R%S"
1030 PRINT TAB 8;"**********"
1040 PRINT ,,;"THIS PROGRAM WILL PRINT ON THE  ZX PRINTER LETTERS AND SYMBOLS  3"" HIGH IN THE FORM OF BANNERS"
1050 PRINT ,,;"THE LENGTH OF THE BANNER IS UP  TO YOU. ENTER BELOW AND PRESS   ENTER"
1060 PRINT ,,;"LETTERS AND GRAPHICS WILL WORK  FUNCTIONS WILL NOT"
1090 GOTO 10