Design

Run this flashy program on a TV as a personalized store window ad. The program listed displays the slogan SYNTAX and SQ among moving designs. First RUN the program to see how the slogan is centered, then EDIT line 130 to insert your specific message.

RUNning the program displays several options first. Start as directed on the lower half of the menu. RECORD A DESIGN consists of two options: RECONSTRUCT A DESIGN freezes a design (without your slogan) for which you enter codes, and CREATE A DESIGN randomly generates designs around your slogan.

Syntactic Sums vary with the message in line 130. DESIGN uses slightly more than 2K RAM.

   1 REM "DESIGN" (CHANGING PATTERN AND SALES MESSAGE, SLOGAN OR NAME)
   2 PRINT AT 4,0;"TO RECORD A DESIGN -",,,"▪ PRESS ""BREAK"" WHEN DESIGN"
   3 PRINT AT 7,4;"FILLS SCREEN"
   4 PRINT AT 8,0;"▪ GO TO 200"
   6 PRINT AT 15,0;"█ TO START PROGRAM -"
   7 PRINT AT 16,4;"PRESS ANY KEY EXCEPT ""BREAK"""
   8 PAUSE 4E4
   9 CLS
  10 DIM A$(6)
  20 FOR K=1 TO 6
  30 LET J=INT (RND*22)+1
  40 IF J>11 THEN LET J=J+116
  50 IF J<=11 THEN LET J=J-1
  60 LET A$(K)=CHR$ J
  70 NEXT K
  80 FOR L=1 TO 112
  90 PRINT A$;
 100 NEXT L
 110 PAUSE 45
 120 FOR J=1 TO 22
 130 PRINT AT 15,7;"SYNTAX";TAB 16;"AND";TAB 22;"SQ"
 140 SCROLL
 150 NEXT J
 160 PRINT AT 0,0
 170 GOTO 20
 200 PRINT TAB 4;"THE DESIGN ELEMENTS ARE:",,,
 210 FOR J=1 TO 6
 220 PRINT TAB 14;A$(J);TAB 16;"(";CODE A$(J);")"
 230 PRINT
 240 NEXT J
 250 PRINT AT 14,0;"[illegible]"
 260 PRINT AT 16,0;"TO RECONSTRUCT DESIGN -",
 270 PRINT AT 17,3;"▪MAKE A NOTE OF CODE NUMBERS     AND TYPE ""R"""
 280 PRINT AT 20,0;"TO CREATE NEW DESIGNS -"
 290 PRINT AT 21,3;"▪TYPE ""N"""
 300 INPUT C$
 310 IF C$="R" THEN GOTO 340
 320 CLS
 330 GOTO 10
 340 CLS
 350 DIM D$(6)
 360 FOR J=1 TO 6
 370 PRINT "CODE NO. OF ELEMENT ";"(";J;") ?"
 380 INPUT X
 390 CLS
 400 LET D$(J)=CHR$ (X)
 410 NEXT J
 420 FOR J=1 TO 112
 430 PRINT D$;
 440 NEXT J
 450 PRINT AT 21,0;"TO RETURN TO PROGRAM - PRESS ""R"""
 460 PAUSE 4E4
 470 CLS
 480 GOTO 10
SYNTACTIC SUM: 7339, 8K ROM