Patterns

   10 GO SUB 280
   20 FOR B=144 TO 159 STEP 4
   30 FOR I=NOT PI TO 7
   40 POKE USR CHR$ (B)+I,FN C(A$(I+N1))
   50 POKE USR CHR$ (B+N1)+I,FN C(A$(I+N1,9 TO ))
   60 POKE USR CHR$ (B+2)+I,FN C(A$(I+9))
   70 POKE USR CHR$ (B+3)+I,FN C(A$(I+9,9 TO ))
   80 NEXT I
   90 FOR I=N1 TO 16: FOR J=N1 TO 16
  100 LET B$(I,J)=A$(J,17-I)
  110 NEXT J: LET A$(I)=B$(I)
  120 NEXT I: NEXT B: CLS 
  130 FOR I=R TO 20 STEP 2: BEEP .075,I: NEXT I
  140 FOR I=I TO R STEP -2: BEEP .075,I: NEXT I
  150 PRINT " USE 5,6,7,& 8 TO MOVE PATTERN"
  160 PRINT AT R,C;"\a\b";TAB C;"\c\d"
  170 LET T$=INKEY$
  180 LET B=(10 AND T$="5")+(20 AND T$="6")+(30 AND T$="7")+(40 AND T$="8")
  190 IF NOT B THEN GO TO 170
  200 GO SUB 230+B
  210 PRINT AT R,C;CHR$ CH;CHR$ (CH+N1)
  220 PRINT AT R+N1,C;CHR$ (CH+2);CHR$ (CH+3)
  230 GO TO 170
  240 LET CH=148: LET C=C-2*(C>2): RETURN 
  250 LET CH=152: LET R=R+2*(R<19): RETURN 
  260 LET CH=144: LET R=R-2*(R>2): RETURN 
  270 LET CH=156: LET C=C+2*(C<29): RETURN 
  280 CLS : PRINT "PLEASE FILL THIS 16X16 SQUARE.  USE ""1"" TO PAINT AND ANY OTHER  KEY FOR A BLANK"
  290 GO SUB 360
  300 FOR I=N1 TO 16
  310 FOR J=N1 TO 16: LET R=5+I: LET C=7+J
  320 PRINT AT R,C; FLASH N1; BRIGHT N1; OVER N1;" ": PAUSE 0: LET A$(I,J)=INKEY$
  330 PRINT AT R,C; FLASH 0; BRIGHT N1; OVER N1;" "
  340 IF A$(I,J)="1" THEN PRINT AT R,C;"█"
  350 NEXT J: NEXT I: LET R=10: LET C=15: RETURN 
  360 PRINT AT 6,8;
  370 LET N1=1: DIM A$(16,16): DIM B$(16,16)
  380 DEF FN C(L$)=(128 AND L$(N1)="1")+(64 AND L$(2)="1")+(32 AND L$(3)="1")+(16 AND L$(4)="1")+(8 AND L$(5)="1")+(4 AND L$(6)="1")+(2 AND L$(7)="1")+(1 AND L$(8)="1")
  390 FOR I=NOT PI TO 128 STEP 8
  400 PLOT 64,128-I: DRAW 128,0
  410 PLOT 64+I,128: DRAW 0,-128
  420 IF I<128 THEN PRINT TAB 8; BRIGHT N1; OVER N1;"                "
  430 NEXT I: RETURN 
  440 SAVE "PATTERNS" LINE PI