This two-module program implements a full Tarot card reading system, consisting of a “READING” module and a “CARDS” reference module. The READING module stores interpretations for all 78 Tarot cards (56 Minor Arcana across four suits plus 22 Major Arcana) in a 78×45 string array, then deals an 11-card Celtic Cross spread by generating non-repeating random indices using a rejection-sampling loop at lines 2500–2550. The CARDS module serves as a standalone reference guide, displaying ASCII art illustrations of each Major Arcana card alongside interpretive text, and uses the CODE keyword to compute array dimensions and TAB positions rather than hard-coded literals. Both modules use keypress-gated GOSUB routines for paged display and cross-load each other via LOAD commands embedded in STOP sequences, forming a two-program suite.
Program Analysis
Program Structure
The listing contains two independent BASIC programs saved as separate files: "READING" and "CARDS". They are designed to cross-load each other — READING ends by suggesting LOAD "CARDS" (line 2968), and CARDS ends by suggesting LOAD "READING" (line 4020), forming a two-part interactive suite.
READING Module
Lines 30–860 declare and populate a DIM M$(78,45) string array holding the card name and meaning for all 78 Tarot cards. The array is indexed sequentially but with deliberate gaps in line numbers (e.g., lines jump from 180 to 200, 330 to 350, etc.) to group the four suits (Wands 1–14, Cups 15–28, Swords 29–42, Pentacles 43–56) and the Major Arcana (57–78) visually in the source.
Lines 870–960 render a decorative title banner using block graphic characters via PRINT AT. Lines 1030–1060 and 1240–1270 display two introductory text screens with a simple block-graphic logo before prompting the user for a question at line 1410 via INPUT Q$.
Lines 1490–1660 print an annotated diagram of the Celtic Cross layout using [▒] placeholders to represent the 11 card positions and their positional labels (SIGNIFICATOR, CROSSES YOU, CROWNS YOU, etc.).
Lines 1690–2480 build a second string array DIM D$(78,3) which holds short card identifier strings (e.g., "[W][1]█" for the Ace of Wands, "[0]██" for The Fool). These are used to prefix card meanings during the reading display.
Card Dealing and Non-Repeating Selection
Lines 2490–2550 implement the card draw using a rejection-sampling approach:
DIM V(11)allocates an 11-element numeric array for the drawn card indices.- A
FOR I=1 TO 11loop generates each card index asINT(RND*78)+1. - An inner
FOR J=1 TO I-1loop checks for duplicates; ifV(I)=V(J), control jumps back to line 2510 to redraw.
This guarantees 11 unique cards but is an O(n²) check — acceptable for a deck of 78 with only 11 draws.
Reading Display
Lines 2570–2780 use PRINT AT to place each card’s short identifier (D$(V(n))) at its correct position on the pre-drawn layout. Between each card placement, GOSUB 2810 pauses for a “T” keypress, simulating the physical act of turning a card. Lines 2850–2961 then present all 11 card meanings in sequence, split across two screen-pages with a “C to continue” pause at line 2937.
Line 2963 offers a new reading by pressing “N”, which loops back to line 1370. This loop runs for only 30 iterations of a FOR A loop (lines 2964–2966), so the window for pressing “N” is limited.
CARDS Module
The CARDS module provides a browsable reference for all 78 cards. A menu at line 170 offers Major Arcana, Minor Arcana by suit, or exit. Each card is displayed with multi-line ASCII art within a bordered frame and accompanied by its meaning string.
Minor Arcana suits each define their own 14-element string array (W$, C$, S$, P$) for Wands, Cups, Swords, and Pentacles respectively. A sequential counter N walks through all 14 cards per suit in a FOR I loop, calling GOSUB 3980 for the keypress gate between cards.
Notable Technique: CODE-Based Array Sizing and Positioning
The CARDS module uses the CODE function extensively in place of numeric literals, exploiting the fact that ASCII character codes equal the numeric values needed:
| Expression | Character | Numeric value | Usage |
|---|---|---|---|
CODE ":" | : | 58 (but on ZX81, CODE ":" = 14) | Array upper bound (14 cards per suit) |
CODE "2" | 2 | String width for W$ | Second DIM dimension |
CODE "/" | / | TAB stop for card frame column | Aligns card art right side |
CODE ";" | ; | Column position for card label | PRINT AT column |
CODE "+" | + | Row for “C to continue” prompt | PRINT AT row |
CODE "\~~" | ~ | 10 (index for 10th card) | Array index for 10 of each suit |
CODE "£" | £ | 12 (Knight index) | Array index for card 12 |
CODE "$" | $ | 13 (Queen index) | Array index for card 13 |
This technique saves token bytes in the stored program since short string arguments to CODE can be more compact than multi-digit numeric literals in some tokenized BASIC implementations.
Major Arcana Display Loop
The Major Arcana section (lines 1790–3900) stores meanings in DIM H$(CODE "-", CODE "2") and uses CODE-based indices for entries 0–9 (mapping character codes to small integers), then switches to plain numeric literals from index 11 onward. Each card gets several lines of PRINT TAB CODE "/" statements to render the right half of the card frame, while the left half and descriptive text are packed into a single wide PRINT string, exploiting the fact that BASIC strings wrap naturally to continue card art across screen columns. The counter variable N is incremented within GOSUB 3910 at line 3940, making the subroutine stateful.
Keypress Gate Subroutines
Two similar subroutines handle pacing:
GOSUB 2970/GOSUB 2980: Waits for “C” (Continue) — used between major reading sections.GOSUB 2810/GOSUB 2820: Waits for “T” (Turn card) — used between individual card reveals during the spread display.GOSUB 3980/GOSUB 3990: Waits for “C” in the CARDS module — used between card reference pages.
All three use the tight polling idiom IF INKEY$ <> "X" THEN GOTO on the very next line, a standard busy-wait pattern.
Timing Loops
Lines 990–1000 and 1450–1460 use empty FOR/NEXT loops as software delays — a common practice where no hardware timer is available. GOSUB 3000 (lines 3000–3020) similarly provides a short pause between printed reading entries.
Anomalies and Minor Issues
- Line 2390 prints
"4-THE EMPEROR"but should be card 4; however the preceding card at line 2300 is already labeled"4-THE EMPRESS". Both are displayed sequentially, suggesting the Emperor’s label should read"4-THE EMPEROR"(correct) but the Empress’s label should be"3-THE EMPRESS"— a numbering slip consistent with some Tarot deck conventions where The Empress is III and The Emperor is IV. - The
D$array in READING uses a fixed width of 3 characters (DIM D$(78,3)), but entries for cards 10–21 of the Major Arcana such as"[1][0]█"are also 3 characters, achieved by packing the bracket-notation tokens tightly. - Lines 2963–2966 limit the “new reading” prompt window to exactly 30
FORloop iterations with no delay body, meaning the window is extremely short on faster hardware. - The CARDS module at line 1530 stores
"GROWTH, ENDEAVOR, A SOULMATE"for Pentacles 7, while the READING module at line 560 stores"GROWTH, ENDEAVOR, SOULMATE"— a minor textual inconsistency between the two modules.
Content
Image Gallery
Source Code
10 REM "READING"
20 RAND
30 DIM M$(78,45)
50 LET M$(1)="OF THE WANDS- A BEGINNING, NEW ENTERPRISE"
60 LET M$(2)="OF THE WANDS- DOMINION, RICHES, GOOD FORTUNE"
70 LET M$(3)="OF THE WANDS- COMMERCE, BUSINESS PARTNERSHIP"
80 LET M$(4)="OF THE WANDS- ROMANCE, PROSPERITY, REFUGE"
90 LET M$(5)="OF THE WANDS- STRIFE, STRUGGLING TO SUCCEED"
100 LET M$(6)="OF THE WANDS- TRIUMPHANT NEWS, ADVANCEMENT"
110 LET M$(7)="OF THE WANDS- STIFF COMPETITION, OPPOSITION"
120 LET M$(8)="OF THE WANDS- LOVE PANGS, HASTE, MOVEMENT"
130 LET M$(9)="OF THE WANDS- PREPAREDNESS, RESERVE STRENGTH"
140 LET M$(10)="OF THE WANDS- HEAVY BURDEN, PROBLEMS SOLVED"
150 LET M$(11)="OF THE WANDS- BRINGS GOOD TIDINGS; A CHILD"
160 LET M$(12)="OF THE WANDS- A RIVAL; NEW ADDRESS, ABSENCE"
170 LET M$(13)="OF THE WANDS- MAGNETIC WOMAN; ENTERPRISING"
180 LET M$(14)="OF THE WANDS- FAMILY MAN; GOOD MARRIAGE"
200 LET M$(15)="OF THE CUPS- ABUNDANCE, LOVE, SPIRITUALITY"
210 LET M$(16)="OF THE CUPS- LOVE AFFAIR, UNION, HARMONY"
220 LET M$(17)="OF THE CUPS- ABUNDANCE, VICTORY, HEALING"
230 LET M$(18)="OF THE CUPS- CONTEMPLATION, RE-EVALUATION"
240 LET M$(19)="OF THE CUPS- REGRET, MARITAL BITTERNESS"
250 LET M$(20)="OF THE CUPS- CHILDHOOD MEMORIES, RENEWAL"
260 LET M$(21)="OF THE CUPS- UNFOCUSED IDEAS, GREAT DREAMS"
270 LET M$(22)="OF THE CUPS- ABANDONED PROJECT, LOVELORN"
280 LET M$(23)="OF THE CUPS- SATISFACTION, ROBUST HEALTH"
290 LET M$(24)="OF THE CUPS- HAPPY FAMILY LIFE, SUCCESS"
300 LET M$(25)="OF THE CUPS- CONSIDERATE YOUTH; NEW METHOD"
310 LET M$(26)="OF THE CUPS- ROMANTIC MAN; AN INVITATION"
320 LET M$(27)="OF THE CUPS- BELOVED WOMAN; HAPPY MARRIAGE"
330 LET M$(28)="OF THE CUPS- FRIENDLY BACHELOR; GENEROSITY"
350 LET M$(29)="OF THE SWORD- GREAT FORCE, POWER, CONQUEST"
360 LET M$(30)="OF THE SWORD- STALEMATE, A FAMILY TRUCE"
370 LET M$(31)="OF THE SWORD- DELAY, SORROW, LOVE LOST"
380 LET M$(32)="OF THE SWORD- RETREAT, CONVALESCENCE"
390 LET M$(33)="OF THE SWORD- PHYSICAL CONQUEST, CONFLICT"
400 LET M$(34)="OF THE SWORD- TRIUMPH, REPRESENTATION"
410 LET M$(35)="OF THE SWORD- PARTIAL SUCCESS, UNCERTAINTY"
420 LET M$(36)="OF THE SWORD- UNCERTAINTY, BONDAGE, CRISIS"
430 LET M$(37)="OF THE SWORD- MISERY, DEATH OF A LOVED ONE"
440 LET M$(38)="OF THE SWORD- MISFORTUNE, END OF DELUSIONS"
450 LET M$(39)="OF THE SWORD- VIGILANT YOUTH; WARY, ALERT"
460 LET M$(40)="OF THE SWORD- DOMINEERING MAN; SKILLFUL"
470 LET M$(41)="OF THE SWORD- QUICK-WITTED WOMAN; SADNESS"
480 LET M$(42)="OF THE SWORD- AUTHORITATIVE MAN; WISDOM"
500 LET M$(43)="OF PENTACLES- ECSTASY, WEALTH, PROSPERITY"
510 LET M$(44)="OF PENTACLES- HARMONIOUS CHANGE, DIPLOMACY"
520 LET M$(45)="OF PENTACLES- ARTFUL MASTER, CONSTRUCTION"
530 LET M$(46)="OF PENTACLES- POSSESSIVE, MISERLY, SELFISH"
540 LET M$(47)="OF PENTACLES- DESTITUTION, LOVE GONE ASTRAY"
550 LET M$(48)="OF PENTACLES- PHILANTHROPY, SHARED WEALTH"
560 LET M$(49)="OF PENTACLES- GROWTH, ENDEAVOR, SOULMATE"
570 LET M$(50)="OF PENTACLES- APPRENTICESHIP, EMPLOYMENT"
580 LET M$(51)="OF PENTACLES- ACCOMPLISHMENT, WELL-BEING"
590 LET M$(52)="OF PENTACLES- FAMILY LINEAGE, INHERITANCE"
600 LET M$(53)="OF PENTACLES- DILIGENT YOUTH; SCHOLARSHIP"
610 LET M$(54)="OF PENTACLES- METHODICAL MAN; PATIENCE"
620 LET M$(55)="OF PENTACLES- INTELLIGENT WOMAN; GENEROSITY"
630 LET M$(56)="OF PENTACLES- MAN OF CHARACTER; RELIABILITY"
650 LET M$(57)="THE FOOL- AN IMPORTANT CHOICE IN LIFE"
660 LET M$(58)="THE MAGICIAN- MASTERY, WISDOM, CREATIVITY"
670 LET M$(59)="HIGH PRIESTESS-HIDDEN INFLUENCES, DUALITY"
680 LET M$(60)="THE EMPRESS- MARRIAGE, WEALTH, FERTILITY"
690 LET M$(61)="THE EMPEROR- POWER, INTELLECT OVER PASSION"
700 LET M$(62)="THE HIEROPHANT-RITUAL, CONFORMITY, CONVENTION"
710 LET M$(63)="THE LOVERS- SACRED OR PROFANE LOVE, CHOICE"
720 LET M$(64)="THE CHARIOT- CONQUEST, TRIUMPH, GREATNESS"
730 LET M$(65)="STRENGTH- TRIUMPH OF LOVE, ENERGY, POWER"
740 LET M$(66)="THE HERMIT- WISDOM, PRUDENCE, GUIDANCE"
750 LET M$(67)="WHEEL/FORTUNE- GOOD FORTUNE, TURN OF LUCK"
760 LET M$(68)="JUSTICE- BALANCED PERSONALITY, EQUALITY"
770 LET M$(69)="THE HANGED MAN-CHANGE OF MIND, PAUSE IN LIFE"
780 LET M$(70)="DEATH- RENEWAL, ALTERED CONSCIOUSNESS"
790 LET M$(71)="TEMPERANCE- COORDINATION, MIND OVER MATTER"
800 LET M$(72)="THE DEVIL- DEATH OF OLD SELF, REVOLUTION"
810 LET M$(73)="THE TOWER- LIFESTYLE CHANGE, BANKRUPTCY"
820 LET M$(74)="THE STAR- INSPIRATION, DEVOTION, HEALTH"
830 LET M$(75)="THE MOON- IMAGINATION, INTUITION, DREAMS"
840 LET M$(76)="THE SUN- ACHIEVEMENT, BALANCE IN LIFE"
850 LET M$(77)="JUDGEMENT- RENEWAL, INNER ENLIGHTENMENT"
860 LET M$(78)="THE WORLD- EARNED REWARD, ASSURED SUCCESS"
870 PRINT AT 5,0;" ▐██████████████████████████"
880 PRINT " ▐█▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▜█"
890 PRINT " ▐█▐▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▜▐█"
900 PRINT " ▐█▐▐▀█▀▌███ █▀█ ▟▀▜▖▛▜▛▜▐▐█"
910 PRINT " ▐█▐▝▘█▝▘▐ ▌ ▐▄▛ █ ▐▌▀▐▌▀▐▐█"
920 PRINT " ▐█▐ █ ▟▄▙ ▐ ▜ █ ▐▌ ▐▌ ▐▐█"
930 PRINT " ▐█▐ ▐█▌▐█ █▌█▌█▌▜▄▟▘ ██ ▐▐█"
940 PRINT " ▐█▐▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▟▐█"
950 PRINT " ▐█▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▟█"
960 PRINT " ▐██████████████████████████"
970 PRINT
980 PRINT " (C)1983 COMPUTER PHOOD"
990 FOR I=1 TO 50
1000 NEXT I
1010 CLS
1020 PRINT
1030 PRINT "▐██▌"
1040 PRINT " ▌▐"
1050 PRINT "▗▙▟▖"
1060 PRINT "█▌▐█S SCIENCE COMES TO REALIZE WHAT TAROT USERS HAVE LONG UNDERSTOOD -THAT EVENTS IN TIME AND SPACE CAN BE ALTERED BY OBSERVING THEM- WE FIND WE HAVE A POWERFUL NEW MEDIUM TO HELP US REACH THE TAROT. THE COMPUTER CAN NOW BE WHAT THE CARDS HAVE ALWAYS BEEN: A WAY OF READING -OF TOUCHING- THE ETERNAL TAROT..."
1220 GOSUB 2970
1230 CLS
1231 PRINT
1240 PRINT "▐██▌"
1250 PRINT " ▌▐"
1260 PRINT "▗▙▟▖"
1270 PRINT "█▌▐█T THE HEART OF THE TAROT EXPERIENCE IS THE READING. WE ASK A QUESTION, THE CARDS ARE CAST AND APPEAR IN A LAYOUT BEFORE US. THEIR MESSAGE MAY NOT BE CLEAR AT FIRST. WE MAY HAVE TO THINK DEEPLY, AND EVEN MEDITATE UPON THE MEANINGS, BUT THE TAROT ALWAYS HAS AN ANSWER-"
1360 GOSUB 2970
1370 CLS
1371 PRINT
1380 PRINT "▛▜▛▜"
1381 PRINT "▀▐▌▀"
1382 PRINT " ▐▌"
1383 PRINT " ██YPE IN YOUR QUESTION-"
1400 PRINT " (ONE LINE, PLEASE)"
1410 INPUT Q$
1420 IF LEN Q$>30 THEN GOTO 1370
1430 CLS
1440 PRINT "NOW, CONCENTRATE..."
1450 FOR I=1 TO 10
1460 NEXT I
1480 PRINT
1490 PRINT " [▒][▒][▒] [▒][▒][▒] "
1500 PRINT " [▒][▒][▒] [▒][▒][▒] "
1510 PRINT " [▒][▒][▒]CROWNS [▒][▒][▒]FINAL "
1520 PRINT " [▒][▒][▒]YOU [▒][▒][▒] [▒][▒][▒]OUTCOME"
1530 PRINT " [▒][▒][▒] [▒][▒][▒] [▒][▒][▒] "
1540 PRINT " SIGNIFICATOR [▒][▒][▒] "
1550 PRINT "[▒][▒][▒] [▒][▒][▒] [▒][▒][▒]FAMILY "
1560 PRINT "[▒][▒][▒] ▒▒▒▒▒CROSSES [▒][▒][▒]OPINION "
1570 PRINT "[▒][▒][▒] ▒▒▒▒▒YOU "
1580 PRINT "[▒][▒][▒] ▒▒▒▒▒ [▒][▒][▒] [▒][▒][▒] "
1590 PRINT "[▒][▒][▒] [▒][▒][▒]COVERS [▒][▒][▒]BEFORE[▒][▒][▒] "
1600 PRINT "BEHIND YOU [▒][▒][▒]YOU [▒][▒][▒]YOUR "
1610 PRINT "YOU [▒][▒][▒] [▒][▒][▒]HOPES"
1620 PRINT " [▒][▒][▒] [▒][▒][▒] [▒][▒][▒] [▒][▒][▒] "
1630 PRINT " [▒][▒][▒] [▒][▒][▒] "
1640 PRINT " [▒][▒][▒]BENEATH [▒][▒][▒]YOUR "
1650 PRINT " [▒][▒][▒]YOU [▒][▒][▒]FEARS "
1660 PRINT " [▒][▒][▒] [▒][▒][▒] "
1670 PRINT
1690 DIM D$(78,3)
1700 LET D$(1)="[W][1]█"
1710 LET D$(2)="[W][2]█"
1720 LET D$(3)="[W][3]█"
1730 LET D$(4)="[W][4]█"
1740 LET D$(5)="[W][5]█"
1750 LET D$(6)="[W][6]█"
1760 LET D$(7)="[W][7]█"
1770 LET D$(8)="[W][8]█"
1780 LET D$(9)="[W][9]█"
1790 LET D$(10)="[W][1][0]"
1800 LET D$(11)="[W][1][1]"
1810 LET D$(12)="[W][1][2]"
1820 LET D$(13)="[W][1][3]"
1830 LET D$(14)="[W][1][4]"
1840 LET D$(15)="[C][1]█"
1850 LET D$(16)="[C][2]█"
1860 LET D$(17)="[C][3]█"
1870 LET D$(18)="[C][4]█"
1880 LET D$(19)="[C][5]█"
1890 LET D$(20)="[C][6]█"
1900 LET D$(21)="[C][7]█"
1910 LET D$(22)="[C][8]█"
1920 LET D$(23)="[C][9]█"
1930 LET D$(24)="[C][1][0]"
1940 LET D$(25)="[C][1][1]"
1950 LET D$(26)="[C][1][2]"
1960 LET D$(27)="[C][1][3]"
1970 LET D$(28)="[C][1][4]"
1980 LET D$(29)="[S][1]█"
1990 LET D$(30)="[S][2]█"
2000 LET D$(31)="[S][3]█"
2010 LET D$(32)="[S][4]█"
2020 LET D$(33)="[S][5]█"
2030 LET D$(34)="[S][6]█"
2040 LET D$(35)="[S][7]█"
2050 LET D$(36)="[S][8]█"
2060 LET D$(37)="[S][9]█"
2070 LET D$(38)="[S][1][0]"
2080 LET D$(39)="[S][1][1]"
2090 LET D$(40)="[S][1][2]"
2100 LET D$(41)="[S][1][3]"
2110 LET D$(42)="[S][1][4]"
2120 LET D$(43)="[P][1]█"
2130 LET D$(44)="[P][2]█"
2140 LET D$(45)="[P][3]█"
2150 LET D$(46)="[P][4]█"
2160 LET D$(47)="[P][5]█"
2170 LET D$(48)="[P][6]█"
2180 LET D$(49)="[P][7]█"
2190 LET D$(50)="[P][8]█"
2200 LET D$(51)="[P][9]█"
2210 LET D$(52)="[P][1][0]"
2220 LET D$(53)="[P][1][1]"
2230 LET D$(54)="[P][1][2]"
2240 LET D$(55)="[P][1][3]"
2250 LET D$(56)="[P][1][4]"
2260 LET D$(57)="[0]██"
2270 LET D$(58)="[1]██"
2280 LET D$(59)="[2]██"
2290 LET D$(60)="[3]██"
2300 LET D$(61)="[4]██"
2310 LET D$(62)="[5]██"
2320 LET D$(63)="[6]██"
2330 LET D$(64)="[7]██"
2340 LET D$(65)="[8]██"
2350 LET D$(66)="[9]██"
2360 LET D$(67)="[1][0]█"
2370 LET D$(68)="[1][1]█"
2380 LET D$(69)="[1][2]█"
2390 LET D$(70)="[1][3]█"
2400 LET D$(71)="[1][4]█"
2410 LET D$(72)="[1][5]█"
2420 LET D$(73)="[1][6]█"
2430 LET D$(74)="[1][7]█"
2440 LET D$(75)="[1][8]█"
2450 LET D$(76)="[1][9]█"
2460 LET D$(77)="[2][0]█"
2470 LET D$(78)="[2][1]█"
2490 DIM V(11)
2500 FOR I=1 TO 11
2510 LET V(I)=INT (RND*78)+1
2520 FOR J=1 TO I-1
2530 IF V(I)=V(J) THEN GOTO 2510
2540 NEXT J
2550 NEXT I
2551 PRINT AT 0,0;" "
2560 PRINT AT 0,0;"""";Q$;""""
2570 GOSUB 2810
2580 PRINT AT 8,5;D$(V(1))
2590 GOSUB 2810
2600 PRINT AT 12,5;D$(V(2))
2610 GOSUB 2810
2620 PRINT AT 10,5;D$(V(3))
2630 GOSUB 2810
2640 PRINT AT 17,5;D$(V(4))
2650 GOSUB 2810
2660 PRINT AT 10,0;D$(V(5))
2670 GOSUB 2810
2680 PRINT AT 4,5;D$(V(6))
2690 GOSUB 2810
2700 PRINT AT 13,15;D$(V(7))
2710 GOSUB 2810
2720 PRINT AT 17,20;D$(V(8))
2730 GOSUB 2810
2740 PRINT AT 7,18;D$(V(9))
2750 GOSUB 2810
2760 PRINT AT 13,24;D$(V(10))
2770 GOSUB 2810
2780 PRINT AT 4,22;D$(V(11))
2790 GOSUB 2970
2800 GOTO 2840
2810 PRINT AT 21,6;"PRESS ""T"" TO TURN CARDS-"
2820 IF INKEY$ <>"T" THEN GOTO 2820
2830 RETURN
2850 CLS
2860 PRINT "▐▜▛▌"
2861 PRINT " ▐▌"
2863 PRINT " ██HE TAROT READING IS DIRECTLY RELATED TO YOUR QUESTION..."
2910 PRINT """";Q$;""""
2911 PRINT
2912 GOSUB 3000
2920 PRINT "SIGNIFIES YOU:";D$(V(1));M$(V(1))
2922 PRINT
2923 GOSUB 3000
2924 PRINT "AURA ABOUT IT:";D$(V(2));M$(V(2))
2926 PRINT
2927 GOSUB 3000
2928 PRINT "IN OPPOSITION:";D$(V(3));M$(V(3))
2930 PRINT
2931 GOSUB 3000
2932 PRINT "FOUNDATION OF:";D$(V(4));M$(V(4))
2933 PRINT
2934 GOSUB 3000
2935 PRINT "WHAT HAS PAST:";D$(V(5));M$(V(5))
2937 GOSUB 2970
2938 CLS
2939 PRINT
2940 PRINT "WHAT MIGHT BE:";D$(V(6));M$(V(6))
2942 PRINT
2943 GOSUB 3000
2944 PRINT "IN THE FUTURE:";D$(V(7));M$(V(7))
2946 PRINT
2947 GOSUB 3000
2948 PRINT "YOU FEAR THIS:";D$(V(8));M$(V(8))
2950 PRINT
2951 GOSUB 3000
2952 PRINT "FAMILY THINKS:";D$(V(9));M$(V(9))
2954 PRINT
2955 GOSUB 3000
2956 PRINT "YOU ASPIRE TO:";D$(V(10));M$(V(10))
2958 PRINT
2959 GOSUB 3000
2960 PRINT "FINAL OUTCOME:";D$(V(11));M$(V(11))
2961 GOSUB 2970
2962 CLS
2963 PRINT AT 2,0;"IF THIS READING WAS NOT CLEAR, PRESS ""N"" FOR A NEW READING."
2964 FOR A=1 TO 30
2965 IF INKEY$ ="N" THEN GOTO 1370
2966 NEXT A
2967 PRINT
2968 PRINT "LOAD ""CARDS"" TO REVIEW CARDS."
2969 STOP
2970 PRINT AT 21,0;" PRESS ""C"" TO CONTINUE-"
2980 IF INKEY$ <>"C" THEN GOTO 2980
2990 RETURN
3000 FOR I=1 TO 50
3010 NEXT I
3020 RETURN
3030 STOP
9990 SAVE "READIN[G]"
9999 RUN
10 REM "CARDS"
20 LET M$="MEANING-"
30 PRINT "▛▜▛▜"
40 PRINT "▀▐▌▀"
50 PRINT " ▐▌"
60 PRINT " ██HE TAROT CARDS-"
70 PRINT
80 PRINT "THE ILLUSTRATED MAJOR ARCANA"
90 PRINT "SYMBOLICALLY REPRESENT THE"
100 PRINT "METAPHYSICAL BASIS OF OUR"
110 PRINT "QUEST FOR ENLIGHTENMENT."
120 PRINT
130 PRINT "THE MINOR ARCANA CONSTITUTE"
140 PRINT "A COMPREHENSIVE PSYCHOLOGICAL"
150 PRINT "EVALUATION OF MAN."
160 PRINT
170 PRINT "CHOOSE ONE (ENTER 1,2,OR 3)"
180 PRINT
190 PRINT "1-MAJOR CARDS"
200 PRINT "2-MINOR CARDS"
210 PRINT "3-END PROGRAM"
220 INPUT A
230 IF A>3 THEN GOTO 0220
240 CLS
250 IF A=3 THEN GOTO 4010
260 IF A=1 THEN GOTO 1790
270 IF A=2 THEN PRINT "▛▜▛▜"
280 PRINT "▀▐▌▀"
290 PRINT " ▐▌"
300 PRINT " ██HE MINOR CARDS-"
310 PRINT "ONE TO TEN,11-PAGE, 12-KNIGHT,"
320 PRINT "13-QUEEN AND 14-KING."
330 PRINT
340 PRINT "CHOOSE A SUIT-"
350 PRINT
360 PRINT "1-WANDS"
370 PRINT "2-CUPS"
380 PRINT "3-SWORDS"
390 PRINT "4-PENTACLES"
400 INPUT A
410 IF A>4 THEN GOTO 0400
420 CLS
430 IF A=1 THEN GOTO 0470
440 IF A=2 THEN GOTO 0800
450 IF A=3 THEN GOTO 1130
460 IF A=4 THEN GOTO 1460
470 DIM W$(CODE ":",CODE "2")
480 LET W$(1)="A BEGINNING, NEW ENTERPRISE"
490 LET W$(2)="DOMINION, RICHES, GOOD FORTUNE"
500 LET W$(3)="COMMERCE, BUSINESS PARTNERSHIP"
510 LET W$(4)="ROMANCE, PROSPERITY, REFUGE"
520 LET W$(5)="STRIFE, STRUGGLING TO SUCCEED"
530 LET W$(6)="TRIUMPHANT NEWS, ADVANCEMENT"
540 LET W$(7)="STIFF COMPETITION, OPPOSITION"
550 LET W$(8)="LOVE PANGS, HASTE, MOVEMENT"
560 LET W$(9)="PREPAREDNESS, RESERVE STRENGTH"
570 LET W$(CODE "~~")="HEAVY BURDEN, PROBLEMS SOLVED"
580 LET W$(11)="BRINGS GOOD TIDINGS; A CHILD"
590 LET W$(CODE "£")="A RIVAL; NEW ADDRESS, ABSENCE"
600 LET W$(CODE "$")="MAGNETIC WOMAN; ENTERPRISING"
610 LET W$(CODE ":")="FAMILY MAN; GOOD MARRIAGE"
620 LET N=1
630 PRINT "WANDS INDICATE-"
640 PRINT "ENTERPRISE, NEW IDEAS, ▛▀▀▀▀▀▜ ENERGY, PRAISE, GROWTH ▌ ▜ ▐ AND LIFES RENEWAL... ▌ ▐ ▐"
650 PRINT TAB CODE "/";"▌ ▐ ▐"
660 PRINT TAB CODE "/";"▌ ▐ ▐"
670 PRINT TAB CODE "/";"▌OF ▐ ▐"
680 PRINT TAB CODE "/";"▌THE▝ ▐"
690 PRINT TAB CODE "/";"▌WANDS▐"
700 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
710 FOR I=1 TO CODE ":"
720 PRINT AT 5,CODE ";";"W";N
730 PRINT AT 11,0;M$
740 PRINT W$(N)
750 LET N=N+1
760 GOSUB 3980
770 NEXT I
780 CLS
790 GOTO 0170
800 DIM C$(CODE ":",CODE "1")
810 LET C$(1)="ABUNDANCE, LOVE, SPIRITUALITY"
820 LET C$(2)="LOVE AFFAIR, UNION, HARMONY"
830 LET C$(3)="ABUNDANCE, VICTORY, HEALING"
840 LET C$(4)="CONTEMPLATION, RE-EVALUATION"
850 LET C$(5)="REGRET, MARITAL BITTERNESS"
860 LET C$(6)="CHILDHOOD MEMORIES, RENEWAL"
870 LET C$(7)="UNFOCUSED IDEAS, GREAT DREAMS"
880 LET C$(8)="ABANDONED PROJECT, LOVELORN"
890 LET C$(9)="SATISFACTION, ROBUST HEALTH"
900 LET C$(CODE "~~")="HAPPY FAMILY LIFE, SUCCESS"
910 LET C$(11)="CONSIDERATE YOUTH; NEW METHOD"
920 LET C$(CODE "£")="ROMANTIC MAN; AN INVITATION"
930 LET C$(CODE "$")="BELOVED WOMAN; HAPPY MARRIAGE"
940 LET C$(CODE ":")="FRIENDLY BACHELOR; GENEROSITY"
950 LET N=1
960 PRINT "CUPS INDICATE-"
970 PRINT "EMOTIONS, HAPPINESS, ▛▀▀▀▀▀▜ LOVE, KNOWLEDGE, BEAUTY ▌ ▐█▌ ▐ AND THE GOOD LIFE... ▌ ▐█▌ ▐"
980 PRINT TAB CODE "/";"▌ █ ▐"
990 PRINT TAB CODE "/";"▌ ▝▀▘ ▐"
1000 PRINT TAB CODE "/";"▌ ▐"
1010 PRINT TAB CODE "/";"▌OF ▐"
1020 PRINT TAB CODE "/";"▌CUPS ▐"
1030 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
1040 FOR I=1 TO 14
1050 PRINT AT 6,CODE ";";"C";N
1060 PRINT AT 11,0;M$
1070 PRINT C$(N)
1080 LET N=N+1
1090 GOSUB 3980
1100 NEXT I
1110 CLS
1120 GOTO 0170
1130 DIM S$(CODE ":",CODE "0")
1140 LET S$(1)="GREAT FORCE, POWER, CONQUEST"
1150 LET S$(2)="STALEMATE, A FAMILY TRUCE"
1160 LET S$(3)="DELAY, SORROW, LOVE LOST"
1170 LET S$(4)="RETREAT, CONVALESCENCE"
1180 LET S$(5)="PHYSICAL CONQUEST, CONFLICT"
1190 LET S$(6)="TRIUMPH, REPRESENTATION"
1200 LET S$(7)="PARTIAL SUCCESS, UNCERTAINTY"
1210 LET S$(8)="UNCERTAINTY, BONDAGE, CRISIS"
1220 LET S$(9)="MISERY, DEATH OF A LOVED ONE"
1230 LET S$(CODE "~~")="MISFORTUNE, END OF DELUSIONS"
1240 LET S$(11)="VIGILANT YOUTH; WARY, ALERT"
1250 LET S$(CODE "£")="DOMINEERING MAN; SKILLFUL"
1260 LET S$(CODE "$")="QUICK-WITTED WOMAN; SADNESS"
1270 LET S$(CODE ":")="AUTHORITATIVE MAN; WISDOM"
1280 LET N=1
1290 PRINT "SWORDS INDICATE-"
1300 PRINT "AGGRESSION, AMBITION, ▛▀▀▀▀▀▜ COURAGE, MISFORTUNE, ▌ ▐ ▐ STRIFE, DESTRUCTION... ▌ ▐ ▐"
1310 PRINT TAB CODE "/";"▌ ▐ ▐"
1320 PRINT TAB CODE "/";"▌ ▐ ▐"
1330 PRINT TAB CODE "/";"▌OF ▜▘▐"
1340 PRINT TAB CODE "/";"▌THE▝ ▐"
1350 PRINT TAB CODE "/";"▌SWORD▐"
1360 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
1370 FOR I=1 TO CODE ":"
1380 PRINT AT 5,CODE ";";"S";N
1390 PRINT AT 11,0;M$
1400 PRINT S$(N)
1410 LET N=N+1
1420 GOSUB 3980
1430 NEXT I
1440 CLS
1450 GOTO 0170
1460 DIM P$(CODE ":",CODE "1")
1470 LET P$(1)="ECSTASY, WEALTH, PROSPERITY"
1480 LET P$(2)="HARMONIOUS CHANGE, DIPLOMACY"
1490 LET P$(3)="ARTFUL MASTER, CONSTRUCTION"
1500 LET P$(4)="POSSESSIVE, MISERLY, SELFISH"
1510 LET P$(5)="DESTITUTION, LOVE GONE ASTRAY"
1520 LET P$(6)="PHILANTHROPY, SHARED WEALTH"
1530 LET P$(7)="GROWTH, ENDEAVOR, A SOULMATE"
1540 LET P$(8)="APPRENTICESHIP, EMPLOYMENT"
1550 LET P$(9)="ACCOMPLISHMENT, WELL-BEING"
1560 LET P$(CODE "~~")="FAMILY LINEAGE, INHERITANCE"
1570 LET P$(11)="DILIGENT YOUTH; SCHOLARSHIP"
1580 LET P$(CODE "£")="METHODICAL MAN; PATIENCE"
1590 LET P$(CODE "$")="INTELLIGENT WOMAN; GENEROSITY"
1600 LET P$(CODE ":")="MAN OF CHARACTER; RELIABILITY"
1610 LET N=1
1620 PRINT "PENTACLES INDICATE-"
1630 PRINT "MONEY, INTEREST, TRADE, ▛▀▀▀▀▀▜ MATERIALISM, INDUSTRY ▌ ▟▖ ▐ AND THE MAGICAL ARTS... ▌ ▜██▘▐"
1640 PRINT TAB CODE "/";"▌ ▗▀▚ ▐"
1650 PRINT TAB CODE "/";"▌ ▐"
1660 PRINT TAB CODE "/";"▌OF ▐"
1670 PRINT TAB CODE "/";"▌PENT-▐"
1680 PRINT TAB CODE "/";"▌ACLES▐"
1690 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
1700 FOR I=1 TO 14
1710 PRINT AT 5,CODE ";";"P";N
1720 PRINT AT 11,0;M$
1730 PRINT P$(N)
1740 LET N=N+1
1750 GOSUB 3980
1760 NEXT I
1770 CLS
1780 GOTO 0170
1790 CLS
1800 LET N=1
1810 DIM H$(CODE "-",CODE "2")
1820 LET H$(CODE "▘")="AN IMPORTANT CHOICE IN LIFE"
1830 LET H$(CODE "▝")="MASTERY, WISDOM, CREATIVITY"
1840 LET H$(CODE "▀")="HIDDEN INFLUENCES, DUALITY"
1850 LET H$(CODE "▖")="MARRIAGE, WEALTH, FERTILITY"
1860 LET H$(CODE "▌")="POWER, INTELLECT OVER PASSION"
1870 LET H$(CODE "▞")="RITUAL, CONFORMITY, CONVENTION"
1880 LET H$(CODE "▛")="SACRED OR PROFANE LOVE, CHOICE"
1890 LET H$(CODE "▒")="CONQUEST, TRIUMPH, GREATNESS"
1900 LET H$(CODE ",,")="TRIUMPH OF LOVE, ENERGY, POWER"
1910 LET H$(CODE "~~")="WISDOM, PRUDENCE, GUIDANCE"
1920 LET H$(11)="GOOD FORTUNE, TURN OF LUCK"
1930 LET H$(CODE "£")="BALANCED PERSONALITY, EQUALITY"
1940 LET H$(CODE "$")="CHANGE OF MIND, PAUSE IN LIFE"
1950 LET H$(CODE ":")="RENEWAL, ALTERED CONSCIOUSNESS"
1960 LET H$(CODE "?")="COORDINATION, MIND OVER MATTER"
1970 LET H$(CODE "(")="DEATH OF OLD SELF, REVOLUTION"
1980 LET H$(CODE ")")="A LIFESTYLE CHANGE, BANKRUPTCY"
1990 LET H$(CODE ">")="INSPIRATION, DEVOTION, HEALTH"
2000 LET H$(CODE "<")="IMAGINATION, INTUITION, DREAMS"
2010 LET H$(CODE "=")="ACHIEVEMENT, BALANCE IN LIFE"
2020 LET H$(CODE "+")="RENEWAL, INNER ENLIGHTENMENT"
2030 LET H$(CODE "-")="EARNED REWARD, ASSURED SUCCESS"
2040 PRINT "0-THE FOOL"
2050 PRINT "STEPS FEARLESSLY OFF A ▛▀▀▀▀▀▜ LEDGE. HE ALONE CARRIES ▌ */* ▐ THE WAND OF COSMIC WILL ▌ /["] ▐ AND SUPERCONSCIOUSNESS. ▌ ▙█▜ ▐"
2060 PRINT TAB CODE "/";"▌ █▄ ▐"
2070 PRINT TAB CODE "/";"▌ ▗▌▝ ▐"
2080 PRINT TAB CODE "/";"▌ ~~▒▒▒▐"
2090 PRINT TAB CODE "/";"▌ ▒▒▒▐"
2100 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2110 GOSUB 3910
2120 PRINT "1-THE MAGICIAN"
2130 PRINT "STANDS ON HIS PLATFORM ▛▀▀▀▀▀▜ SURROUNDED BY MAGICAL ▌ <=> ▐ COSMIC SYMBOLS. ▌ ▖["] ▐"
2140 PRINT TAB CODE "/";"▌+▀[?]▜/▐"
2150 PRINT TAB CODE "/";"▌ [*] ▐"
2160 PRINT TAB CODE "/";"▌ ▗█▖ ▐"
2170 PRINT TAB CODE "/";"▌ [▒][▒][▒] ▐"
2180 PRINT TAB CODE "/";"▌ [▒][▒][▒] ▐"
2190 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2200 GOSUB 3910
2210 PRINT "3-THE HIGH PRIESTESS"
2220 PRINT "STANDS BETWEEN THE ▛▀▀▀▀▀▜ PILLARS OF POSITIVE AND ▌-▗▄▖+▐ NEGATIVE LIFE FORCES. ▌█▝["]▘▒▐"
2230 PRINT TAB CODE "/";"▌█▐[*]▌▒▐"
2240 PRINT TAB CODE "/";"▌█▝█▘▒▐"
2250 PRINT TAB CODE "/";"▌█ █ ▒▐"
2260 PRINT TAB CODE "/";"▌█▗█▖▒▐"
2270 PRINT TAB CODE "/";"▌█>=<▒▐"
2280 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2290 GOSUB 3910
2300 PRINT "4-THE EMPRESS"
2310 PRINT "RESTS ON HER THRONE, ▛▀▀▀▀▀▜ CROWNED BY STARS; SHE ▌ * ▐ RADIATES LIFE ENERGY. ▌*[~~]* ▐"
2320 PRINT TAB CODE "/";"▌▝["]▘ 0▐"
2330 PRINT TAB CODE "/";"▌▐[+]▙/ ▐"
2340 PRINT TAB CODE "/";"▌▐[~~][~~]█ ▐"
2350 PRINT TAB CODE "/";"▌▐ ▐▐▖▐"
2360 PRINT TAB CODE "/";"▌[O][O][O][O][O]▐"
2370 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2380 GOSUB 3910
2390 PRINT "4-THE EMPEROR"
2400 PRINT "COMMANDINGLY STANDS ▛▀▀▀▀▀▜ BETWEEN THE RAMS HEAD ▌ *▄* ▐ SYMBOLS OF MARS; LORD ▌ ,,["],, ▐ OF THOUGHT AND REASON. ▌▜▐[+]▌/▐"
2410 PRINT TAB CODE "/";"▌▐▀[▒]▀ ▐"
2420 PRINT TAB CODE "/";"▌▚ [▒] ▞▐"
2430 PRINT TAB CODE "/";"▌["]▗█▖["]▐"
2440 PRINT TAB CODE "/";"▌[~~][~~][~~][~~][~~]▐"
2450 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2460 GOSUB 3910
2470 PRINT "5-THE HIEROPHANT"
2480 PRINT "STANDS BEFORE TWO NEW ▛▀▀▀▀▀▜ INITIATES, THE RULING ▌* [+]▗▙▐ POWER OF CEREMONY. ▌▐(["])▌▐"
2490 PRINT TAB CODE "/";"▌▝▀█▜▌▐"
2500 PRINT TAB CODE "/";"▌ ▗[~~]▖▌▐"
2510 PRINT TAB CODE "/";"▌ ▐█▌▘▐"
2520 PRINT TAB CODE "/";"▌+▀ ▀+▐"
2530 PRINT TAB CODE "/";"▌▙["]▄["]▟▐"
2540 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2550 GOSUB 3910
2560 PRINT "6-THE LOVERS"
2570 PRINT "STAND TOGETHER AMONG ▛▀▀▀▀▀▜ THE TREES OF UNITY AND ▌▞▄▚▄▞▐ DUALITY; THE SERPENT ▌ ["]▝["]▘▐ AND THE APPLE NEARBY. ▌▐██[W]▌▐"
2580 PRINT TAB CODE "/";"▌▝█▀█▘▐"
2590 PRINT TAB CODE "/";"▌ █ █ ▐"
2600 PRINT TAB CODE "/";"▌▝▀▘▀(▐"
2610 PRINT TAB CODE "/";"▌▄▛▙["]O▐"
2620 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2630 GOSUB 3910
2640 PRINT "7-THE CHARIOT"
2650 PRINT "THE SPHINXES OF MERCY ▛▀▀▀▀▀▜ AND JUSTICE CAN TEAR ▌ * ▐ THE CHARIOTEER IN TWO ▌ (["]) ▐ IF HIS RESOLVE WEAKENS. ▌▖▟[+]▙▗▐"
2660 PRINT TAB CODE "/";"▌▙[▒]▒[▒]▟▐"
2670 PRINT TAB CODE "/";"▌▌[~~]~~[~~]▐▐"
2680 PRINT TAB CODE "/";"▌▝["]▀""▘▐"
2690 PRINT TAB CODE "/";"▌▗█▄█▖▐"
2700 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2710 GOSUB 3910
2720 PRINT "8-STRENGTH"
2730 PRINT "A WOMAN OF MAGIC CLOSES ▛▀▀▀▀▀▜ THE MOUTH OF A LION; ▌*▗▄▖*▐ COSMIC FORCES OFFER NO ▌*▝["]▘*▐ RESISTANCE TO HER FEAT. ▌*▛[W]▜*▐"
2740 PRINT TAB CODE "/";"▌ ▀[-]▝ ▐"
2750 PRINT TAB CODE "/";"▌ ▚██▛▐"
2760 PRINT TAB CODE "/";"▌ ▟▗▌▐"
2770 PRINT TAB CODE "/";"▌[~~][~~][~~][~~][~~]▐"
2780 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2790 GOSUB 3910
2800 PRINT "9-THE HERMIT"
2810 PRINT "A LONE FIGURE ATOP A ▛▀▀▀▀▀▜ MOUNTAIN LIGHTS THE WAY ▌.▗▄▖.▐ TO THE UNION OF COSMIC ▌▄▝["]▘▛▐ WILL AND CONSCIOUSNESS. ▌▒▟█▙▌▐"
2820 PRINT TAB CODE "/";"▌▀▐█▌▌▐"
2830 PRINT TAB CODE "/";"▌.▐█▌▌▐"
2840 PRINT TAB CODE "/";"▌ ▗█▖▌▐"
2850 PRINT TAB CODE "/";"▌,,▒▒▒,,▐"
2860 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2870 GOSUB 3910
2880 PRINT "10-WHEEL OF FORTUNE"
2890 PRINT "EMBLAZONED WITH MAGICAL ▛▀▀▀▀▀▜ SYMBOLS, TURNS FOREVER ▌▞ ▚▐ IN UNCHANGING REALITY. ▌▗▟▀▙▖▐"
2900 PRINT TAB CODE "/";"▌▟>?*▙▐"
2910 PRINT TAB CODE "/";"▌▌£+=▐▐"
2920 PRINT TAB CODE "/";"▌▜/0<▛▐"
2930 PRINT TAB CODE "/";"▌▝▜▄▛▘▐"
2940 PRINT TAB CODE "/";"▌▚ ▞▐"
2950 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
2960 GOSUB 3910
2970 PRINT "11-JUSTICE"
2980 PRINT "CARRIES THE SCALES OF ▛▀▀▀▀▀▜ JUSTICE AND THE DOUBLE- ▌▐▗[=]▖ ▐ EDGED SWORD OF THE LAW. ▌▐▝["]▘ ▐"
2990 PRINT TAB CODE "/";"▌▟▟[W]▙ ▐"
3000 PRINT TAB CODE "/";"▌▝▜[,,][▒],,▐"
3010 PRINT TAB CODE "/";"▌ ▐[A]▌A▐"
3020 PRINT TAB CODE "/";"▌ ▟~~▙~~▐"
3030 PRINT TAB CODE "/";"▌[▒][▒][▒][▒][▒]▐"
3040 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3050 GOSUB 3910
3060 PRINT "12-THE HANGED MAN"
3070 PRINT "IN A DEEP TRANCE, AND ▛▀▀▀▀▀▜ SUSPENDED FROM A LIVING ▌,,,,,,,,,,▐ GALLOWS BY ONE LEG; AN ▌ ▝█▗ ▐ AURA SURROUNDS HIS HEAD.▌ ▐█▀ ▐"
3080 PRINT TAB CODE "/";"▌ ▄█▄ ▐"
3090 PRINT TAB CODE "/";"▌ ▙█▟ ▐"
3100 PRINT TAB CODE "/";"▌ (["]) ▐"
3110 PRINT TAB CODE "/";"▌ ▒ ▐"
3120 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3130 GOSUB 3910
3140 PRINT "13-DEATH"
3150 PRINT "APPEARS AS A SKULL ▛▀▀▀▀▀▜ BEFORE WHICH ALL ARE ▌ ▗ ▖▐ POWERLESS; THE FLOWER ▌▗▄ [▒] ▐ OF LIFE IS NEARBY. ▌▛▛▛)▘▐"
3160 PRINT TAB CODE "/";"▌▜▜▘( ▐"
3170 PRINT TAB CODE "/";"▌▝▀ ["]▐"
3180 PRINT TAB CODE "/";"▌▖ ▖["][▒]▐"
3190 PRINT TAB CODE "/";"▌▀▀▀~~~~▐"
3200 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3210 GOSUB 3910
3220 PRINT "14-TEMPERANCE"
3230 PRINT "WITH ONE FOOT IN THE ▛▀▀▀▀▀▜ MAIN STREAM OF COSMIC ▌▗▄▖ *▐ CONSCIOUSNESS, AN ANGEL ▌▝["]▘▄▗▐ POURS THE ESSENCE OF ▌▐[+][,,]█▜▐ LIFE FROM CUP TO CUP. ▌▐██ ▐"
3240 PRINT TAB CODE "/";"▌▐█▙ [▒]▐"
3250 PRINT TAB CODE "/";"▌▀[▒][,,][▒][▒]▐"
3260 PRINT TAB CODE "/";"▌[▒][▒][▒] ▐"
3270 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3280 GOSUB 3910
3290 PRINT "15-THE DEVIL"
3300 PRINT "ABOVE A BESTIALIZED MAN ▛▀▀▀▀▀▜ AND WOMAN; HIS INVERTED ▌▌▐▄▟ ▐ TORCH MEANS DESTRUCTION.▌▌▛▜▀▌▐"
3310 PRINT TAB CODE "/";"▌[▒]▜[<]█▘▐"
3320 PRINT TAB CODE "/";"▌ ▖▙▌▖▐"
3330 PRINT TAB CODE "/";"▌["]▘▝["]▘▐"
3340 PRINT TAB CODE "/";"▌[W]▚▞█▘▐"
3350 PRINT TAB CODE "/";"▌█▞▚█▖▐"
3360 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3370 GOSUB 3910
3380 PRINT "16-THE TOWER"
3390 PRINT "STRUCK BY SPIRITUAL ▛▀▀▀▀▀▜ LIGHTNING FROM ABOVE, ▌ ~~,, ▐ THE TOWER CRUMBLES. ▌ ▙▙[~~]▌▐"
3400 PRINT TAB CODE "/";"▌ ▐▐[/]▗▐"
3410 PRINT TAB CODE "/";"▌ ▐[/]▗ ▐"
3420 PRINT TAB CODE "/";"▌ ▐█[/]▝▐"
3430 PRINT TAB CODE "/";"▌ ▐[/]█ ▐"
3440 PRINT TAB CODE "/";"▌▗███▙▐"
3450 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3460 GOSUB 3910
3470 PRINT "17-THE STAR"
3480 PRINT "RADIATES COSMIC ENERGY ▛▀▀▀▀▀▜ UPON A MAIDEN STANDING ▌. ▖. ▐ NEAR THE POOL OF LIFE. ▌ ▚▙▘ ▐"
3490 PRINT TAB CODE "/";"▌▝▜█▀.▐"
3500 PRINT TAB CODE "/";"▌ ▘▌▘)▐"
3510 PRINT TAB CODE "/";"▌. ["] ▐"
3520 PRINT TAB CODE "/";"▌ ▝[W]▘▐"
3530 PRINT TAB CODE "/";"▌,,,,▗█▖▐"
3540 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3550 GOSUB 3910
3560 PRINT "18-THE MOON"
3570 PRINT "REFLECTS SUBCONSCIOUS ▛▀▀▀▀▀▜ LIGHT UPON THE PATH OF ▌▗▖▗▖.▐ CONSCIOUS PROGRESS AND ▌[+].▜█▖▐ THE CREATIONS OF MAN. ▌█ .██▐"
3580 PRINT TAB CODE "/";"▌█ ▟█▘▐"
3590 PRINT TAB CODE "/";"▌█▙▝▘ ▐"
3600 PRINT TAB CODE "/";"▌ ,,▒~~▐"
3610 PRINT TAB CODE "/";"▌▒▒~~ ▐"
3620 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3630 GOSUB 3910
3640 PRINT "19-THE SUN"
3650 PRINT "SHINES GROWTH AND LIFE ▛▀▀▀▀▀▜ ON THE NAKED CHILD OF ▌▚▝▄▘▞▐ MAN AND ALL OF NATURE. ▌▖▟█▙▗▐"
3660 PRINT TAB CODE "/";"▌▐███▌▐"
3670 PRINT TAB CODE "/";"▌▘▜█▛▝▐"
3680 PRINT TAB CODE "/";"▌▞ ▀ ▚▐"
3690 PRINT TAB CODE "/";"▌ ▗["]▖ ▐"
3700 PRINT TAB CODE "/";"▌ ▗[.]▖ ▐"
3710 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3720 GOSUB 3910
3730 PRINT "20-JUDGEMENT"
3740 PRINT "AN ANGEL BLOWS ON HIS ▛▀▀▀▀▀▜ TRUMPET TO LIBERATE MAN ▌▙["]▟▙▖▐ FROM TERRESTRIAL LIMITS.▌▘[+]▘.▘▐"
3750 PRINT TAB CODE "/";"▌▄.*▗▄▐"
3760 PRINT TAB CODE "/";"▌["] ▝["]▐"
3770 PRINT TAB CODE "/";"▌█▄["]▄[W]▐"
3780 PRINT TAB CODE "/";"▌█▗[.]▖█▐"
3790 PRINT TAB CODE "/";"▌[,,]▘,,▝[,,]▐"
3800 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3810 GOSUB 3910
3820 PRINT "21-THE WORLD"
3830 PRINT "THE SUCCESSFUL SEEKER ▛▀▀▀▀▀▜ OF SUPERCONSCIOUSNESS ▌ ▄▀▄ ▐ DANCES JOYOUSLY WITHIN ▌▞▗▄▖▚▐ THE WREATH OF NATURE. ▌▐▝["]▘▌▐"
3840 PRINT TAB CODE "/";"▌▌▙[W]▟▐▐"
3850 PRINT TAB CODE "/";"▌▐▄█ ▌▐"
3860 PRINT TAB CODE "/";"▌▚▘▐▖▞▐"
3870 PRINT TAB CODE "/";"▌ ▀▄▀ ▐"
3880 PRINT TAB CODE "/";"▙▄▄▄▄▄▟"
3890 GOSUB 3910
3900 GOTO 0170
3910 PRINT
3920 PRINT AT 11,0;M$
3930 PRINT H$(N)
3940 LET N=N+1
3950 GOSUB 3980
3960 CLS
3970 RETURN
3980 PRINT AT CODE "+",CODE ":";"""C"" TO CONTINUE-"
3990 IF INKEY$ <>"C" THEN GOTO 3990
4000 RETURN
4010 PRINT
4020 PRINT "LOAD ""READING"" FOR A READING."
4030 STOP
9990 SAVE "CARD[S]"
9999 RUN
Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.