Tracker

Gallery

Source Code

  10 REM \CD\E7\02\06\0E\21\00\FF\2B\7C\B5\20\FB\10\F6\2A\10\40\23\4E\23\46\23\C5\5E\CD\1F\03\C1\0B\78\B1\20\F4\C9\CD\E7\02\2A\10\40\23\4E\23\46\23\C5\1E\08\DB\FE\D3\FF\17\30\F9\0E\94\06\1A\0D\DB\FE\17\CB\79\79\38\F5\10\F5\20\04\FE\56\30\E4\3F\CB\16\1D\20\DE\C1\0B\78\B1\C8\18\D3
  20 DIM A$(1,1459)
  30 DIM B$(1,63)
  40 DIM F$(12,10)
  50 DIM A(48)
  60 REM %L%O%A%D% %F%$% %A%R%R%A%Y% % % % % % % % % % 
  70 FOR X=1 TO 12
  80 PRINT AT 10,0;"ENTER EVENT TITLE";TAB 19;X;TAB 24;"(10 POS)"
  90 INPUT F$(X)
 100 NEXT X
 110 REM %L%O%A%D% %A% %A%R%R%A%Y% % % % % % % % % % % 
 120 FOR X=1 TO 48
 130 PRINT AT 10,0;"ENTER STARTING POSITION OF FIELD"
 140 INPUT A(X)
 150 NEXT X
 160 REM %P%R%I%N%T% %A%R%R%A%Y%S% % % % % % % % % % % 
 170 LPRINT "F$ ARRAY",,,,
 180 FOR X=1 TO 12 STEP 2
 190 LPRINT X;TAB 3;F$(X);TAB 15;X+1;TAB 19;F$(X+1)
 200 NEXT X
 210 LPRINT ,,"A ARRAY",,,,
 220 FOR X=1 TO 48 STEP 3
 230 LPRINT X;TAB 3;A(X);TAB 10;X+1;TAB 13;A(X+1);TAB 20;X+2;TAB 23;A(X+2)
 240 NEXT X
 250 REM %R%E%A%D% %A% %R%E%C%O%R%D% %F%R%O%M% %T%A%P%E
 260 CLS 
 270 SLOW 
 280 PRINT AT 2,13;"TRACKER"
 290 PRINT AT 10,0;"PLACE DATA TAPE IN TAPE DECK"
 300 PRINT AT 12,0;"PRESS ""PLAY"" ON TAPE DECK"
 310 PRINT AT 14,0;"PRESS ""ENTER"" ON COMPUTER"
 320 INPUT Z$
 330 RAND USR 16549
 340 CLS 
 350 SLOW 
 360 PRINT AT 12,0;"PRESS ""STOP"" ON TAPE DECK"
 370 PRINT AT 14,0;"PRESS ""ENTER"" ON COMPUTER"
 380 INPUT Z$
 390 REM %C%H%E%C%K% %F%O%R% %R%I%G%H%T% %P%E%R%S%O%N% 
 400 CLS 
 410 PRINT AT 2,13;"TRACKER"
 420 PRINT AT 8,0;"GEN/CODE NBR.  ";A$(1, TO 5)
 430 PRINT "FIRST NAME     ";A$(1,6 TO 20)
 440 PRINT "SECOND NAME    ";A$(1,21 TO 35)
 450 PRINT "THIRD NAME     ";A$(1,36 TO 50)
 460 PRINT "LAST NAME      ";A$(1,51 TO 65)
 470 PRINT AT 14,0;"DO YOU WISH TO TRACK THIS PERSON"
 480 PRINT "(Y OR N)"
 490 IF INKEY$="" THEN GOTO 0490
 500 LET I$=INKEY$
 510 IF I$<>"Y" AND I$<>"N" THEN GOTO 0480
 520 CLS 
 530 IF I$="N" THEN GOTO 0250
 540 REM %F%O%R%M%A%T% %R%E%C%O%R%D%S% % % % % % % % % 
 550 REM %R%E%D%U%C%E% %N%A%M%E% %L%E%N%G%T%H% % % % % 
 560 FAST 
 570 DIM B$(1,70)
 580 LET B$(1, TO 15)=A$(1,6 TO 20)
 590 LET B$(1,17 TO 31)=A$(1,21 TO 35)
 600 LET B$(1,33 TO 47)=A$(1,36 TO 50)
 610 LET B$(1,49 TO 63)=A$(1,51 TO 65)
 620 LET D$=""
 630 FOR X=1 TO 63
 640 IF B$(1,X)=" " THEN GOTO 0670
 650 LET D$=D$+B$(1,X)
 660 IF B$(1,X+1)=" " THEN LET D$=D$+" "
 670 NEXT X
 680 LET B$(1)=""
 690 LET B$(1,((70-LEN D$)/2) TO )=D$
 700 REM %F%O%R%M%A%T% %E%V%E%N%T% %L%I%N%E%S% % % % % 
 710 DIM C$(12,70)
 720 LET X=1
 730 LET L=1
 740 FOR I=1 TO 12
 750 IF A$(1,A(X))=" " THEN GOTO 0820
 760 LET C$(L, TO 10)=A$(1,A(X) TO (A(X)+9))
 770 LET C$(L,12 TO 21)=F$(I)
 780 LET Z$=A$(1,A(X+1) TO (A(X+1)+14))+" "+A$(1,A(X+2) TO (A(X+2)+14))+" "+"CO. "+A$(1,A(X+3) TO (A(X+3)+14))+" "
 790 GOSUB 0850
 800 LET C$(L,23 TO )=Z$
 810 LET L=L+1
 820 LET X=X+4
 830 NEXT I
 840 GOTO 0940
 850 REM %R%E%D%U%C%E% %P%L%A%C%E% %L%E%N%G%T%H% % % % 
 860 LET D$=""
 870 FOR Z=1 TO 47
 880 IF Z$(Z)=" " THEN GOTO 0910
 890 LET D$=D$+Z$(Z)
 900 IF Z$(Z+1)=" " THEN LET D$=D$+" "
 910 NEXT Z
 920 LET Z$=D$
 930 RETURN 
 940 REM %S%O%R%T% %R%E%C%O%R%D%S% % % % % % % % % % % 
 950 FOR X=1 TO L-1
 960 FOR S=X+1 TO L
 970 IF C$(X, TO 10)<C$(S, TO 10) THEN GOTO 1010
 980 LET S$=C$(X)
 990 LET C$(X)=C$(S)
1000 LET C$(S)=S$
1010 NEXT S
1020 NEXT X
1030 REM %P%R%I%N%T% %R%E%C%O%R%D%S% % % % % % % % % % 
1040 LPRINT "% % % % %         ";B$(1, TO 19),,
1050 LPRINT "% % % % %         ";"DATE       EVENT",,,
1060 FOR X=1 TO L
1070 IF C$(X,1)=" " THEN NEXT X
1080 LPRINT "% % % % %         ";C$(X, TO 19),,
1090 NEXT X
1100 LPRINT ,,"--------------------------------",,
1110 LPRINT B$(1,20 TO 51),,
1120 LPRINT "   PLACE                        ",,
1130 FOR X=1 TO L
1140 IF C$(X,1)=" " THEN NEXT X
1150 LPRINT C$(X,20 TO 51),,
1160 NEXT X
1170 LPRINT ,,"--------------------------------",,
1180 LPRINT B$(1,52 TO );"       % % % % % % ",,
1190 LPRINT "                          % % % % % % ",,
1200 FOR X=1 TO L
1210 IF C$(X,1)=" " THEN NEXT X
1220 LPRINT C$(X,52 TO );"       % % % % % % ",,
1230 NEXT X
1240 LPRINT ,,"--------------------------------",,
1250 GOTO 0250
1260 REM %S%A%V%E% %T%R%A%C%K%E%R% % % % % % % % % % % 
1270 SAVE "1016%1"
1280 GOTO 0250