Merry Christmas

To run this Christmas display program, enter the program in the FAST mode, then return to the SLOW mode and RUN. To exit, hit BREAK.

You can personalize your messages by changing lines 40, 110 and 125. To add additional text, insert in pairs between lines 100 and 129 the following lines:

101 PRINT AT 10,12;" 9 characters of text"
102 PAUSE 120

Have a Merry Christmas!

   1 REM MERRY CHRISTMAS BY M.FREITAS 1981, REVISED 1982
   2 LET T$="X"
   3 LET Y=16
   4 CLS
  10 GOSUB 60
  20 LET A$="███████████▒▒▒▒▒▒▒▒▒▒▒██████████"
  30 PRINT A$
  40 PRINT "███████████▒ HAVE A  ▒██████████"
  50 PRINT A$
  55 GOSUB 60
  57 GOTO 100
  60 FOR I=1 TO 9
  70 PRINT "████████████████████████████████";
  80 NEXT I
  90 RETURN
 100 PAUSE 120
 110 PRINT AT 10,12;"  MERRY"
 115 PAUSE 120
 120 PRINT AT 10,12;"CHRISTMAS"
 125 PAUSE 120
 129 FOR S=1 TO 32
 130 SCROLL
 131 NEXT S
 140 PRINT AT 2,19;"::";AT 3,20;"Y";AT 4,9;"£";AT 4,20;"█▄."
 150 PRINT AT 5,4;"▄▄▄▄▖O ---------█▀";AT 6,4;"▝███▙▐▀ ▗▄▖  ▗██▛";
 160 PRINT AT 7,5;"████▐ ▗█▛   ▝▛▀▌";AT 8,5;"▜███████▘   ▗▘▗▘";
 170 PRINT AT 9,4;"▗ ▜█████▛";AT 10,4;"▚▄▄▙▄▄▄▟▄▘";
 180 FOR I=1 TO 8
 189 FOR B=1 TO 4
 190 PRINT AT 8,17;" ▌ ▌";
 191 NEXT B
 194 FOR B=1 TO 8
 195 PRINT AT 8,17;"▗▘▗▘"
 196 NEXT B
 200 NEXT I
 210 PRINT AT 13,4;"HERE COMES SANTA CLAUS"
 220 FOR I=1 TO 3
 230 GOSUB 2000
 240 NEXT I
 245 PRINT AT 13,4;"  HERE COMES SANTA CLAUS"
 250 FOR I=1 TO 3
 260 GOSUB 2000
 270 NEXT I
 280 PRINT AT 13,4;" RIGHT DOWN SANTA CLAUS LANE"
 285 FOR B=1 TO 100
 290 GOSUB 2000
 295 NEXT B
 300 PRINT AT 13,4;"VIXEN AND BLITZEN             "
 310 PRINT AT 14,7;" AND ALL HIS REINDEER"
 315 FOR I=1 TO 5
 316 GOSUB 2000
 320 NEXT I
 321 PRINT AT 15,12;"PULLING ON THE REINS"
 322 FOR B=1 TO 17
 323 SCROLL
 324 NEXT B
 325 PRINT AT 19,16;"*"
 330 PRINT AT 20,16;"X"
 335 FOR I=1 TO 8
 340 LET T$=T$+"XX"
 350 LET Y=Y-1
 360 PRINT AT 21,Y;T$
 370 SCROLL
 380 PRINT AT 21,Y;T$
 390 SCROLL
 400 NEXT I
 420 FOR I=1 TO 3
 430 PRINT AT 21,15;"III"
 435 SCROLL
 440 NEXT I
 445 PRINT "         MERRY CHRISTMAS"
 450 PAUSE 400
 455 FAST
 465 CLS
 470 LET A$="▞▞CHRISTMAS"
 490 FOR I=1 TO 29
 500 PRINT A$;A$;
 510 NEXT I
 520 PRINT "▞▞"
 540 SLOW
 550 FOR N=1 TO 13
 560 PRINT AT N,7;"  "
 570 NEXT N
 580 PRINT AT 12,1;"        ";AT 13,2;"       ";AT 10,1;"  ";AT 11,1;"  "
 590 FOR L=1 TO 2
 600 PRINT AT L,12;"      "
 610 NEXT L
 620 FOR B=3 TO 11
 630 PRINT AT B,11;"  ";AT B,17;"  "
 640 NEXT B
 650 FOR I=11 TO 13
 660 PRINT AT I,12;"      "
 670 NEXT I
 680 FOR I=1 TO 3
 690 PRINT AT I,19+I;"  ";AT I,20-I;"  "
 700 NEXT I
 710 FOR I=4 TO 13
 720 PRINT AT I,23;"   "
 730 NEXT I
 740 PAUSE 1000
 744 FOR B=1 TO 22
 745 SCROLL
 746 NEXT B
 750 RUN
1999 STOP
2000 FOR B=1 TO 3
2010 PRINT AT 8,17;" ▌ ▌"
2020 NEXT B
2030 FOR B=1 TO 5
2040 PRINT AT 8,17;"▗▘▗▘"
2050 NEXT B
2060 RETURN
9998 SAVE "X-MAS"
9999 GOTO 9998
SYNTACTIC SUM:  17460, 8K ROM