Time Bomb

   1 REM "TIME BOMB"
   2 FAST 
   5 RAND 
  10 PRINT "YOU HAVE FIVE SECONDS TO DEFUSE A BOMB.  YOU WILL BE SHOWN A    SERIES OF CLOCK FACES SHOWING   TIMES PICKED AT RANDOM.  IF YOU ENTER THE CORRECT TIME YOU ARE  GIVEN AN EXTRA SECOND.  IF YOU  ENTER THE WRONG TIME IT COSTS   YOU A SECOND.  IF THE COUNT     REACHES ZERO THE BOMB EXPLODES. IF THE COUNT REACHES 10 YOU     DEFUSE THE BOMB.  DO NOT ENTER ACOLON TO ENTER THE TIME.  1:30  IS ENTERED AS 130.  SELECT LEVEL(1 - 5)"
  20 INPUT LEVEL
  30 LET COUNT=5
  40 LET TIME=INT (RND*1200)+100
  50 LET T$=STR$ TIME
  60 IF LEN T$=3 THEN LET T$="0"+T$
  70 LET M$=T$(3 TO )
  80 IF VAL M$>59 THEN GOTO 40
  90 IF VAL M$<>0 AND LEVEL=1 THEN GOTO 40
 100 IF (VAL M$/30)<>INT (VAL M$/30) AND LEVEL=2 THEN GOTO 40
 110 IF (VAL M$/15)<>INT (VAL M$/15) AND LEVEL=3 THEN GOTO 40
 120 IF (VAL M$/5)<>INT (VAL M$/5) AND LEVEL=4 THEN GOTO 40
 130 CLS 
 150 FOR D=1 TO 12
 160 PRINT AT 10-8*COS (D/6*PI),16+8*SIN (D/6*PI);D
 170 NEXT D
 180 FOR I=1 TO 60
 190 PLOT 33+20*SIN (I/30*PI),22+20*COS (I/30*PI)
 200 NEXT I
 210 LET H=2*INT (TIME/100)
 220 IF VAL M$>15 THEN LET H=H+1
 230 IF VAL M$>45 THEN LET H=H+1
 240 LET L=VAL M$/30*PI
 250 LET D=33+14*SIN L
 260 LET E=22+14*COS L
 270 GOSUB 1000
 280 LET G=H/12*PI
 290 LET D=33+10*SIN G
 300 LET E=22+10*COS G
 310 GOSUB 1000
 330 PRINT AT 0,25;COUNT
 340 INPUT RESPONSE
 350 IF RESPONSE<>TIME THEN GOTO 390
 360 LET COUNT=COUNT+1
 370 IF COUNT=10 THEN GOTO 2000
 380 GOTO 410
 390 LET COUNT=COUNT-1
 400 IF COUNT=0 THEN GOTO 2100
 410 GOTO 40
\n1000 REM DRAW
\n1010 LET X=33
\n1020 LET Y=22
\n1050 LET A=X-D
\n1060 LET B=Y-E
\n1070 LET C=(A AND ABS A>=ABS B)+(B AND ABS B>ABS A)
\n1080 IF C=0 THEN LET C=0.1
\n1090 FOR F=0 TO C STEP SGN C
\n1100 PLOT X+A/C*-F,Y+B/C*-F
\n1110 NEXT F
\n1120 RETURN 
\n2000 CLS 
\n2010 PRINT "YOU DID IT","%Y%O%U% %D%I%D% %I%T"
\n2020 GOTO 2010
\n2100 CLS 
\n2110 PRINT "BOOM";"%B%O%O%M";
\n2120 GOTO 2110