Concentration

   10 PAPER 7: INK 0: FLASH 0: BORDER 7: CLS 
   20 FOR I=1 TO 4: READ X$: FOR J=0 TO 7: READ X: POKE USR X$+J,X: NEXT J: NEXT I
   30 DATA "H",34,119,127,127,62,62,28,8,"C",28,28,8,107,127,107,8,8,"D",8,28,62,127,62,28,8,0,"S",8,28,62,127,127,127,107,8
   40 LET S$="HCDS": LET V$="A23456789TJQK"
   50 DIM C(52): DIM T(52): DIM V(52): DIM S(4)
   60 FOR I=1 TO 4: LET S(I)=CODE S$(I)+79: NEXT I
   70 FOR I=1 TO 52: LET C(I)=I: NEXT I
   80 FOR I=1 TO 52: LET R=INT (52*RND)+1:: LET Z=C(I): LET C(I)=C(R): LET C(R)=Z: NEXT I
   90 FOR I=1 TO 52: LET T(I)=INT ((C(I)-1)/13)+1: LET V(I)=C(I)-13*(T(I)-1): NEXT I
  100 PAPER 4: PRINT TAB 31: FOR I=1 TO 5: FOR J=1 TO 2: PRINT " ██ ██ ██ ██ ██ ██ ██ ██ ██ ██ ": NEXT J: PRINT TAB 31: NEXT I
  110 PRINT " ██ ██ "'" ██ ██ ": PRINT TAB 7
  120 PAPER 7: PLOT 0,175: DRAW 0,-151: DRAW 55,0: DRAW 0,24: DRAW 192,0: DRAW 0,127: DRAW -247,0
  130 FOR N=1 TO 52: GO SUB 390: PRINT AT L1,C1; INVERSE 1;N: NEXT N
  140 LET CH=0: LET PR=0: PRINT AT 16,8;"CHOICES: 0   PAIRS: 0"
  150 PRINT AT 18,8,,: INPUT "ENTER FIRST LOCATION: =";P1
  160 IF P1<>INT P1 OR P1>52 OR P1<1 THEN INPUT "INVALID - REENTER (1)=";P1: GO TO 160
  170 IF V(P1)=0 THEN INPUT "ALREADY PAIRED -REENTER (1)=";P1: GO TO 160
  180 LET N=P1: GO SUB 390: GO SUB 340
  190 INPUT "ENTER SECOND LOCATION: =";P2
  200 IF P2<>INT P2 OR P2>52 OR P2<1 THEN INPUT "INVALID - REENTER =";P2: GO TO 200
  210 IF V(P2)=0 THEN INPUT "ALREADY PAIRED -REENTER =";P2: GO TO 200
  220 IF P1=P2 THEN INPUT "PAIR MUST BE SEPARATE - REENTER ";P2: GO TO 200
  230 LET N=P2: GO SUB 390: GO SUB 340
  240 LET CH=CH+1: PRINT AT 16,17;CH
  250 IF V(P1)<>V(P2) THEN GO TO 290
  260 PRINT AT 18,8; INK 1;"Correct Choice!": LET V(P1)=0: LET V(P2)=0: LET PR=PR+1: PRINT AT 16,28;PR: BEEP .5,25: BEEP .5,15
  270 IF PR=26 THEN PRINT AT 20,0;"YOU HAVE FINISHED AFTER ";CH;"TURNS": BEEP .5,20: BEEP .5,25: BEEP .5,20: GO TO 310
  280 GO TO 300
  290 PRINT AT 18,8;"DO NOT MATCH ": BEEP 1,-15: PAUSE 150: GO SUB 440: LET N=P1: GO SUB 390: GO SUB 440
  300 GO TO 150
  310 PAUSE 150: INPUT "PRESS 1 TO REPETE OR 0 TO STOP "; LINE Z$
  320 IF Z$="1" THEN RUN 
  330 STOP 
  340 PAPER 7: LET VN=V(N): LET SN=T(N): INK 2-(SN=2*INT (SN/2))*2
  350 PRINT AT L1,C1;V$(VN);" ";AT L1+1,C1;" ";CHR$ S(SN)
  360 INK 0
  370 PLOT C1*8-1,176-8*L1: DRAW 17,0: DRAW 0,-17: DRAW -17,0: DRAW 0,17
  380 BEEP 1,5: RETURN 
  390 LET X10=INT (N/10): LET X1=N-10*X10
  400 IF X1=0 THEN LET X10=X10-1: LET X1=10
  410 LET L1=1+3*X10
  420 LET C1=3*X1-2
  430 RETURN 
  440 PRINT AT L1,C1; INVERSE 1;N;: IF N<10 THEN PRINT "█"
  450 PRINT AT L1+1,C1;"██": RETURN 
 9000 SAVE "CONC" LINE PI