Lollipops

    5 REM  ** LOLLIPOPS **                        by                        Warren Fricke
   10 GO SUB 300
   20 RANDOMIZE : GO TO 420
   30 BORDER 6: PAPER 7: CLS 
   35 FOR n=1 TO 10: PRINT BRIGHT 1; PAPER 7;AT 19*RND+1,15*RND+8;" ": NEXT n
   40 FOR N=1 TO 75
   50 PRINT PAPER 6-INT (7*RND*RND);AT 19*RND+1,29*RND+1;" "
   60 NEXT N
   70 LET l=11: LET c=1: LET k=1
   80 LET p=0: LET s=0: LET t=0
   90 LET ll=l: LET cc=c
   95 POKE 23658,8
  100 IF c<1 OR c>28 THEN LET k=-k
  105 LET a$=INKEY$: LET st=STICK(1,1)
  110 LET l=l+((a$="Z" OR st=2) AND l<20)-((a$="Q" OR st=1) AND l>1)
  120 LET c=c+k
  130 LET a=ATTR (l,((c+2) AND k=1)+(c AND k=-1))/8
  140 IF a<=6 THEN BEEP .05,25: LET p=p+1: LET s=s+(7-1)^2
  145 IF a=15 THEN BEEP .5,-35: GO TO 200
  150 PRINT PAPER 7;AT l,c;("--O" AND k=1)+("O--" AND k=-1)
  160 PAUSE 5
  170 PRINT PAPER 7;AT ll,cc;"   "
  180 LET t=t+1: IF t>=300 THEN GO TO 200
  190 GO TO 90
  200 PRINT FLASH 1;AT 0,9;" GAME IS OVER ": PAUSE 120
  210 PRINT AT 0,2;"Press C-key or FIRE button,           to play again."
  220 PRINT AT 21,0;"You got ";p;" pops.";AT 21,20;"Score = ";s
  230 IF STICK(2,1)=1 OR INKEY$="C" THEN GO TO 30
  240 GO TO 230
  300 PRINT FLASH 1;AT 0,7;" ** LOLIPOPS ** ": RETURN 
  420 PRINT AT 2,0;"Your lollipop sweeps left and   right, back and forth about 10  times thru a field of assorted  flavors."
  430 PRINT '"The Q and Z keys control the up and down position of the lolli- pop. You may also use a joy     stick plugged into the port on  your left."
  440 PRINT '"You get credit for each flavor  you try, but the score depends  upon the flavor itself."
  450 PRINT '"Press "; FLASH 1;" ENTER "; FLASH 0;" to continue."
  460 INPUT z$: CLS 
  470 GO SUB 300
  480 PRINT AT 2,0;"The highest scoring is licorice and they are in this order:"
  490 PRINT AT 5,9;"Licorice...49";TAB 9;"Grape......36";TAB 9;"Cherry.....25";TAB 9;"Strawberry.16";TAB 9;"Lime........9";TAB 9;"Pistachio...4";TAB 9;"Lemon.......1"
  495 PRINT AT 13,0;"BUT BE CAREFUL. IT'S A NO-NO TO TASTE TNE PEPPERMINT. "; BRIGHT 1; PAPER 7;" "
  500 PRINT AT 17,0;"PRESS, "; FLASH 1;" ENTER "; FLASH 0;" TO START THE GAME."
  510 INPUT Z$: GO TO 30
 8999 STOP 
 9000 SAVE "Lollipops": PRINT "Rewind & key ENTER to Verify.": PAUSE 0: VERIFY "Lollipops"