Micro Invaders

In Micro Invaders, a space fantasy game in Basic for the 8K ROM, 1K RAM Sinclair, the Earth is under attack by a fleet of Micro Invaders from outer space.

You are in charge of a mobile intercepter launcher defending the Earth. Intelligence has reported that the invading ships can be destroyed only by hitting them just inside the left landing leg. This requires pinpoint aiming. You control your launcher movement with the arrow keys using 5 for left and 8 for right. You launch your intercepters by pressing the zero key.

 10 LET G=0
 15 LET G=G+5
 20 LET B=15
 25 LET N=5
 30 LET L=0
 35 DIM A(5)
 40 GOTO 60
 45 CLS
 50 LET N=N-1
 55 IF N=0 THEN GOTO 15
 60 LET A=20
 65 LET C=0
 70 IF L=20 THEN GOTO 200
 75 FOR M=1 TO N
 80 LET A(M)=INT (RND*18+7)
 85 NEXT M
 90 FOR I=1 TO 12
 95 FOR M=1 TO N
100 PRINT AT L,A(M);"[gT][gY]"
105 IF A=L AND B=A(M) THEN GOTO 45
110 NEXT M
115 IF INKEY$="0" THEN LET C=1
120 IF C=1 THEN GOTO 140
125 IF INKEY$="5" THEN LET B=B-1
130 IF INKEY$="8" THEN LET B=B+1
135 GOTO 145
140 LET A=A-2
145 PRINT AT A,B;"[gQ][g4]"
150 IF A<L THEN LET C=0
155 IF A<L THEN LET A=20
160 PAUSE 25
165 CLS
170 NEXT I
175 LET L=L+4
180 GOTO 70
200 PRINT AT 21,20;G-N;" INVADERS"

The invaders come swooping in from outer space in formations of five space ships. The ships can change formation at times, and they can hide behind each other. Hitting one ship results in a formation rearrangement and a delay in renewing the attack.

If all the ships of the formation are destroyed before they reach you, you are assigned a new formation to deal with. The number of craft destroyed is shown in the lower right of the display. The game is over if your launcher is hit by the invaders.

Since the program is quite full, more memory would be needed to add anything unless the efficiency of the program can be improved.

Program notes:

Line 100: graphics on T and Y.
Line 145: graphics on Q and 4.