Psychic

Gallery

Source Code

    5 CLS 
   10 REM "PSYCHIC"
   20 REM "RICHARD W. MCDANIEL"
   30 REM "JANUARY 1,1983"
   40 DIM R$(9,3)
   50 FOR A=1 TO 9
   60 FOR B=1 TO 3
   70 LET R$(A,B)=CHR$ (61+A*3+B)
   80 NEXT B
   90 NEXT A
  100 LET R$(9,3)=" "
  110 FOR I=1 TO 30
  120 LET A=INT (RND*9)+1
  130 LET B=INT (RND*3)+1
  140 LET T$=R$(A,B)
  150 LET R$(A,B)=R$(5,2)
  160 LET R$(5,2)=T$
  170 NEXT I
  180 FOR I=1 TO 3
  190 PRINT TAB 4;"COL.1";TAB 13;"COL.2";TAB 22;"COL.3",,
  200 FOR A=1 TO 9
  210 PRINT TAB 6;
  220 FOR B=1 TO 3
  230 PRINT R$(A,B);"        ";
  240 NEXT B
  250 PRINT 
  260 NEXT A
  270 PRINT "ENTER THE COLUMN CONTAINING YOUR LETTER."
  280 INPUT C
  290 IF C<1 OR C>3 THEN GO TO 280
  300 IF I=3 THEN GO TO 470
  310 FOR A=1 TO 9
  320 LET T$=R$(A,2)
  330 LET R$(A,2)=R$(A,C)
  340 LET R$(A,C)=T$
  350 NEXT A
  360 LET T$=""
  370 FOR A=1 TO 3
  380 FOR B=1 TO 9
  390 LET T$=T$+R$(B,A)
  400 NEXT B
  410 NEXT A
  420 FOR A=1 TO 9
  430 FOR B=1 TO 3
  440 LET R$(A,B)=T$(A*3+B-3)
  450 NEXT B
  460 NEXT A
  470 CLS 
  480 NEXT I
  490 PRINT ,,"I MYSTICALLY PERCEIVE YOUR","LETTER TO BE ";R$(5,C);"."
  500 PRINT ,,"WOULD YOU LIKE TO TEST MY MAGIC ABILITIES AGAIN?(Y OR N)"
  510 INPUT T$
  520 CLS 
  530 IF (T$+" ")(1)="Y" THEN GO TO 180: STOP 
  540 STOP 
 9998 SAVE "PSYCHIC" LINE 5