Gunner

Gallery

Source Code

   1 REM ***GUNNER***
   2 GOTO 500
   5 LET HS=0
   8 LET H=19
  10 DIM A$(1,6000)
  15 LET X=0
  20 FOR N=1 TO 65 STEP 2
  30 LET A$(1,N)=CHR$ (INT (RND*26)+166)
  40 NEXT N
  45 LET N=2
  50 LET Z=0
  55 LET S=0
  60 PRINT AT 0,0;"SCORE","HIGH-SCORE";AT 1,0;S,HS
  70 PRINT AT 3,0;A$(1,N TO N+31);AT 5,0;A$(1,N+33 TO N+65);AT 21,Z;" \.: ";AT 20,Z;" . "
  80 LET A$(1,N+65)=CHR$ (INT (RND*26)+166)
  90 IF INT (RND*40)=10 THEN LET A$(1,N+65)="\@@"
  95 IF A$(1,N+1)="\@@" THEN GOTO 350
 100 LET N=N+2
 105 IF X<>0 THEN GOTO 140
 110 IF INKEY$="8" AND Z<28 THEN LET Z=Z+1
 120 IF INKEY$="5" AND Z>1 THEN LET Z=Z-1
 130 IF INKEY$="7" THEN GOTO 140
 135 GOTO 70
 140 LET H=H-2
 150 PRINT AT H,Z+1;
 155 LET R=PEEK (PEEK 16398+256*PEEK 16399)
 156 PRINT "."
 160 PRINT AT H+2,Z+1;" "
 170 LET X=1
 180 IF R<>0 THEN GOTO 250
 190 IF H<3 THEN PRINT AT H,Z+1;" "
 200 IF H<3 THEN LET X=0
 210 GOTO 70
 250 IF R-165<0 THEN LET R=165
 255 LET S=S+(R-165)
 260 LET X=0
 270 PRINT AT 1,0;S
 280 IF H=3 THEN LET A$(1,N+(Z-1))=" "
 290 IF H=5 THEN LET A$(1,N+(32+Z))=" "
 300 LET H=19
 310 GOTO 70
 350 CLS 
 360 PRINT "SCORE","HIGH-SCORE"
 370 IF S>HS THEN LET HS=S
 380 PRINT S,HS
 390 PRINT 
 400 PRINT "THE ""\@@"" GOT AWAY."
 410 PRINT 
 420 PRINT "DO YOU WANT TO TRY AGAIN(Y/N)?"
 430 INPUT Z$
 440 IF Z$<>"YES" AND Z$<>"Y" AND Z$<>"NO" AND Z$<>"N" THEN GOTO 430
 450 CLS 
 460 IF Z$="YES" OR Z$="Y" THEN GOTO 8
 470 STOP 
 500 PRINT TAB 12;"GUNNER"
 510 PRINT TAB 12;"------"
 520 PRINT 
 530 PRINT "THE POINT OF THIS GAME IS TO GET AS MANY POINTS AS POSSIBLE BY SHOOTING THE LETTERS; BUT YOU MUST NOT LET THE ""\@@"" GET AWAY."
 540 PRINT "THE FURTHER THE LETTER IS IN THE ALPHABET THE MORE ITS WORTH. FOR EXAMPLE ""%Z"" IS WORTH MORE THAN ""%A"". TO MOVE THE GUN YOU USE THE"
 550 PRINT "CURSOR KEYS AND THE UPWARD POINTING CURSOR KEY TO FIRE.",,,"GOOD LUCK"
 560 PRINT 
 570 PRINT "HIT ANY KEY TO CONTINUE."
 580 IF INKEY$="" THEN GOTO 580
 590 CLS 
 600 GOTO 5
 700 SAVE "1006%7"
 710 RUN