Recipes for 2068 Advanced Video

Your TS2068 can display lines of 64 characters, more detailed color, or a completely separate display file. We show you how to activate these functions and plot hi-res (512×192) points.

First, use program 1 to move system variables out of the area used by DFILE 2, change video mode, and clear DFILE 2. Timex supplied this machine code. LOAD & RUN it; use p. 248 of your 2068 manual to choose video mode. (Mode 62 gives the best 64 col. display.)

Now use program 2 to accept Y,X-pairs and plot on the 64-column screen. Prior plots aren’t erased.

Hints:

• G=file number (0-1)
• K=high digits, character line (0-2)
• I=scan line in character line (0-7)
• J=low digits, character line (0-7)
• H=character position in line (0-31)
• S=dot position in character (7-0)

    POKE 01GK KIII  JJJH HHHH,SSS
Binary:  High byte  Low  byte,Data

Program 1

  1 REM Don't NEW after this
  2 CLEAR 65399
  5 READ A,B,C,D,E,F
  6 DATA 10,11,12,13,14,15
 10 READ Q$
 15 LET P=1
 20 FOR X=65400 TO 65437
 30 LET X$=Q$(P TO P+1)
 40 LET V=VAL (X$(1))*16+VAL (X$(2))
 50 POKE X,V
 60 LET P=P+3
 70 NEXT X
 80 INPUT "Video Mode:";V
 90 POKE 65412,V
 95 RANDOMIZE USR 65400
100 DATA "F3,3E,01,D3,F4,DB,FF,CB,FF,D3,FF,3E,01,F5,FB,CD,8E,0E,F3,DB,FF,CB,BF,D3,FF,AF,D3,F4,F1,FE,80,20,03,32,2C,5C,FB,C9"

Program 2

  5 DEF FN R(N,D)=N-INT (N/D)*D
  7 OUT 255,62
 10 INPUT "Y<=191 from top? ";Y
 20 LET KK=INT (Y/64)
 30 LET JJJ=INT (FN R(Y,64)/8)
 40 LET III=FN R(FN R(Y,64),8)
 50 INPUT "X<=511 fm left? ";X
 60 LET HHHHH=INT (X/16)
 70 LET G=INT (FN R(X,16)/8)
 80 LET SSS=FN R(FN R(X,16),8)
 90 LET DAT=2↑(7-SSS)
110 LET ADDR=16384+G*8192+KK*2048+III*256+JJJ*32+HHHHH
120 POKE ADDR,DAT
130 GO TO 10