Source Code
10 REM PROGRAM-LUNAR LAND
20 BORDER 3: PAPER 6: INK 9: CLS
30 POKE 23658,8
40 PRINT "DO YOU DESIRE INSTRUCTIONS? TYPE Y FOR YES, N FOR NO ."
50 INPUT Z$
60 IF Z$="N" THEN GO TO 190
70 IF Z$<>"N" THEN GO TO 80
80 REM INSTRUCTION BLOCK
90 PRINT '"WHILE FLYING ON A LOW ORBIT MAPPING MISSION OF THE MOON,YOUR"
100 PRINT "CRAFT HAS HIT A FLYING WOMBAT! (AN AVIAN MAMMAL NATIVE TO THE AREA).": PRINT
110 PRINT "YOU ARE SAFE INSIDE YOUR EJECTEDSURVIVAL CAPSULE WHEN YOU"
120 PRINT "DISCOVER THAT YOUR AUTOMATIC DESCENT COMPUTER IS JAMMED FULL OF WOMBAT FEATHERS & HAS FAILED.": PRINT
130 PRINT "YOUR MAIN THRUST UNIT IS ERRATIC& FALTERING BUT IT MAY GET YOU DOWN SAFELY YET.": PRINT
140 PRINT "TO SAVE THE CAPSULE YOU MUST LAND AT LESS THAN 2 FT/SEC.": PRINT
150 PRINT "TO SURVIVE YOU MUST LAND AT LESSTHAN 5 FT/SEC.": PRINT
160 PRINT "THE CAPSULE INSTRUMENTATION IS FUNCTIONING AND WILL TELL YOU WHERE YOU ARE.": PRINT
170 PRINT "REMEMBER, GRAVITY WILL ADD 5 FT/SEC. TO YOUR DESCENT.": PRINT
180 PRINT '"GOOD LUCK AND HAPPY LANDINGS"
190 REM L=LIMIT OF BURN
200 LET L=RND*10+25
210 PRINT
220 PRINT "YOUR ENGINES ARE CAPABLE OF A MAXIMUM BURN OF ";L;"FT/SEC.": PRINT
230 REM INITIALIZE DATA; T=TIME,H=HEIGHT,V=VELOCITY,F=FUEL LEFT
240 LET T=1
250 LET V=(RND*75)-75
260 LET H=(RND*300)+200
270 LET F=120
280 PRINT
290 FLASH 1: PRINT " MANUAL DESCENT MODE ENGAGED ": FLASH 0
300 PRINT
310 PRINT "TIME ALT. VELOCITY FUEL "
320 PRINT "SEC. (FEET) (FT/SEC) LEFT"
330 PRINT " ";TAB 1;T;TAB 5;H;TAB 16;V;TAB 28;F; : PRINT '
340 INPUT B
350 IF B>L THEN LET B=L
360 REM L=LIMIT OF BURN
370 IF F<=0 THEN LET B=0
380 IF B+100<=100 THEN LET B=0
390 LET F=F-B
400 REM B=BURN
410 LET T=T+1
420 LET V=(V-5)+B
430 LET H=H+V
440 LET E=RND*12
450 IF E<9 OR E>6 THEN GO SUB 700
460 REM VARIABLE "E" DETERMINES THRUST FAILURE
470 IF F<=0 THEN GO TO 550
480 IF H<=0 THEN IF V+100<=95 THEN GO TO 610
490 IF H<=0 THEN IF V+100<=98 THEN GO TO 580
500 PAUSE 60: PRINT '''''''': IF H>0 THEN GO TO 310
510 PRINT " YOU HAVE LANDED SAFELY": PRINT '''': FLASH 1: PRINT " CONGRATULATIONS! ": FLASH 0: PRINT ''''
520 PRINT "YOUR VELOCITY AT TOUCHDOWN WAS ";V;" FT/SEC."
530 PRINT "WITH ";F;" UNITS OF FUEL REMAINING"
540 GO TO 640
550 FLASH 1: PRINT "!!!OUT OF FUEL!!!": FLASH 0
560 IF H>0 THEN GO TO 330
570 GO TO 610
580 PRINT "YOU HAVE MADE A CONTROLLED CRASH AND YOU ARE ALIVE!"
590 PRINT " HOWEVER THE LANDER IS DAMAGED AND YOU ARE STRANDED!": PRINT '''
600 GO TO 520
610 FLASH 1: PAUSE 3: FLASH 0: PRINT "CRUNCH! YOU HAVE JUST BECOME THEMOON'S NEWEST CRATER!"
620 PRINT "YOUR FLIGHT PAY WILL BE FORWARDED TO YOUR WIDOW.": PRINT
630 GO TO 520
640 PRINT
650 PRINT "LIKE TO TRY AGAIN,ACE? (Y/N) "
660 INPUT Z$
670 IF Z$="Y" THEN GO TO 190
680 IF Z$<>"Y" THEN STOP
690 REM DERIVE LEVEL OF THRUST FAILURE
700 LET L=L-(RND*10)+1
710 IF L+100<=100 THEN GO TO 760
720 PRINT
730 FLASH 1: PRINT TAB 8;"DETERIORATION",: FLASH 0: PRINT " IN MAIN THRUST UNIT": PRINT
740 PRINT "YOUR MAX. BURN IS NOW",L;"FT/SEC.": PRINT
750 RETURN
760 PRINT : PRINT " YOUR THRUST UNITS HAVE ": FLASH 1: PRINT TAB 8;"FAILED COMPLETELY ": FLASH 0: PRINT
770 LET L=0
780 RETURN
790 SAVE "LUNAR LAND" LINE 0
