Hurkle

A Hurkle is a happy beast and lives in another galaxy on a planet named Lirht that has three moons. Hurkle are favorite pets of the Gwik, the dominant race of Lirht and . . .well, to find out more, read “The Hurkle is a Happy Beast,” in the book A Way Home, by Theodore Sturgeon.

In this program a shy Hurkle is hiding on a 10 by 10 grid. Homebase is point 0,0 in the southwest corner. Your guess as to the gridpoint where the Hurkle is hiding should be a pair of whole numbers. After each try the computer will tell you the approximate direction to go look for the Hurkle. You get five guesses to find him.

This program was written by Bob Albrecht of People’s Computer Company, and was translated by Laura McLauglin.

220 PRINT "A HURKLE IS HIDING IN A 10 BY 10 GRID."
240 PRINT "TRY TO GUESS THE LOCATION OF THE HURKLE."
250 PRINT "YOU GET 5 TRIES."
260 PRINT "AFTER EACH TRY, I WILL TELL YOU"
270 PRINT "THE DIRECTION TO GO TO FIND HIM."
280 PRINT "HIT NEWLINE TO START."
282 INPUT A$
283 CLS
284 RANDOMISE
285 LET A=RND(10)
286 LET B=RND(10)
310 FOR K=1 TO 5
320 PRINT "GUESS NUMBER " ;K
325 PRINT "X COORDINATE?"
330 INPUT X
333 PRINT "Y COORDINATE?"
335 INPUT Y
340 IF ABS (X-A)+ABS(Y-B)=0 THEN GO TO 500
350 CLS
355 PRINT "X=";X;"Y=";Y;"  ";
360 GO SUB 610
380 NEXT K
420 PRINT "SORRY, THAT IS 5 GUESSES"
430 PRINT "THE HURKLE IS HIDING AT ";A;",";B
440 PRINT
450 PRINT "PLAY AGAIN?"
460 INPUT A$
470 IF NOT CODE(A$)=62 THEN STOP
480 GO TO 283
500 PRINT
520 PRINT "YOU FOUND HIM IN ";K;" GUESSES."
540 GO TO 440
610 PRINT "GO ";
620 IF Y=B THEN GO TO 670
630 IF Y<B THEN GO TO 660
640 PRINT "SOUTH";
650 GO TO 670
660 PRINT "NORTH";
670 IF X=A THEN GO TO 720
680 IF X<A THEN GO TO 710
690 PRINT "WEST"
700 GO TO 720
710 PRINT "EAST"
720 PRINT
730 RETURN