2068 Character Builder

Author(s): John (Basil) Wentworth
Publication: SyncWare News
Pub Details: SyncWare News v2 n3 (Volume 2, Issue 3)
Date: Jan-Feb 1985
Pages: 11

The TS2068 offers a very powerful feature in its capacity to build up user-defined characters. However, the procedure for building up those characters is a bit of a pain in the neck. This program will simplify that procedure for you.

First, a quick review of those user-defined characters. You probably already know that all of the characters printed by the TS2068 (and by the good old ZX81 and ZX80) are constructed on an 8 x 8 matrix. Each location of the matrix (these locations are called “pixels”) is assigned either a dark spot (ink colored, in the case of the 2068) or a space (paper colored). When they are displayed on the screen, these pixels are integrated by the eye into continuous lines. If you’re interested, you should be able to resolve them into their pixels by using a magnifying glass.

The TS2068 allows you to assign ink or paper colors to the pixels of your choosing, so you can build up (and PRINT or LPRINT) any character that you can define by the 64 pixels available.

The character you have defined is then assigned to a key – any key you want, between A and U, inclusive. Once you have made this assignment, the GRAPHICS output of the key you have chosen will give you the character you have built up. Apparently forever, as time is measured in computer terms. Cutting off the power will lose the character, of course, and it can be overwritten with a new character, but it will survive such ordinarily fatal procedures as NEW and CLEAR. And SAVE and LOAD.

How It Works

The program given is a rudimentary turtle. The display defines the matrix within which you will work, giving a co-ordinate grid for the pixel positions. The turtle can be moved by the customary shifted 5-8 keys, and a cursor shows you where he is standing at any moment. If you press “1” the turtle lays down an ink-colored tile where he is standing; if you press “0”, he picks up any tile that may be lying there. When he has finished, you are left with a mosaic that represents the character you have built.

Sometimes it takes a little imagination to visualize how the character will look when it is reduced to operating size, but you’ll just have to do the best you can. You can always change the character if it doesn’t come up to your expectations.

If you are satisfied with the character, press “STOP”, and the computer will ask you to which key you want to assign it. INPUT a letter between A and U, inclusive, and PRESTO! you’ve done the job. Well, not exactly Presto – sort of more of a Larghetto, if you’re familiar with the terminology of music. The process actually takes a few patience-trying seconds. For the sake of those who are as fidgety as I am, I included a little reminder from the computer that it hasn’t gone to sleep, plus an audible TA-DA! when the job is done.

  10>LET A$="                                "
15 LET A$=A$+A$
20 LET SC=0
30 FOR F=1 TO 8
40 PRINT AT F-1,8;F;AT 8,F-1;F
50 NEXT F
55 PRINT AT 0,0;"↑"
60 IF INKEY$="" THEN GO TO 60
70 LET P=PEEK 23560
80 LET SC=SC+(P=9)+8*(P=10)-(P=8)-8*(P=11)
90 IF SC<0 THEN LET SC=0
100 IF SC>63 THEN LET SC=63
110 LET V=INT (SC/8)
120 LET H=SC-8*V
130 LET Z$="↑"
140 PAUSE 5: PRINT AT V,H;Z$
150 PAUSE 5: PRINT AT V,H;A$(SC+1)
160 IF INKEY$="1" THEN LET A$(SC+1)="▒"
170 IF INKEY$="0" THEN LET A$(SC+1)=" "
180 IF INKEY$="" THEN GO TO 140
190 IF P<>226 THEN GO TO 60
200 REM GO TO 60
210 PRINT AT 12,1;"WHAT KEY DO YOU WANT TO CARRY THIS CHR$ (A-U)?"
220 INPUT B$
250 PRINT ,,,,"I'm thinking, I'm thinking!"
1000 FOR G=0 TO 7
1010 LET B=0
1020 FOR H=1 TO 8
1030 LET Z$=A$(8*G+9-H)
1040 LET N=(Z$="▒")
1050 LET B=B+N*2↑(H-1)
1060 NEXT H
1070 POKE USR B$+G,B
1080 NEXT G
2000 BEEP .25,12
2010 BEEP 1,12
4999 STOP
5000 SAVE "FIG" LINE 1

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.