Minibreakout

Author(s): Dan Tandberg
Publication: Timex Sinclair User
Pub Details: Timex Sinclair User n7 (Volume 1, Issue 7)
Date: December 1983
Pages: 32
Man knocking a ball through a brick wall
Man knocking a ball through a brick wall

MINIBREAKOUT was written in an attempt to produce a reasonably good “breakout” type arcade game without resorting to machine language programming. Type in the program exactly as shown in the listing. Be sure to use the correct graphics characters, since the CODEs of these are used to produce the correct “bounce.” Proofread and EDIT out any errors, then SAVE to tape.

To play MINIBREAKOUT, RUN the program and you’ll see a playing screen filled with two kinds of “bricks”, a paddle (which you can move with the “8” and “Y” keys), and a ball. Move the paddle right or left to keep the ball in play. Each time you knock out a brick, you’ll receive 10 points. When you finally “break out” to the top of the screen, you win. Whenever you miss the ball, however, the paddle moves up closer to the bricks and the game gets a bit harder. Three misses and you lose.

Submitted by Dr. Dan Tandberg of Albuquerque, New Mexico.

  10 REM "MINIBREAKOUT"
20 LET Z=NOT PI
30 LET P=NOT Z
40 LET T=P+P
50 PRINT "▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒"
60 PRINT
70 FOR R=P TO PI
80 PRINT " ▓ ▓ ▓ ▓ ▓ ▓ ▓ ▓ ▓ ▓ ▓ ▓ ▓ ▓"
90 PRINT " ▒ ▒ ▒ ▒ ▒ ▒ ▒ ▒ ▒ ▒ ▒ ▒ ▒ ▒ ▒"
100 NEXT R
110 LET C=CODE "?"
120 PRINT AT C,Z;"▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒"
130 FOR R=Z TO C
140 PRINT AT R,Z;"█";AT R,C+C;"█"
150 NEXT R
160 PRINT TAB PI*PI;"MINIBREAKOUT"
170 LET R=CODE "$"
180 LET S=Z
190 LET Y=CODE "£"
200 LET X=8+T*INT (RND*8)
210 LET V=-P
220 LET H=P-T*(RND>P/T)
230 LET XX=X
240 LET XY=Y
250 LET XC=C
260 LET K$=INKEY$
270 LET C=C+T*(K$="8")*(C<27)-T*(K$="Y")*(C>P)
280 PRINT AT R,XC;" ";AT R,C;"▀▀▀";AT Y+V,X+H;
290 LET A=PEEK (PEEK 16398+256*PEEK 16399)
300 IF A>Z AND A<=128 THEN GOSUB 390
310 LET X=X+H
320 LET Y=Y+V
330 IF A>128 THEN GOSUB 360
340 PRINT AT XY,XX;" ";AT Y,X;"O"
350 GOTO 230
360 LET V=-V
370 LET S=S+10
380 RETURN
390 IF Y=P THEN GOTO 470
400 IF A<>128 OR (A=128 AND (Y=R-P OR Y=14)) THEN LET V=-V
410 IF A=128 THEN LET H=-H
420 IF Y<>14 THEN RETURN
430 PRINT AT R,C;" "
440 LET R=R-P
450 IF R=10 THEN GOTO 470
460 RETURN
470 FOR R=P TO PI
480 PRINT AT Y,X;"▣";AT Y,X;"O"
490 NEXT R
500 IF Y=P THEN PRINT AT T,T*PI;"*****YOU WIN*****"
510 PRINT AT T+T,T+PI;"GAME OVER SCORE= ";S

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.