Videographity

Author(s): Alex San Miguel
Publication: Timex Sinclair User
Pub Details: Timex Sinclair User n5 (Volume 1, Issue 5)
Date: October 1983
Pages: 32
Cartoon painter at an easel-mounted TV showing the Mona Lisa
Cartoon painter at an easel-mounted TV showing the Mona Lisa

THIS is a game that allows you to draw a picture with the cursor. To erase something (move the cursor without leaving a trail), press E, and to draw again, press R. When you are finished, type A. To retrieve a picture previously loaded onto the cassette, type Y.

Submitted by Alex R. San Miguel of Tenafly, N.J. (T/S1000,1500,ZX81 16K).

   1 PRINT AT 10,9;"VIDEO GRAPHITY"
2 PAUSE 200
3 PRINT "THE FOLLOWING NUMBERS MOVE THE PIXEL TO DRAW:1.UP LEFT 2.DOWN LEFT 3.DOWN RIGHT 4.UP RIGHT 5.LEFT 6.DOWN 7.UP 8.RIGHT"
4 PRINT "TYPE E TO ERASE OR MOVE PIXEL WITHOUT DRAWING, TYPE R TO DRAW AGAIN, TYPE A TO STOP "
5 PRINT AT 21,0;"(PRESS ANY KEY)"
6 PAUSE 40000
8 PRINT AT 21,0;"DO YOU WANT LAST DRAWING?"
9 INPUT L$
10 IF L$="Y" THEN GOTO 199
11 CLS
12 DIM F(63,42)
13 LET X=31
14 LET Y=21
15 LET S=16
16 UNPLOT X,Y
17 PLOT X,Y
20 IF INKEY$="5" THEN LET X=X-1
25 IF INKEY$="1" THEN LET X=X-1
26 IF INKEY$="1" THEN LET Y=Y+1
30 IF INKEY$="6" THEN LET Y=Y-1
35 IF INKEY$="4" THEN LET Y=Y+1
36 IF INKEY$="4" THEN LET X=X+1
40 IF INKEY$="8" THEN LET X=X+1
45 IF INKEY$="3" THEN LET X=X+1
46 IF INKEY$="3" THEN LET Y=Y-1
50 IF INKEY$="7" THEN LET Y=Y+1
55 IF INKEY$="2" THEN LET Y=Y-1
56 IF INKEY$="2" THEN LET X=X-1
60 IF S=100 THEN LET F(X,Y)=0
65 IF S=16 THEN LET F(X,Y)=1
70 IF INKEY$="R" THEN LET S=16
75 IF INKEY$="E" THEN LET S=100
80 IF INKEY$="A" THEN GOTO 150
85 GOTO S
100 PLOT X,Y
101 UNPLOT X,Y
102 GOTO 20
150 CLS
151 PRINT "DO YOU WANT TO SAVE?"
152 INPUT L$
153 IF L$="Y" THEN GOTO 156
154 CLS
155 STOP
156 PRINT "SET UP RECORDER"
157 PAUSE 240
158 PRINT "START RECORDER"
159 PAUSE 120
160 SAVE "VIDEO GRAPHITY"
161 PRINT "DRAWING SAVED"
162 STOP
199 CLS
200 FOR X=1 TO 63
201 FOR Y=1 TO 42
202 IF F(X,Y)=1 THEN PLOT X,Y
203 NEXT Y
204 NEXT X
205 GOTO 13

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.