Source Code
10 REM "DONKEY"
15 POKE 16418,0
20 LET C=1
25 LET G=0
30 LET D=21
40 LET F=-1
50 LET E=1
60 LET A=22
70 LET B=4
200 PRINT AT 7,0;"HX XXXXXXXXXXXXXXXXXXXXXXXXXXXX"
201 PRINT AT 0,0;"% % %D%O%N%K%E%Y%-%K%O%N%G% % % % % % % % % % % % % % % % % % "
210 PRINT AT 11,0;"XXX XXXXXXXXXXXXX X X XXX XXXXH"
220 PRINT AT 15,0;"HXX XXXXX XXXXXXX X XXXXXXXXXXX"
230 PRINT AT 19,0;"XXX XXXXXXXXX XXXXXXXXXXXX XXXH"
240 PRINT AT 23,0;"XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXH"
250 FOR N=1 TO 4
260 PRINT AT 7+N,0;"H";AT 11+N,30;"H";AT 15+N,0;"H";AT 19+N,30;"H"
270 NEXT N
280 PRINT AT 6,7;"H H \~~ \;;"
290 PRINT AT 5,7;"H H \ .% \. "
300 PRINT AT 4,7;"HXXXXH \: \;;\ :"
310 PRINT AT 3,9;"% % "
320 PRINT AT 2,8;"\ :% \: ";AT 1,9;"O"
330 PRINT AT 20,0;"\..\:.";AT 21,0;"% % ";AT 22,0;"% % "
350 PRINT AT 10,C;" O O O ";AT 14,D;" O O O ";AT 18,C;" O O O ";AT 22,D;" O O O "
351 PRINT AT A,B;
352 LET A$=CHR$ PEEK (PEEK 16398+256*PEEK 16399)
353 PRINT AT A,B;"\ :"
354 IF A$="O" THEN GOTO 9000
360 LET C=C+E
370 LET D=D+F
375 PRINT AT 6,16;;"\;; \~~";AT 4,16;"\ .\;;\':";AT 1,11;"HELP"
376 PRINT AT A+1,B;
377 LET B$=CHR$ PEEK (PEEK 16398+256*PEEK 16399)
378 IF B$=" " THEN GOTO 600
380 IF C=21 THEN LET E=-1
390 IF C=2 THEN LET E=1
400 IF D=2 THEN LET F=1
410 IF D=21 THEN LET F=-1
411 LET G=G-1
412 IF A=6 AND B=7 THEN GOTO 9080
460 PRINT AT A,B;A$
470 IF INKEY$="7" AND A$="H" THEN GOSUB 6000
480 LET B=B+(INKEY$="8" AND B<30)-(INKEY$="5" AND B>0)
490 IF INKEY$="I" THEN GOSUB 7000
500 IF INKEY$="T" THEN GOSUB 8000
505 PRINT AT 6,16;"\~~ \;;";AT 4,16;"\:'\;;\. ";AT 1,11;" "
510 GOTO 350
600 PRINT AT A,B;" ";AT A+1,B;"\ :"
610 PRINT AT A+2,B;
620 LET G$=CHR$ PEEK (PEEK 16398+256*PEEK 16399)
630 IF G$<>" " THEN LET A=A+1
631 IF G$<>" " THEN GOTO 9000
632 LET A=A+1
650 GOTO 600
\n6000 FOR N=A TO A-3 STEP -1
\n6001 PRINT AT N,B;"\ :"
\n6002 FOR J=1 TO 3
\n6003 NEXT J
\n6004 PRINT AT N,B;"H"
\n6005 NEXT N
\n6006 PRINT AT N,B;"\ :";AT N,B;" "
\n6007 LET A=A-4
\n6009 RETURN
\n7000 PRINT AT A,B;" ";AT A-1,B;"\.'";AT A-1,B;" ";AT A-2,B;"\ :";AT A-2,B;" ";AT A-2,B+1;"\ :";AT A-2,B+1;" ";AT A-2,B+2;"\'.";AT A-2,B+2;"\ :";AT A-2,B+2;" ";AT A-1,B+2;"\'.";AT A-1,B+2;" "
\n7001 PRINT AT A,B+2;
\n7002 LET U$=CHR$ PEEK (PEEK 16398+256*PEEK 16399)
\n7003 IF U$="O" THEN GOTO 9000
\n7004 PRINT AT A,B+2;"\ :";AT A,B+2;" "
\n7010 LET B=B+2
\n7020 RETURN
\n8000 PRINT AT A,B;" ";AT A-1,B;"\'.";AT A-1,B;" ";AT A-2,B;"\ :";AT A-2,B;" ";AT A-2,B-1;"\ :";AT A-2,B-1;" ";AT A-2,B-2;"\'.";AT A-2,B-2;" ";AT A-1,B-2;"\ :";AT A-1,B-2;" "
\n8001 PRINT AT A,B-2;
\n8002 LET U$=CHR$ PEEK (PEEK 16398+256*PEEK 16399)
\n8003 IF U$="O" THEN GOTO 9000
\n8004 PRINT AT A,B-2;"\ :";AT A,B-2;" "
\n8010 LET B=B-2
\n8020 RETURN
\n9000 FOR N=1 TO 30
\n9010 PRINT AT A,B;"\ :";AT A,B;"\''";AT A,B;"\ :";AT A,B;"\.."
\n9020 NEXT N
\n9040 PRINT AT 10,10;"GAME OVER"
\n9050 PAUSE 200
\n9060 CLS
\n9070 GOTO 1
\n9080 PRINT AT 2,25;"\':\.:\' ";AT 3,26;"\' "
\n9081 LET S=S+G
\n9090 FOR N=1 TO 60
\n9091 NEXT N
\n9092 PRINT AT 2,25;"\':\ .\:'";AT 3,25;"\' "
\n9093 PRINT AT 1,0;"SCORE: ";S
\n9094 PRINT AT 3,9;" ";AT 2,8;" ";AT 1,9;" ";
\n9095 PRINT AT 4,16;"\:'% \:'";AT 3,16;" %"\ .O HELP"
\n9100 FOR U=1 TO 80
\n9120 NEXT U
\n9125 CLS
\n9130 GOTO 10
\n9140 SAVE "1017%6"
\n9150 RUN
