0 REM GARBAGE GOBBLER CORE PROGRAM BY TIM HARTNELL MOVING GRAPHIC SCREENS AND INSTRUCTIONS BY TONY WILLING
2 PRINT AT 2,7;"GARBAGE GOBBLER",,,,,"USE THE ARROW KEYS (5,6,7,8) TO MOVE AROUND AND EAT AS MUCH GARBAGE AS YOU CAN"
3 FOR S=1 TO 30
4 PRINT AT 2,S;"%G"
5 PRINT AT 2,S-1;"."
6 PRINT AT 11,8;"YOU ARE THE %G"
7 PRINT AT 11,8;"%Y%O%U% %A%R%E% %T%H%E% %G"
8 NEXT S
9 RAND
10 PRINT AT 15,0;"HOW MUCH GARBAGE DO YOU WANT?"
11 PRINT AT 18,4;"(40,60, OR 80 PIECES?)"
12 INPUT BB
13 CLS
14 IF BB=40 OR BB=60 OR BB=80 THEN GOTO 16
15 IF BB<>40 OR BB<>60 OR BB<>80 THEN GOTO 2
16 PAUSE 50
17 FAST
18 FOR A=1 TO BB
20 PRINT AT INT (RND*21),INT (RND*31);CHR$ (INT (RND*11)+128)
30 NEXT A
35 SLOW
37 PAUSE 200
40 LET A=0
50 LET X=INT (RND*31)
60 LET Y=INT (RND*21)
70 LET Q=INT (RND*110)+30
71 PRINT AT 0,18;"TIME: ";Q
75 FOR T=Q TO 0 STEP -1
80 LET X1=X
90 LET Y1=Y
100 LET X=X+(INKEY$="8" AND X<30)-(INKEY$="5" AND X>0)
110 LET Y=Y+(INKEY$="6" AND Y<20)-(INKEY$="7" AND Y>0)
120 PRINT AT Y,X;
130 IF PEEK (PEEK 16398+256*PEEK 16399)>=128 AND PEEK (PEEK 16398+256*PEEK 16399)<=138 THEN LET A=A+1
140 PRINT AT Y1,X1;"." AND (X<>X1 OR Y<>Y1);AT Y,X;"%G"
150 NEXT T
160 PRINT AT 20,0;"YOU COLLECTED ";A
165 LET TT=(Q/A)
166 LET V=1000-(INT (TT*100))
167 IF BB=40 THEN LET V=V*1.3
168 IF BB=60 THEN LET V=V
169 IF BB=80 THEN LET V=V*.92
170 PRINT AT 21,14;"SCORE: ";V
180 PAUSE 400
190 CLS
200 PRINT AT 15,2;"DO YOU WANT TO PLAY AGAIN?"
205 PRINT AT 18,2;"ENTER 1 FOR YES, 0 FOR NO"
210 INPUT HH
220 IF HH=1 THEN CLS
222 IF HH=1 THEN PAUSE 200
224 IF HH=1 THEN GOTO 10
230 IF HH=0 THEN CLS
233 PRINT AT 8,10;"THANK YOU"
237 PRINT AT 14,1;"% \ .% \.'\@@\:'\:.\.:\,,\!!\;;\'.\: \. \ :\ .\ '\;;\!!\@@\!!\,,\:'\:.\.:\ .\'.\.'\'.\;;"
242 FOR W=0 TO 30
243 PRINT AT 14,W;"%G"
244 PRINT AT 14,W-1;"."
248 NEXT W
249 FOR O=14 TO 8 STEP -1
250 PRINT AT O,30;"%G"
252 PRINT AT O,30;"."
254 NEXT O
255 FOR O=30 TO 0 STEP -1
257 PRINT AT 8,O;"%G"
259 PRINT AT 8,O;"."
261 NEXT O
262 FOR O=8 TO 14
263 PRINT AT O,0;"%G"
264 PRINT AT O,0;"."
266 NEXT O
268 PRINT AT 14,0;"."
269 PRINT AT 11,10;"%C%O%M%E% %A%G%A%I%N"
270 FOR Z=1 TO 125
272 NEXT Z
275 CLS
280 STOP
300 STOP
310 CLEAR
320 SAVE "1019%7"
330 RUN
