Type: Program
Platform(s): TS 2068
Save the Earth: aliens are invading and are trying to build cities on Earth. Shoot them before they build their cities, conquer Earth, and use you for toothpicks.
Saucers
1 REM saucers
3 GO SUB 5000
4 GO SUB 4000
5 LET l=16: LET k=11: LET pos=10
6 LET m=3: LET n=INT (RND*26)+2
8 LET score=0
9 LET LAN=0
10 PLOT 0,0: DRAW 97,50
20 PLOT 255,0: DRAW -97,50
30 PLOT 137,50: DRAW 50,-50
40 PLOT 117,50: DRAW -50,-50
50 PLOT 70,50: DRAW -70,-15
60 PLOT 185,50: DRAW 70,-15
70 PLOT 0,50: DRAW 255,0
80 PLOT 127,50: DRAW 0,-50
90 PLOT 0,40: DRAW 255,0
100 PLOT 0,15: DRAW 255,0
110 PLOT 0,14: DRAW 255,0
120 INK 7: PLOT 0,0: DRAW 0,175: DRAW 255,0: DRAW 0,-175: DRAW -255,0
125 PRINT AT k,l-1;" "
126 PRINT AT k,l+1;" "
127 PRINT AT k-1,l;" "
128 PRINT AT k+1,l;" "
130 IF INKEY$="8" AND l<29 THEN LET l=l+1
140 IF INKEY$="5" AND l>2 THEN LET l=l-1
150 IF INKEY$="6" AND k<13 THEN LET k=k+1
160 IF INKEY$="7" AND k>2 THEN LET k=k-1
180 PRINT AT INT m,INT n;" "
200 PRINT AT k,l-1;"+"
210 PRINT AT k-1,l;"+"
220 PRINT AT k+1,l;"+"
230 PRINT AT k,l+1;"+"
240 IF INKEY$="0" THEN FOR t=0 TO 3: BEEP 0.02,40: NEXT t: IF k=INT m AND l=INT n THEN GO SUB 1000
245 LET n=n+INT (RND*3)-1
246 IF n<3 THEN LET n=n+1
247 IF n>29 THEN LET n=n-1
248 BEEP 0.005,(RND*35)+15
250 LET m=m+0.2
252 IF score>1000 THEN LET m=m+0.2: IF m>2000 THEN LET m=m+0.2
255 IF n<1 OR n>31 THEN PLOT 0,0: DRAW 0,175: DRAW 255,0: DRAW 0,-175: DRAW -255,0
260 IF m>15 THEN GO SUB 2000
300 INK INT (RND*7)+2: PRINT AT INT m,INT n;"\p": INK 7
310 PRINT AT 1,1;"SCORE:";score;" "
999 GO TO 125
1020 PRINT AT k,l;"\p": PRINT ; OVER 1;AT k,l;"\.'"
1030 FOR h=50 TO 45 STEP -0.5: BEEP 0.01,h: NEXT h
1040 PRINT AT k,l;" "
1050 LET m=3: LET n=INT (RND*26)+2
1060 LET score=score+100
1080 RETURN
2000 LET lan=lan+1
2010 IF lan>10 THEN GO TO 7000
2015 LET m=3: LET n=INT (RND*26)+2
2020 RETURN
3005 FOR n=0 TO 100: BEEP 0.1,40: NEXT n
4000 PAPER 1: INK 7: BORDER 1: CLS
4010 PRINT AT 0,10; FLASH 1;"SAUCER"; FLASH 0
4020 INK 6: PRINT : PRINT "Save the Earth,the aliens are invading and are trying to buildcities on the Earth.": PRINT : PRINT "Shoot them before they build their cities and conquer EARTH and use you for toothpicks."
4030 INK 7: PRINT : PRINT : PRINT " 5 FOR LEFT": PRINT : PRINT " 8 FOR RIGHT": PRINT : PRINT " 6 FOR DOWN": PRINT : PRINT " 7 FOR UP": PRINT : PRINT " 0 TO FIRE"
4040 PRINT AT 21,1; FLASH 1;"Good Luck.......": FLASH 0
4045 PAUSE 9999
4050 BORDER 0: PAPER 0: INK 6: CLS : FOR n=0 TO 50: BEEP 0.005,(RND*35)+15: INK INT (RND*7)+1: PLOT INT (RND*250)+5,INT (RND*120)+50: NEXT n: INK 4: GO TO 5
5000 DATA BIN 0,BIN 00011000,BIN 01111110,BIN 11011011,BIN 11111111,BIN 01100110,BIN 0,BIN 0
5010 FOR n=0 TO 7: READ j
5030 POKE USR "\p"+n,j: NEXT n
5040 RETURN
7000 BEEP 0.7,1: BEEP 0.5,1: BEEP 1,6
7010 PRINT AT 1,1;"THEY HAVE CONQUERED EARTH"
7020 PRINT AT 2,3;"AND ARE BUILDING THEIR CITY"
7025 PAUSE 100
7030 INK INT 2: PRINT AT 12,10;"\::"
7035 BEEP 0.5,5
7040 PRINT AT 13,9;"\.:\::\:."
7045 BEEP 0.5,4
7050 PRINT AT 14,9;"\: \::\ :"
7055 BEEP 0.5,3
7060 PRINT AT 15,9;"\::\::\::"
7065 BEEP 0.5,2
7070 PRINT AT 16,8;"\.:\::\::\::\:."
7075 BEEP 0.5,1
7076 INK 6
7080 PRINT AT 8,1;"YOU HAVE LOST EARTH, THE "
7090 PRINT AT 9,1;"ALIENS HAVE DOOMED MANKIND"
7100 PRINT AT 10,1;"TO BECOME TOOTH PICKS"
7110 PRINT AT 18,1;"ENTER 'RUN' TO GO BACK INTO "
7120 PRINT AT 19,1;"TIME TO TRY AND SAVE THE"
7130 PRINT AT 20,1;"EARTH AGAIN !!!!"
7140 FLASH 1: PRINT AT 5,1;"YOUR SCORE WAS ";score: FLASH 0
7150 STOP
9999 SAVE "saucers" LINE 1: BEEP 1,32
People
No people associated with this content.