Character Analysis

CHARACTER ANALYSIS is a utility program to define the binary and decimal value of a byte and is useful with user defined graphics when they appear in a machine code program. It can be merged with another program and activated with GOSUB 9600.

9600 BORDER 5: PAPER 5: CLS
9610 CLS : PRINT AT 10,0;" ENTER CHARACTER TO BE ANALYZED "
9620 INPUT "(GRAPHIC MODE) ";A$
9630 CLS
9640 GO SUB 9880
9650 PRINT AT 4,15; PAPER 7; BRIGHT 0;A$
9660 LET x=120
9670 LET l=9
9680 LET y=143
9690 FOR a=y TO y-7 STEP -1
9700 LET c=9
9710 LET z=7
9720 LET byte=0
9730 FOR b=x TO x+7
9740 LET byte=byte+2^z*(POINT (b,a))
9750 PRINT AT l,c;POINT (b,a)
9760 IF POINT (b,a)=0 THEN  PRINT AT l,c; OVER 1; PAPER 6; BRIGHT 1;" "
9770 IF POINT (b,a)=1 THEN  PRINT AT l,c; OVER 1; INVERSE 1; BRIGHT 1;" "
9780 PRINT  PAPER 1; INK 7; BRIGHT 1;AT l,19;"      ";AT l,20;byte
9790 LET c=c+1
9800 LET z=z-1
9810 NEXT b
9820 LET l=l+1
9830 NEXT a
9840 PRINT  PAPER 2; INK 9; BRIGHT 1;AT 18,9;" BINARY ";AT 18,17; PAPER 1;" DECIMAL "
9850 PRINT #1;TAB 10;"COPY? (Y/N)"
9860 PAUSE 0: IF INKEY$="y" THEN  COPY
9870 CLS : PRINT AT 10,0;"REMEMBER TO CHANGE GRAPHIC MODE": PAUSE 200: CLS : STOP
9880 PLOT 111,152
9890 DRAW 25,0: DRAW 0,-25: DRAW -25,0: DRAW 0,25
9900 PRINT AT 3,14; PAPER 7;"   "
9910 PRINT AT 4,14; PAPER 7;"   "
9920 PRINT AT 5,14; PAPER 7;"   "
9930 RETURN