Rule of 1978 – Car Loan Payments

This program can be used to closely approximate the repayment schedule of a bank financed auto loan. Most banks use the “Rule of 1978” rather than the simple interest formula to calculate loan payments for cars. Even though the total amount of interest paid is the same in either case, in the “Rule of 1978” loan more of the interest is paid in the earlier payments and less in the latter payments, compared to a simple interest loan (i.e., in a simple interest loan the interest is figured on the unpaid balance). This rule was developed due to the rapid depreciation of new car values.

This program allows the option of printing to the ZX or TS 2040 printer, using LPRINT statements. For any time period over 14 months, the screen fills up and it is necessary to press CONTinue, then ENTER. This can be avoided by adding line: 485 IF I > 15 THEN SCROLL.

The last number in the balance column gives an indication of the accuracy of the calculation. The smaller the absolute value of the number, the better the calculation.

Dollar Format Subroutine

Lines 900 through 990 of the “Rule of 1978” program comprise a dollar formatting subroutine that can be used in other business/financial programs. This routine converts the number represented by ZZ into the string Z$ which contains exactly two decimal places (i.e., 117 is converted to 117.00 and 456.8352 is converted to 456.84.)

1 REM ****RULE OF 1976****
2 REM * INTEREST PAYMENT *
3 REM *   P.G. SIMPSON   *
4 REM ****T-S HORIZONS****
100 PRINT "RULE OF 1978"
110 PRINT "INTEREST PAYMENT",,,
120 PRINT "AMOUNT TO BE FINANCED?";
125 INPUT PV
130 PRINT PV,"YEARLY INT. RATE(PERCENT)?";
135 INPUT YI
140 PRINT YI,"NUMBER OF MONTHS?";
142 INPUT N
144 PRINT N
146 LET PV=INT (PV*100)/100
148 LET MI=YI/1200
150 LET D=N*(N+1)/2
160 LET PM=PV/((1-(1+MI)**-N)/MI)
165 LET ZZ=PM
170 GOSUB 900
175 LET D$=Z$
190 LET AP=N*VAL D$
200 LET IC=0
210 LET IT=AP-PV
220 LET BL=PV
250 PRINT "DO YOU WANT A PRINTOUT?(Y/N)"
260 INPUT A$
270 IF A$="Y" THEN GOTO 310
280 IF A$="N" THEN GOTO 400
290 GOTO 260
300 FAST
310 LPRINT TAB 9;"RULE OF 1978"
320 LPRINT TAB 7;"INTEREST PAYMENT"
330 LPRINT ,,"AMOUNT TO BE FINANCED =";PV
340 LPRINT "YEARLY INT. RATE(PERCENT)=";YI
350 LPRINT "NUMBER OF MONTHS         =";N
360 LPRINT "MONTH PAYMENT  INTEREST  BALANCE"
400 PRINT "MONTH PAYMENT  INTEREST  BALANCE"
410 FOR I=1 TO N
430 LET IM=(N+1-I)/D*IT
432 LET ZZ=IM
434 GOSUB 900
436 LET I$=Z$
438 LET IM=VAL I$
440 LET BL=BL-PM+IM
450 LET ZZ=BL
460 GOSUB 900
465 LET B$=Z$
470 LET IC=IC+IM
480 PRINT TAB 1;I;TAB 3;D$;" ";I$;" ";B$
490 IF A$="Y" THEN LPRINT TAB 1;I;TAB 3;D$;" ";I$;" ";B$
500 NEXT I
510 LET ZZ=IC
512 GOSUB 900
514 LET I$=Z$
516 LET ZZ=AP
518 GOSUB 900
520 PRINT "SUM";Z$;" ";I$
530 IF A$="Y" THEN LPRINT "TOTAL";Z$;I$
550 PRINT "DO YOU WISH TO REPEAT?(Y/N)"
560 INPUT A$
570 IF A$="Y" THEN GOTO 100
580 IF A$<>"N" THEN GOTO 550
600 STOP
899 REM ROUTINE-FORMAT DOLLARS
900 LET Z$="        "+STR$ (INT ((ZZ+.005)*100)/100)
910 FOR X=1 TO LEN Z$
920 IF Z$(X)="." THEN GOTO 960
930 NEXT X
940 LET Z$=Z$+".00"
950 GOTO 980
960 IF LEN Z$-X=0 THEN LET Z$=Z$+"00"
970 IF LEN Z$-X=1 THEN LET Z$=Z$+"0"
980 LET Z$=Z$(LEN Z$-8 TO )
990 RETURN

         RULE OF 1978
       INTEREST PAYMENT

AMOUNT TO BE FINANCED =6000
YEARLY INT. RATE(PERCENT)=15
NUMBER OF MONTHS         =36
MONTH PAYMENT  INTEREST  BALANCE
  1    207.99      80.41   5872.42
  2    207.99      78.18   5742.61
  3    207.99      75.95   5610.56
  4    207.99      73.71   5476.28
  5    207.99      71.48   5339.77
  6    207.99      69.24   5201.02
  7    207.99      67.01   5060.04
  8    207.99      64.78   4916.82
  9    207.99      62.54   4771.37
 10    207.99      60.31   4623.69
 11    207.99      58.08   4473.78
 12    207.99      55.84   4321.63
 13    207.99      53.61   4167.24
 14    207.99      51.37   4010.62
 15    207.99      49.14   3851.77
 16    207.99      46.91   3690.69
 17    207.99      44.67   3527.37
 18    207.99      42.44   3361.81
 19    207.99      40.21   3194.03
 20    207.99      37.97   3024.01
 21    207.99      35.74   2851.76
 22    207.99      33.51   2677.28
 23    207.99      31.27   2500.55
 24    207.99      29.04   2321.60
 25    207.99      26.80   2140.41
 26    207.99      24.57   1956.99
 27    207.99      22.34   1771.34
 28    207.99      20.10   1583.44
 29    207.99      17.87   1393.32
 30    207.99      15.64   1200.97
 31    207.99      13.40   1006.38
 32    207.99      11.17    809.56
 33    207.99       8.93    610.50
 34    207.99       6.70    409.20
 35    207.99       4.47    205.68
 36    207.99       2.23      -.08
SUM   7487.64    1487.63