Reaction

Source Code

   1 PRINT ,,"%I%N%S%T%R%U%C%T%I%O%N%S?"
   2 LET A$=INKEY$
   3 IF A$="" THEN GOTO 2
   4 CLS 
   5 IF A$="N" THEN GOTO 10
   6 IF A$="Y" THEN GOTO 2000
   7 GOTO 1
   9 FAST 
  10 PRINT AT 10,0;"THE GAME NOW BEGINS AT LEVEL 5  PRESS ANY KEY BUT <BREAK> TO    BEGIN."
  15 SLOW 
  20 LET G$=INKEY$
  21 IF G$="" THEN GOTO 20
  22 FAST 
  25 LET G=5
  30 LET H=10-G
  40 LET TT=0
  50 RAND 
  60 FOR Q=1 TO 5
  62 LET B$=STR$ (INT (RND*100000))
  64 IF LEN B$=5 THEN GOTO 70
  66 GOTO 62
  70 LET A$=STR$ Q+"-"+B$+"*"
  90 FAST 
 100 RAND 
 120 LET E=8*(INT (RND*5)+1)
 150 LET S=0
 160 FOR N=1 TO 10
 170 CLS 
 200 FOR K=1 TO LEN A$
 210 LET C=CODE A$(K)
 220 IF C<128 THEN GOTO 250
 230 LET M$=CHR$ (C-128)
 240 LET C=0
 250 FOR L=0 TO 7
 260 LET P=PEEK (7680+C*8+L)
 270 LET V=128
 280 FOR J=0 TO 7
 290 IF P<V THEN GOTO 320
 300 PLOT 8*(K-1)+J,E-L
 310 LET P=P-V
 320 LET V=V/2
 330 NEXT J
 340 NEXT L
 350 NEXT K
 360 SLOW 
 370 FOR F=1 TO H*3
 380 NEXT F
 390 CLS 
 400 FOR F=1 TO H
 420 LET C$=INKEY$
 430 IF C$<>"" THEN GOTO 600
 500 NEXT F
 505 PRINT AT 11,12;"%S%T%O%P";AT 11,12;"STOP";AT 11,12;"%S%T%O%P";AT 11,12;"STOP";AT 11,12;"    ";AT 11,12;"\@@\@@\@@\@@"
 510 NEXT Q
 520 GOTO 1000
 600 IF A$(Q+2)<>C$ THEN GOTO 505
 610 LET TT=TT+1
 620 GOTO 505
1000 CLS 
1010 PRINT AT 10,0;"YOU SCORED ";TT;" OF 5 CORRECT."
1020 FOR N=1 TO 150
1030 NEXT N
1040 FAST 
1050 IF TT<5 THEN GOTO 3000
1060 IF TT=5 THEN GOTO 4000
1999 STOP 
2000 FAST 
2010 CLS 
2020 PRINT AT 1,10;"\:'\''\''\''\''\''\''\''\''\':";AT 2,10;"\: REACTION\ :";AT 3,10;"\:.\..\..\..\..\..\..\..\..\.:"
2030 PRINT ,,"   THIS IS A GAME TO TEST YOUR  MENTAL AND PHYSICAL REFLEXES.  ",,,"   IT WILL START AT THE MEDIUM  DIFFICULTY LEVEL."
2040 PRINT "   IN A RANDOM COLUMN, A NUMBER WILL APPEAR, FOLLOWED BY A 5    DIGIT NUMBER."
2050 PRINT "   5 OF THESE 5 DIGIT NUMBERS   IN ALL WILL APPEAR. YOU ARE     CHALLENGED TO INPUT FIRST THE   FIRST DIGIT OF THE FIRST NUMBER,THEN THE SECOND DIGIT OF THE    SECOND NUMBER AND SO ON."
2060 GOSUB 9000
2070 PRINT ,,,,"   IF YOU GET ALL 5 ENTRIES     CORRECT, THE GAME WILL THEN     CYCLE TO THE NEXT HIGHEST DIFF- ICULTY LEVEL."
2080 PRINT "   IF YOU MISS A NUMBER, THE    GAME WILL THEN CYCLE TO THE NEXTLOWEST DIFFICULTY LEVEL."
2090 PRINT "   THERE ARE 9 LEVELS IN ALL    AND YOU START AT LEVEL 5."
2100 PRINT "   IF YOUR LEVEL REACHS 0 OR 10,THE GAME WILL BE OVER. IT IS    ENTIRELY POSSIBLE THAT YOU COULDBE PLAYING FOR A VERY LONG TIME BECAUSE LEVEL 1 IS RELATIVLY    EASY AND LEVEL 9 IS IMPOSSIBLE."
2110 GOSUB 9000
2120 PRINT ,,,,"   DEPENDING ON THE DIFFICULTY  LEVEL, THE AMOUNT OF TIME THE 5 DIGIT NUMBER IS DISPLAYED AND   THE AMOUNT OF TIME THAT YOU HAVEFOR YOUR REPLY, WILL INCREASE   OR DECREASE."
2130 PRINT "   ENTER YOUR REPLY IMMEDIATLY  %A%F%T%E%R THE 5 DIGIT NUMBER DIS-   APPEARS FROM THE SCREEN."
2140 PRINT "   WHEN THE WORD <STOP> BRIEFLY FLUTTERS ON THE SCREEN, THIS    MEANS THE GAME WILL NO LONGER   ACCEPT AN INPUTTED NUMBER AND   WILL CYCLE TO THE  NEXT 5 DIGIT NUMBER."
2150 PRINT "   THE NUMBER THAT APPEARS AT   THE LEFT OF THE 5 DIGIT NUMBER  REPRESENTS THE CURRENT CYCLE    YOU ARE AT."
2160 GOSUB 9000
2170 PRINT AT 10,3;"THE GAME WILL NOW BEGIN."
2180 GOSUB 9000
2190 PRINT AT 10,11;"%G%O%O%D% % %L%U%C%K"
2200 GOSUB 9000
2210 GOTO 9
3000 LET G=G-1
3010 IF G=0 THEN GOTO 3500
3020 CLS 
3030 PRINT AT 10,0;"YOU DROPPED A LEVEL FROM       ",G+1;" TO ";G
3040 PRINT ,,"THE NEXT GAME IS READY TO BEGIN."
3050 GOSUB 9000
3060 GOTO 30
3500 FAST 
3510 CLS 
3520 PRINT AT 10,0;"NICE TRY - KEEP AT IT - YOU\ 'RE  BOUND TO IMPROVE."
3530 PRINT AT 21,0;"DO YOU WANT TO TRY AGAIN????????"
3540 SLOW 
3550 LET G$=INKEY$
3560 IF G$="" THEN GOTO 3550
3570 IF G$="N" THEN GOTO 3700
3580 IF G$="Y" THEN GOTO 3800
3700 CLS 
3710 PRINT AT 10,0;"GOODBYE, THANKS FOR PLAYING."
3720 STOP 
3800 FAST 
3810 CLS 
3820 SLOW 
3830 RUN 
4000 LET G=G+1
4010 IF G=10 THEN GOTO 4900
4020 CLS 
4030 PRINT AT 10,0;"YOU RAISED A LEVEL FROM       ",G-1;" TO ";G
4040 GOTO 3040
4500 FAST 
4510 CLS 
4520 PRINT AT 10,0;"CONGRATULATIONS, I DIDN\ 'T THINK ANYONE WOULD GET A PERFECT SCORE"
4530 GOTO 3530
8999 STOP 
9000 PRINT AT 21,0;"PRESS ENTER TO CONTINUE :::::::"
9010 SLOW 
9020 INPUT G$
9030 FAST 
9040 CLS 
9050 RETURN 
9998 SAVE "REACTIO%N"
9999 RUN