8K Updates

In the first issues of SYNC the programs were all for the 4K ROM. When the 8K ROM became available, we tried wherever possible to provide listings for both ROMs. Since we have had requests from readers for updated versions of some of the programs we published earlier, we will include these from time to time.

Forest Treasure

Paul Frahm

In Forest Treasure a treasure (shown as a blank space) is hidden in the forest. You (shown as a pound sign) are searching for it. Enchanted walls which are invisible may throw you off into a different direction. Monsters (shown as M) may pounce on you, steal the treasure, or kill you. Then you lose. However, they can even duplicate themselves. If you get the treasure, you win. You control your movements by U, D, R, L and then press ENTER. Entering S will exit you from the program.

 10 FOR I=1 TO 20
 20 FOR J=1 TO 32
 30 PRINT "▒";
 40 NEXT J
 50 PRINT
 60 NEXT I
 70 DIM B(75)
 80 PRINT AT 20,6;"FOREST TREASURE"
 90 LET E=INT (RND*20)
100 LET F=INT (RND*32)
110 LET T=INT (RND*659)
120 POKE PEEK 16396+256*PEEK 16397+T,0
130 FOR I=1 TO 75
140 LET B(I)=INT (RND*659)
150 NEXT I
160 LET M=INT (RND*659)
170 IF M/33=INT (M/33) THEN GOTO 160
180 POKE PEEK 16396+256*PEEK 16397+M,50
190 IF M=T THEN GOTO 490
200 LET H=F+33*(E-1)
210 IF H/33=INT (H/33) THEN GOTO 380
220 LET N=PEEK 16396+256*PEEK 16397+H
230 IF PEEK N=50 THEN GOTO 460
240 POKE N,12
250 IF H=T THEN GOTO 430
260 INPUT A$
270 PRINT AT 20,1;"                              "
280 IF A$="S" THEN STOP
290 POKE N,22
300 FOR I=1 TO 75
310 IF B(I)=H THEN GOTO 380
320 NEXT I
330 IF A$="R" AND F<32 THEN LET F=F+1
340 IF A$="L" AND F>1 THEN LET F=F-1
350 IF A$="D" AND E<20 THEN LET E=E+1
360 IF A$="U" AND E>1 THEN LET E=E-1
370 GOTO 160
380 LET F=F+(INT (RND*9)-5)
390 LET E=E+(INT (RND*9)-5)
400 POKE PEEK 16396+256*PEEK 16397+B(I),24
410 PRINT AT 20,1;"[inv OOPS, YOU RAN INTO A WALL]"
420 GOTO 160
430 POKE PEEK 16396+256*PEEK 16397+T,141
440 PRINT AT 20,1;"[inv YOU HAVE TAKEN THE TREASURE]"
450 GOTO 510
460 POKE PEEK 16396+256*PEEK 16397+H,178
470 PRINT AT 20,1;"[inv THE MONSTER HAS KILLED YOU]"
480 GOTO 510
490 PRINT AT 20,1;"[inv THE MONSTER HAS STOLEN THE]"
500 PRINT AT 21,1;"[inv TREASURE]";
510 PRINT "ANOTHER GAME?"
520 INPUT B$
530 CLS
540 IF CODE B$=62 THEN RUN
550 STOP

Graphics notes:

30: A
410: inverse: OOPS, YOU RAN INTO A WALL
440: inverse: YOU HAVE TAKEN THE TREASURE
470: inverse: THE MONSTER HAS KILLED YOU
490: inverse: THE MONSTER HAS STOLEN THE
500: inverse: TREASURE

---

Defuse

Raymond Fowkes

You are in a one million room building which has a bomb hidden somewhere inside. Fortunately, you have a bomb detector that registers a signal that get stronger as you get closer.

Enter the listing and press RUN and ENTER. The type in the coordinates of the room you want to test (length, width, height from 0 to 99) and proceed according to the signal you receive. You have 200 seconds before the building blows up.

To edit in 1K you must LIST the line, press CLEAR and ENTER and then EDIT. Do your editing and hit ENTER.

 10 RAND
 20 LET A=INT (RND*100)
 30 LET B=INT (RND*100)
 40 LET C=INT (RND*100)
100 PRINT AT 19,0;"L   W   H      SECONDS  SIGNAL"
110 PRINT
120 FOR S=10 TO 200 STEP 10
130 INPUT D
140 PRINT D;
160 INPUT E
180 PRINT TAB 4;E;
190 INPUT F
200 PRINT TAB 8;F,S;TAB 23;1E4-(ABS (A-D)+ABS (B-E)+ABS (C-F))*29
210 SCROLL
215 SCROLL
220 IF A=D AND B=E AND C=F THEN GOTO 290
230 NEXT S
270 PRINT "*BOOOMMM* IT WAS AT ";A;",";B;",";C
280 GOTO 300
290 PRINT "BOMB DEFUSED"
300 PAUSE 4E4
310 CLS
320 RUN

L   W   H      SECONDS  SIGNAL
40  0   0      10       6636
20  40  0      20       8376
20  60  0      30       8434
20  52  0      40       8666
20  50  0      50       8666
20  51  16     60       9159
20  51  30     70       9565
20  51  46     80       9971
20  51  45     90       10000
BOMB DEFUSED

---

Mastermind

Raymond Fowkes

In Mastermind the computer selects from six colors a code of four letters. You must discovered this code in no more than 9 guesses. Input your guess as a series of four letters (representing the colors ROYGBW). The computer will match your letters one by one with the selected code. A black peg shows that your guess was right in color and position; a white peg, that your guess was right in color, but wrong in position. Continue until you guess the code or run out of guesses.

 10 LET A=4
 20 DIM A$(A)
 30 DIM B$(A)
 40 FOR D=SGN A TO A
 50 LET A$(D)="ROYGBW"(VAL "RND*5+1")
 60 NEXT D
 70 PRINT "ROYGBW [inv        ]"
 80 FOR D=19 TO INT PI STEP -2
 90 LET B=NOT A
100 INPUT B$
110 PRINT AT D,9;B$
120 LET C$=A$
130 FOR E=SGN A TO A
140 IF B$(E)<>C$(E) THEN GOTO 190
150 PRINT AT D,B;"[inv  ]"
160 LET B=B+2
170 LET B$(E)="▒"
180 LET C$(E)="[inv  ]"
190 NEXT E
200 IF B=A+A THEN GOTO 310
210 FOR E=SGN A TO A
220 FOR F=SGN A TO A
230 IF C$(E)<>B$(F) THEN GOTO 280
240 PRINT AT D,B;"▒"
250 LET B=B+2
260 LET B$(F)="▒"
270 GOTO 290
280 NEXT F
290 NEXT E
300 NEXT D
310 PRINT AT NOT A,NOT A;"WRONG " AND D=SGN D;TAB A+A;" ";A$,
320 IF D<>SGN D THEN PRINT INT VAL "11-D/2";" TRIES"

70: inverse space (8).
150: inverse space.
170: A.
180: inverse space.
240: A.
260: A.

---

Hangman

Raymond Fowkes

After entering and RUNning the classic game of Hangman, the first player inputs a word of up to 18 characters (32 for 2K). The screen is then cleared. The second player begins trying to discover the secret word by entering letters likely to be in the word. All correct letters are printed where they occur in the word and any others are printed in the center of the screen and a body part is added to the figure on the gallows.

Typing in the lines below will cause the program to accept characters without pressing ENTER after each. Spaces, however, will not be recognized:

190 PAUSE 4E4
195 LET C$=INKEY$
Delete line 140

 10 PRINT " INPUT WORD"
 20 INPUT A$
 30 CLS
 40 PRINT "        [gD][gD][gD][gD][gD][gD]"
 50 PRINT "        [g5]    ▒"
 60 PRINT "        [g5]    ▒"
 70 FOR A=1 TO 7
 80 PRINT TAB 8;"▒"
 90 NEXT A
100 PRINT "▒▒▒▒▒▒▒▒▒▒▒"
110 PRINT
120 LET B$=A$
130 LET F=NOT A
140 DIM C$(NOT F)
150 FOR B=F TO LEN A$-NOT F
160 PRINT "-";
170 NEXT B
180 FOR G=F TO 11
190 INPUT C$
200 LET D=NOT A
210 FOR A=NOT D TO B
220 IF C$<>A$(A) THEN GOTO 280
230 PRINT AT 12,A-1;C$
240 LET A$(A)="[inv  ]"
250 LET F=F+1
260 LET D=F
270 IF F=B THEN STOP
280 NEXT A
290 IF D THEN GOTO 190
300 PRINT AT 14,G*2;C$;AT VAL "344455567788"(G+NOT D),VAL "332431532415"(G+NOT D);"▒"
310 NEXT G
320 PRINT AT G,NOT A;B$

Graphics line notes:

40: D (6)
50: 5, A
60: 5, A
80: A
100: A (11)
240: inverse space.
300: A