Source Code
1 REM "CHAR"ECTOR DESIGN: REM M .JESKIN,LI,NY: CLS
2 PRINT AT 1,1;"USE CURSOR KEYS TO MOVE THE"
3 PRINT AT 2,1;"ASTERISK AROUND THE GRID."
4 PRINT AT 4,1;"PRESS 9 TO DARKEN A SQUARE"
5 PRINT AT 5,1;"PRESS 0 TO ERASE A SQUARE"
6 PRINT AT 6,1;"PRESS F WHEN FINISHED AND"
7 PRINT AT 7,1;"THE COMPUTER WILL CALCULATE THE"
8 PRINT AT 8,1;"THE DECIMAL DATA NEEDED FOR THE"
9 PRINT AT 9,1;"FIGURE AND PRINT THE CHARECTOR"
10 PRINT AT 10,1;"AT NORMAL SIZE BELOW THE GRID"
11 PRINT AT 11,1;"PRESS P TO PRINT COPY OF SCREEN"
12 PRINT AT 12,1;"PRESS A TO ADJUST THE GRID"
13 PRINT AT 13,1;"PRESS E TO ERASE AND START OVER"
14 PRINT AT 15,1;"COPY THESE INSTRUCTIONS "
15 PRINT AT 20,1;"PRESS ANY KEY TO START"
16 PAUSE 6000: RUN 18
18 FOR n=0 TO 7: READ d
19 POKE 65368+n,d: NEXT n
20 DATA 255,129,129,129,129,129,129,255
25 FOR i=1 TO 8: PRINT "\a\a\a\a\a\a\a\a": NEXT i
30 LET r=0: LET c=0
35 PRINT AT 15,0;"PRESS f WHEN FINISHED."
45 PRINT : PRINT
50 PRINT "a=ALTER"'"e=ERASE"'"p=PRINT"
100 PRINT OVER 1;AT r,c;"*"
105 IF INKEY$="" THEN GO TO 105
110 LET m$=INKEY$: BEEP .01,20
115 IF m$="f" THEN GO TO 160
120 IF m$="9" THEN PRINT AT r,c;"\::": BEEP .05,-10: GO TO 100
125 IF m$="0" THEN PRINT AT r,c;"\a": BEEP .05,50: GO TO 100
130 LET pr=r: LET pc=c
135 LET r=r+(m$="6")-(m$="7")
140 LET c=c+(m$="8")-(m$="5")
145 IF c<0 OR c>7 THEN LET c=pc
150 IF r<0 OR r>7 THEN LET r=pr
155 PAUSE 3: PRINT OVER 1;AT pr,pc;"*": GO TO 100
160 LET byte=0: DIM d(8)
165 PRINT OVER 1;AT r,c;"*"
170 FOR a=171 TO 115 STEP -8
175 LET bit=8
180 FOR i=4 TO 60 STEP 8
185 LET bit=bit-1
190 IF POINT (i,a) THEN LET d(byte+1)=d(byte +1)+2^bit
195 PRINT AT byte,10;" ";AT byte,10;d(byte+1): NEXT i
200 POKE 65376+byte, d(byte+1)
205 LET byte=byte+1
210 NEXT a
215 PRINT AT 10,5;"\b"
220 IF INKEY$="" THEN GO TO 220
225 IF INKEY$="a" THEN GO TO 100
230 IF INKEY$="e" THEN RUN 18
235 IF INKEY$="p" THEN COPY
240 GO TO 220
