Headline

    1 PRINT "This is a ""banner"" program for  the 2040 printer.  It makes niceblocky letters.  However, it    will only work with the letters ""a"" thru ""u""." 
    2 PRINT : PRINT "Press any key to begin......"
    3 IF INKEY$="" THEN GO TO 3
    4 CLS 
  150 DIM a(8): LET a(1)=128: LET a(2)=64: LET a(3)=32: LET a(4)=16: LET a(5)=8: LET a(6)=4: LET a(7)=2: LET a(8)=1
  160 INPUT "Enter message > ";a$
  170 FOR s=1 TO LEN a$: IF a$(s)=" " THEN GO TO 190
  180 IF CODE a$(s)<65 OR CODE a$(s)<97 AND CODE a$(s)>85 OR CODE a$(s)>117 AND CODE a$(s)<144 OR CODE a$(s)>164 THEN PRINT a$(s);" isn't a user graphic character": BEEP 1,-20: STOP 
  190 NEXT s
  200 FOR p=1 TO LEN a$
  210 IF a$(p)=" " THEN CLS : COPY : GO TO 490
  220 LET y=USR a$(p)
  230 DIM b$(8,8)
  240 FOR i=0 TO 7
  250 LET b$(i+1)="00000000"
  260 LET x=PEEK (y+i)
  270 FOR n=1 TO 8
  280 IF x>=a(n) THEN LET b$(i+1,n)="1": LET x=x-a(n)
  290 NEXT n
  300 NEXT i
  340 DIM e$(8,8)
  350 LET k=1
  360 FOR i=1 TO 8
  370 LET f$=""
  380 FOR n=8 TO 1 STEP -1
  390 LET f$=f$+b$(n,k): NEXT n
  400 LET e$(i)=f$
  410 LET k=k+1: NEXT i
  450 FOR i=1 TO 8
  460 LET c$="": FOR n=1 TO 8
  470 LET c$=c$+("    " AND e$(i,n)="0")+("████" AND e$(i,n)="1")
  480 NEXT n: LPRINT c$'c$'c$: NEXT i
  490 NEXT p
  500 BEEP 1,20: STOP