Taking Stock

Source Code

    1 FLASH 0: CLS : POKE 23658,8: INPUT "FIRST USE? Y/N",I$: IF I$="" THEN GO TO 1
    3 IF I$="Y" THEN GO SUB 8000
    5 LET TOT=0: INPUT "NUMBER OF CO.s REPRESENTED ";T
   10 POKE 23692,255: PRINT "NAME   # SHARES   PRICE   VALUE"
   15 DIM P(T): DIM V(T)
   18 FOR N=1 TO T
   20 PRINT N$(N);
   30 PRINT TAB 12;S(N);
   40 INPUT "current price ea. ";P(N)
   50 LET V(N)=S(N)*P(N)
   60 LET TOT=TOT+V(N)
   70 PRINT TAB 18;P(N);TAB 25;V(N)
   75 NEXT N
   80 INPUT "Want a COPY from TS2040? Y/N",C$: IF C$="" THEN GO TO 80
   85 IF C$="Y" THEN LPRINT "________________________________": LPRINT : LPRINT "     T A K I N G  S T O C K     ": LPRINT 
   86 LPRINT ''"NAME      SHARES   PRICE   VALUE": LPRINT : LPRINT 
   87 FOR N=1 TO T: LPRINT N$(N);"  ";S(N);TAB 18;P(N);TAB 25;V(N)
   89 NEXT N
  176 PRINT '"PRESS ANY KEY": PAUSE 0: CLS : PRINT AT 10,5;"NOW FOR TOTAL TODAY": INPUT "DATE IN NUMERALS?MONTH ";M;" DAY ";D;" YEAR ";Y
  178 PRINT '"$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$": PRINT ''"TOTLVAL  $";TOT;" DATE: ";M;"/";D;"/";Y
  180 LPRINT '"$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$": LPRINT ''"TOTLVAL  $";TOT;" DATE: ";M;"/";D;"/";Y
  185 STOP 
 8000 PRINT "YOU WILL NEED STOCK MARKET PRICEQUOTATIONS FROM NEWSPAPER, LIST OF COMPANIES WITH WHICH YOU OWN STOCK, AND NUMBER OF SHARES.";'"YOU WILL ENTER CURRENT PRICE &  COMPUTER WILL PRINT THE CURRENT VALUE OF THAT BLOCK OF STOCK &  THEN VALUE TOTAL FOR ALL STOCK  YOU OWN ON THAT DATE."
 8005 PRINT '"BUT FIRST,";'"YOU WILL BE SAVING THE COMPANY  NAMES AND NUMBER OF SHARES IN   A STRING ARRAY AND AN ARRAY SO  BE ACCURATE.  HENCEFORTH, YOU   WILL ONLY NEED TO ENTER CURRENT PRICE IN TABLE FOR COMPLETE COM-PUTATION."
 8006 PRINT '''"PRESS ANY KEY": PAUSE 0: CLS 
 8008 PRINT '"IF YOU ARE USING A TAPE, YOU'LL NEED TO RECORD POSITION # ON    TAPE CAREFULLY OR LEAVE A BLANK AREA EQUAL TO LENGTH OF THIS    PROGRAM AND RECORD THIS PROGRAM AHEAD OF TWO DATA SAVES SINCE   THEY WILL LOAD FROM WITHIN THIS PROGRAM."
 8009 PRINT '"SINCE MAX OF CORP. NAMES IS 10  LETTERS, YOU MAY WANT TO USE THESTOCK MARKET ABBREVIATIONS FOR  THE COMPANY ISSUE."
 8010 PRINT ''"PRESS ANY KEY": PAUSE 0: CLS 
 8012 INPUT "TOTAL NUMBER OF ENTRIES (USUALLYTHE NUMBER OF DIFFERENT CORPOR- ATIONS INVOLVED) ";T
 8014 PRINT AT 19,0;"YOU WILL BE ASKED TO GIVE THIS  TOTAL ENTRY NUMBER ";T;" AGAIN IN THE MAIN PROGRAM.": PAUSE 360: CLS 
 8020 DIM N$(T,10): DIM S(T)
 8025 FOR N=1 TO T
 8030 INPUT "NAME OF COMPANY ",N$(N)
 8035 INPUT "NUMBER OF SHARES ";S(N)
 8040 NEXT N
 8050 SAVE "STOKNAMDAT" DATA N$(): SAVE "SHARNUMDAT" DATA S()
 8060 RETURN 
 9990 STOP 
 9995 CLS : PRINT INK 9;"LOADING TWO DATA ARRAYS": LOAD "STOKNAMDAT" DATA N$(): LOAD "SHARNUMDAT" DATA S(): GO TO 1
 9998 SAVE "STOKVALU" LINE 9995: STOP : REM DO NOT USE THIS SAVE UNTIL YOU HAVE SAVED TWO DATA ARRAYS.
 9999 SAVE "STOKVALU" LINE 1: REM ALL-PURPOSE SAVE FOR LATER INVESTIGATION OF PROGRAM