Asteroids

Source Code

    1 BORDER 1: PAPER 1: CLS : INK 7: PRINT AT 0,8; FLASH 1;"ASTEROIDS AHEAD!": PAUSE 100: PRINT FLASH 0;''" Steer your spacecraft through   the swarm of asteroids"''"Press 5 for Left or 8 for Right."''"Press 0 to activate your craft'sEnergy Screen to destroy        asteroids you cannot avoid"''"But BEWARE - the Screen has onlya short range and you have only 5 energy units left"''" Your craft will disintegrate    after 5 hits (wings=1,body=2)"''"   HOW LONG CAN YOU SURVIVE?": GO SUB 9000: PRINT '"        Press 8 to start": PAUSE 0: LET b=0
    4 LET e=0
   10 INK 0: CLS : LET t=0: LET p=5: LET l=15: LET l1=l: LET f=6
   50 POKE 23692,255: LET l=l+(INKEY$="8" AND l<29)-(INKEY$="5" AND l>0): IF INKEY$="0" THEN LET f=f-1: IF f>0 THEN PRINT AT 8,l; INK 6;"\p\q\r": GO TO 64
   62 IF INKEY$="0" THEN LET f=f-1: IF f>0 THEN PRINT AT 8,l; INK 6;"\p\q\r"
   64 IF ATTR (8,l+2)=15 OR ATTR (8,l)=15 THEN LET p=p-1
   66 IF ATTR (8,l+1)=15 THEN LET p=p-2
   67 IF p<1 THEN GO TO 400
  100 PRINT AT 7,l1;"   ";AT 21,31;"": PRINT : PRINT AT 7,l; INK 6;"\s"; INVERSE 1;p; INVERSE 0;"\t": LET t=t+1: LET l1=l: PRINT AT 21,RND*31; INK 7;CHR$ (RND*11+144);AT 21,RND*31;CHR$ (RND*11+144): GO TO 50
  400 FOR n=1 TO 3: PRINT AT 6,l1;"   ";AT 7,l1; INK 2;" \m ";AT 8,l1;"   ": PAUSE 2: PRINT AT 6,l1; INK 6;"\o\q\u";AT 7,l1;"\n \n";AT 8,l1;"\p\q\r": PAUSE 2: NEXT n: FOR n=6 TO 8: PRINT AT n,l1;"    ": NEXT n
  402 CLS : IF b<t-13 THEN LET b=t-13
  403 INK 7: IF e<b THEN LET e=b: PRINT AT 6,0;"You have beaten the best ever   score. Enter the HALL OF FAME"''"Press the two letters of your   initials": LET n$="": FOR n=1 TO 2: PAUSE 0: LET n$=n$+INKEY$+".": NEXT n: CLS 
  405 PRINT ;"   Score=";t-13,"Best Score=";b''"   Best ever Score=";: PRINT FLASH 1;e;" by ";n$''': FOR n=1 TO 150: NEXT n: PRINT FLASH 0;"   Press P to play again"''"         s to save"''"         f to finish": PAUSE 0: GO TO (5 AND INKEY$="p")+(430 AND INKEY$="s")+(450 AND INKEY$="f")
  430 SAVE "ASTEROIDS" LINE 1
  450 PRINT ''''"  Thank you for playing.  'Bye"
  460 GO TO 460
 9000 
 9020 RESTORE 9070: FOR m=1 TO 21
 9030 READ p$
 9040 FOR n=0 TO 7
 9050 READ a: POKE USR p$+n,a
 9060 NEXT n: NEXT m: RETURN 
 9065 BORDER 1: PAPER 1: CLS : INK 7: GO TO 2
 9070 DATA "a",62,33,255,129,129,65,37,26
 9080 DATA "b",112,148,138,65,129,65,37,26
 9090 DATA "c",0,0,24,36,36,56,0,0
 9100 DATA "d",0,0,48,40,48,32,0,0
 9110 DATA "e",0,24,40,40,16,0,0,0
 9120 DATA "f",112,136,136,68,40,48,0,0
 9130 DATA "g",0,0,0,56,44,16,0,0
 9140 DATA "h",0,0,30,18,34,84,232,0
 9150 DATA "i",94,177,130,228,34,65,66,60
 9160 DATA "j",0,62,65,66,34,17,14,0
 9170 DATA "k",96,144,144,116,10,49,65,126
 9180 DATA "l",62,65,242,9,247,126,144,88
 9190 DATA "m",145,82,16,7,244,8,74,127
 9200 DATA "n",100,24,198,0,222,0,24,102
 9210 DATA "o",0,4,34,18,1,68,50,0
 9220 DATA "p",9,50,68,1,18,34,4,0
 9230 DATA "q",0,8,170,42,73,65,137,137
 9240 DATA "r",144,76,34,128,72,68,32,0
 9250 DATA "s",0,3,15,15,120,200,255,56
 9260 DATA "t",0,192,240,240,30,19,255,28
 9270 DATA "u",0,32,68,72,128,36,76,144
 9998 SAVE "Asteroids" LINE 1: BEEP .4,15
 9999 VERIFY ""