Conjecture

Do you enjoy word games? Here is a nifty little 32 line program that is a lot like HANGMAN:

  10 PRINT AT 10,0;"INPUT YOUR M
ESSAGE?"
  20 INPUT A$
  30 LET B$=A$
  40 FOR N=1 TO LEN A$
  50 IF A$(N)<>" " THEN LET A$(N
)="▒"
  60 NEXT N
  70 CLS
  80 PRINT AT 10,(31-LEN A$)/2;A
$
  90 LET PS=1
 100 GOSUB 330
 200 INPUT C$
 210 IF LEN C$>1 THEN GOTO 400
 220 LET C=0
 230 FOR N=1 TO LEN B$
 240 IF B$(N)=C$ AND A$(N)<>C$ T
HEN GOSUB 300
 250 NEXT N
 260 IF C=0 THEN LET PS=PS+1
 270 GOSUB 330
 280 IF PS<1 THEN LET PS=1
 290 GOTO 200
 300 LET A$(N)=C$
 310 PRINT AT 10,(31-LEN A$)/2;A
$
 320 LET C=1
 330 IF PS=6 THEN GOTO 410
 340 PRINT AT 20,0;"PASS NUMBER
";PS
 350 RETURN
 400 IF C$=B$ THEN PRINT AT 20,0
[illegible]"YOU GOT IT IN ";PS;" PASSES."
 410 IF C$<>B$ THEN PRINT AT 20,
0;"WRONG ......"
 420 PRINT B$
 430 PAUSE 300
 440 CLS
 450 RUN

With this two player game, a person enters a group of words whose total amount of characters, including empty spaces, does not exceed 32 in number.

The computer will then replace the characters with graphic periods and display the result on the center of the screen. The other player is then challenged to guess the sentence in 5 passes by entering one letter at a time. If the letter is in any word in the sentence, it will replace the graphic periods as many times as it occurs and the pass won’t be counted.

If the letter does not appear in the sentence, a pass will be charged against the player. Five passes are allowed before the game is over and the message will appear.

If the player thinks (s)he knows what the message is, it can be typed in and the computer will tell whether it is right or not. If the inputted guess is wrong, the game will be over.

The limit of 5 passes can be changed to make the game harder (ha ha) or easier by editing the <6> in line 330.

This program can have a lot of features added to it, such as Player’s names, score keeping, high score by name, timer with INKEY$ input, etc.

Another much more elaborate two player word game is “SCRAMBLED WORDS” on BOSS package #101 where there are 200 common five letter words in a data base. The screen displays one word at a time with the letters mixed up and challenges the current player to input the correct spelling of the word as a 60 second clock counts down and is displayed on the screen. If the player spells the word correctly, whatever time is left on the clock is added to his or her score. If time runs out, the word is displayed. The game cycles between two players with 10 words each and then totals the scores.

These types of games are excellent for forcing the players to accomplish a mental task because of the time element involved. A clocking routine could be added to the “CONJECTURE” program where a character would have to be inputted in a certain amount of time or a pass would be lost.